229 lines
6.0 KiB
Fortran
229 lines
6.0 KiB
Fortran
*> \brief \b DQRT01P
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* SUBROUTINE DQRT01P( M, N, A, AF, Q, R, LDA, TAU, WORK, LWORK,
|
|
* RWORK, RESULT )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* INTEGER LDA, LWORK, M, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* DOUBLE PRECISION A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
|
|
* $ R( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
|
|
* $ WORK( LWORK )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> DQRT01P tests DGEQRFP, which computes the QR factorization of an m-by-n
|
|
*> matrix A, and partially tests DORGQR which forms the m-by-m
|
|
*> orthogonal matrix Q.
|
|
*>
|
|
*> DQRT01P compares R with Q'*A, and checks that Q is orthogonal.
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] M
|
|
*> \verbatim
|
|
*> M is INTEGER
|
|
*> The number of rows of the matrix A. M >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The number of columns of the matrix A. N >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] A
|
|
*> \verbatim
|
|
*> A is DOUBLE PRECISION array, dimension (LDA,N)
|
|
*> The m-by-n matrix A.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] AF
|
|
*> \verbatim
|
|
*> AF is DOUBLE PRECISION array, dimension (LDA,N)
|
|
*> Details of the QR factorization of A, as returned by DGEQRFP.
|
|
*> See DGEQRFP for further details.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] Q
|
|
*> \verbatim
|
|
*> Q is DOUBLE PRECISION array, dimension (LDA,M)
|
|
*> The m-by-m orthogonal matrix Q.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] R
|
|
*> \verbatim
|
|
*> R is DOUBLE PRECISION array, dimension (LDA,max(M,N))
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDA
|
|
*> \verbatim
|
|
*> LDA is INTEGER
|
|
*> The leading dimension of the arrays A, AF, Q and R.
|
|
*> LDA >= max(M,N).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] TAU
|
|
*> \verbatim
|
|
*> TAU is DOUBLE PRECISION array, dimension (min(M,N))
|
|
*> The scalar factors of the elementary reflectors, as returned
|
|
*> by DGEQRFP.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] WORK
|
|
*> \verbatim
|
|
*> WORK is DOUBLE PRECISION array, dimension (LWORK)
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LWORK
|
|
*> \verbatim
|
|
*> LWORK is INTEGER
|
|
*> The dimension of the array WORK.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] RWORK
|
|
*> \verbatim
|
|
*> RWORK is DOUBLE PRECISION array, dimension (M)
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] RESULT
|
|
*> \verbatim
|
|
*> RESULT is DOUBLE PRECISION array, dimension (2)
|
|
*> The test ratios:
|
|
*> RESULT(1) = norm( R - Q'*A ) / ( M * norm(A) * EPS )
|
|
*> RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \ingroup double_lin
|
|
*
|
|
* =====================================================================
|
|
SUBROUTINE DQRT01P( M, N, A, AF, Q, R, LDA, TAU, WORK, LWORK,
|
|
$ RWORK, RESULT )
|
|
*
|
|
* -- LAPACK test routine --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
*
|
|
* .. Scalar Arguments ..
|
|
INTEGER LDA, LWORK, M, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
DOUBLE PRECISION A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
|
|
$ R( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
|
|
$ WORK( LWORK )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
DOUBLE PRECISION ZERO, ONE
|
|
PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
|
|
DOUBLE PRECISION ROGUE
|
|
PARAMETER ( ROGUE = -1.0D+10 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER INFO, MINMN
|
|
DOUBLE PRECISION ANORM, EPS, RESID
|
|
* ..
|
|
* .. External Functions ..
|
|
DOUBLE PRECISION DLAMCH, DLANGE, DLANSY
|
|
EXTERNAL DLAMCH, DLANGE, DLANSY
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL DGEMM, DGEQRFP, DLACPY, DLASET, DORGQR, DSYRK
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC DBLE, MAX, MIN
|
|
* ..
|
|
* .. Scalars in Common ..
|
|
CHARACTER*32 SRNAMT
|
|
* ..
|
|
* .. Common blocks ..
|
|
COMMON / SRNAMC / SRNAMT
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
MINMN = MIN( M, N )
|
|
EPS = DLAMCH( 'Epsilon' )
|
|
*
|
|
* Copy the matrix A to the array AF.
|
|
*
|
|
CALL DLACPY( 'Full', M, N, A, LDA, AF, LDA )
|
|
*
|
|
* Factorize the matrix A in the array AF.
|
|
*
|
|
SRNAMT = 'DGEQRFP'
|
|
CALL DGEQRFP( M, N, AF, LDA, TAU, WORK, LWORK, INFO )
|
|
*
|
|
* Copy details of Q
|
|
*
|
|
CALL DLASET( 'Full', M, M, ROGUE, ROGUE, Q, LDA )
|
|
CALL DLACPY( 'Lower', M-1, N, AF( 2, 1 ), LDA, Q( 2, 1 ), LDA )
|
|
*
|
|
* Generate the m-by-m matrix Q
|
|
*
|
|
SRNAMT = 'DORGQR'
|
|
CALL DORGQR( M, M, MINMN, Q, LDA, TAU, WORK, LWORK, INFO )
|
|
*
|
|
* Copy R
|
|
*
|
|
CALL DLASET( 'Full', M, N, ZERO, ZERO, R, LDA )
|
|
CALL DLACPY( 'Upper', M, N, AF, LDA, R, LDA )
|
|
*
|
|
* Compute R - Q'*A
|
|
*
|
|
CALL DGEMM( 'Transpose', 'No transpose', M, N, M, -ONE, Q, LDA, A,
|
|
$ LDA, ONE, R, LDA )
|
|
*
|
|
* Compute norm( R - Q'*A ) / ( M * norm(A) * EPS ) .
|
|
*
|
|
ANORM = DLANGE( '1', M, N, A, LDA, RWORK )
|
|
RESID = DLANGE( '1', M, N, R, LDA, RWORK )
|
|
IF( ANORM.GT.ZERO ) THEN
|
|
RESULT( 1 ) = ( ( RESID / DBLE( MAX( 1, M ) ) ) / ANORM ) / EPS
|
|
ELSE
|
|
RESULT( 1 ) = ZERO
|
|
END IF
|
|
*
|
|
* Compute I - Q'*Q
|
|
*
|
|
CALL DLASET( 'Full', M, M, ZERO, ONE, R, LDA )
|
|
CALL DSYRK( 'Upper', 'Transpose', M, M, -ONE, Q, LDA, ONE, R,
|
|
$ LDA )
|
|
*
|
|
* Compute norm( I - Q'*Q ) / ( M * EPS ) .
|
|
*
|
|
RESID = DLANSY( '1', 'Upper', M, R, LDA, RWORK )
|
|
*
|
|
RESULT( 2 ) = ( RESID / DBLE( MAX( 1, M ) ) ) / EPS
|
|
*
|
|
RETURN
|
|
*
|
|
* End of DQRT01P
|
|
*
|
|
END
|