169 lines
4.6 KiB
Fortran
169 lines
4.6 KiB
Fortran
*> \brief \b CLASSQ updates a sum of squares represented in scaled form.
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
*> \htmlonly
|
|
*> Download CLASSQ + dependencies
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/classq.f">
|
|
*> [TGZ]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/classq.f">
|
|
*> [ZIP]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/classq.f">
|
|
*> [TXT]</a>
|
|
*> \endhtmlonly
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* SUBROUTINE CLASSQ( N, X, INCX, SCALE, SUMSQ )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* INTEGER INCX, N
|
|
* REAL SCALE, SUMSQ
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* COMPLEX X( * )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> CLASSQ returns the values scl and ssq such that
|
|
*>
|
|
*> ( scl**2 )*ssq = x( 1 )**2 +...+ x( n )**2 + ( scale**2 )*sumsq,
|
|
*>
|
|
*> where x( i ) = abs( X( 1 + ( i - 1 )*INCX ) ). The value of sumsq is
|
|
*> assumed to be at least unity and the value of ssq will then satisfy
|
|
*>
|
|
*> 1.0 .le. ssq .le. ( sumsq + 2*n ).
|
|
*>
|
|
*> scale is assumed to be non-negative and scl returns the value
|
|
*>
|
|
*> scl = max( scale, abs( real( x( i ) ) ), abs( aimag( x( i ) ) ) ),
|
|
*> i
|
|
*>
|
|
*> scale and sumsq must be supplied in SCALE and SUMSQ respectively.
|
|
*> SCALE and SUMSQ are overwritten by scl and ssq respectively.
|
|
*>
|
|
*> The routine makes only one pass through the vector X.
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The number of elements to be used from the vector X.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] X
|
|
*> \verbatim
|
|
*> X is COMPLEX array, dimension (N)
|
|
*> The vector x as described above.
|
|
*> x( i ) = X( 1 + ( i - 1 )*INCX ), 1 <= i <= n.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] INCX
|
|
*> \verbatim
|
|
*> INCX is INTEGER
|
|
*> The increment between successive values of the vector X.
|
|
*> INCX > 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in,out] SCALE
|
|
*> \verbatim
|
|
*> SCALE is REAL
|
|
*> On entry, the value scale in the equation above.
|
|
*> On exit, SCALE is overwritten with the value scl .
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in,out] SUMSQ
|
|
*> \verbatim
|
|
*> SUMSQ is REAL
|
|
*> On entry, the value sumsq in the equation above.
|
|
*> On exit, SUMSQ is overwritten with the value ssq .
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \date December 2016
|
|
*
|
|
*> \ingroup complexOTHERauxiliary
|
|
*
|
|
* =====================================================================
|
|
SUBROUTINE CLASSQ( N, X, INCX, SCALE, SUMSQ )
|
|
*
|
|
* -- LAPACK auxiliary routine (version 3.7.0) --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
* December 2016
|
|
*
|
|
* .. Scalar Arguments ..
|
|
INTEGER INCX, N
|
|
REAL SCALE, SUMSQ
|
|
* ..
|
|
* .. Array Arguments ..
|
|
COMPLEX X( * )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
REAL ZERO
|
|
PARAMETER ( ZERO = 0.0E+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER IX
|
|
REAL TEMP1
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL SISNAN
|
|
EXTERNAL SISNAN
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC ABS, AIMAG, REAL
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
IF( N.GT.0 ) THEN
|
|
DO 10 IX = 1, 1 + ( N-1 )*INCX, INCX
|
|
TEMP1 = ABS( REAL( X( IX ) ) )
|
|
IF( TEMP1.GT.ZERO.OR.SISNAN( TEMP1 ) ) THEN
|
|
IF( SCALE.LT.TEMP1 ) THEN
|
|
SUMSQ = 1 + SUMSQ*( SCALE / TEMP1 )**2
|
|
SCALE = TEMP1
|
|
ELSE
|
|
SUMSQ = SUMSQ + ( TEMP1 / SCALE )**2
|
|
END IF
|
|
END IF
|
|
TEMP1 = ABS( AIMAG( X( IX ) ) )
|
|
IF( TEMP1.GT.ZERO.OR.SISNAN( TEMP1 ) ) THEN
|
|
IF( SCALE.LT.TEMP1 .OR. SISNAN( TEMP1 ) ) THEN
|
|
SUMSQ = 1 + SUMSQ*( SCALE / TEMP1 )**2
|
|
SCALE = TEMP1
|
|
ELSE
|
|
SUMSQ = SUMSQ + ( TEMP1 / SCALE )**2
|
|
END IF
|
|
END IF
|
|
10 CONTINUE
|
|
END IF
|
|
*
|
|
RETURN
|
|
*
|
|
* End of CLASSQ
|
|
*
|
|
END
|