293 lines
7.6 KiB
Fortran
293 lines
7.6 KiB
Fortran
*> \brief \b CLA_GERCOND_X computes the infinity norm condition number of op(A)*diag(x) for general matrices.
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
*> \htmlonly
|
|
*> Download CLA_GERCOND_X + dependencies
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cla_gercond_x.f">
|
|
*> [TGZ]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cla_gercond_x.f">
|
|
*> [ZIP]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cla_gercond_x.f">
|
|
*> [TXT]</a>
|
|
*> \endhtmlonly
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* REAL FUNCTION CLA_GERCOND_X( TRANS, N, A, LDA, AF, LDAF, IPIV, X,
|
|
* INFO, WORK, RWORK )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* CHARACTER TRANS
|
|
* INTEGER N, LDA, LDAF, INFO
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* INTEGER IPIV( * )
|
|
* COMPLEX A( LDA, * ), AF( LDAF, * ), WORK( * ), X( * )
|
|
* REAL RWORK( * )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*>
|
|
*> CLA_GERCOND_X computes the infinity norm condition number of
|
|
*> op(A) * diag(X) where X is a COMPLEX vector.
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] TRANS
|
|
*> \verbatim
|
|
*> TRANS is CHARACTER*1
|
|
*> Specifies the form of the system of equations:
|
|
*> = 'N': A * X = B (No transpose)
|
|
*> = 'T': A**T * X = B (Transpose)
|
|
*> = 'C': A**H * X = B (Conjugate Transpose = Transpose)
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The number of linear equations, i.e., the order of the
|
|
*> matrix A. N >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] A
|
|
*> \verbatim
|
|
*> A is COMPLEX array, dimension (LDA,N)
|
|
*> On entry, the N-by-N matrix A.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDA
|
|
*> \verbatim
|
|
*> LDA is INTEGER
|
|
*> The leading dimension of the array A. LDA >= max(1,N).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] AF
|
|
*> \verbatim
|
|
*> AF is COMPLEX array, dimension (LDAF,N)
|
|
*> The factors L and U from the factorization
|
|
*> A = P*L*U as computed by CGETRF.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDAF
|
|
*> \verbatim
|
|
*> LDAF is INTEGER
|
|
*> The leading dimension of the array AF. LDAF >= max(1,N).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] IPIV
|
|
*> \verbatim
|
|
*> IPIV is INTEGER array, dimension (N)
|
|
*> The pivot indices from the factorization A = P*L*U
|
|
*> as computed by CGETRF; row i of the matrix was interchanged
|
|
*> with row IPIV(i).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] X
|
|
*> \verbatim
|
|
*> X is COMPLEX array, dimension (N)
|
|
*> The vector X in the formula op(A) * diag(X).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] INFO
|
|
*> \verbatim
|
|
*> INFO is INTEGER
|
|
*> = 0: Successful exit.
|
|
*> i > 0: The ith argument is invalid.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] WORK
|
|
*> \verbatim
|
|
*> WORK is COMPLEX array, dimension (2*N).
|
|
*> Workspace.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] RWORK
|
|
*> \verbatim
|
|
*> RWORK is REAL array, dimension (N).
|
|
*> Workspace.
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \ingroup complexGEcomputational
|
|
*
|
|
* =====================================================================
|
|
REAL FUNCTION CLA_GERCOND_X( TRANS, N, A, LDA, AF, LDAF, IPIV, X,
|
|
$ INFO, WORK, RWORK )
|
|
*
|
|
* -- LAPACK computational routine --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER TRANS
|
|
INTEGER N, LDA, LDAF, INFO
|
|
* ..
|
|
* .. Array Arguments ..
|
|
INTEGER IPIV( * )
|
|
COMPLEX A( LDA, * ), AF( LDAF, * ), WORK( * ), X( * )
|
|
REAL RWORK( * )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Local Scalars ..
|
|
LOGICAL NOTRANS
|
|
INTEGER KASE
|
|
REAL AINVNM, ANORM, TMP
|
|
INTEGER I, J
|
|
COMPLEX ZDUM
|
|
* ..
|
|
* .. Local Arrays ..
|
|
INTEGER ISAVE( 3 )
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
EXTERNAL LSAME
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL CLACN2, CGETRS, XERBLA
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC ABS, MAX, REAL, AIMAG
|
|
* ..
|
|
* .. Statement Functions ..
|
|
REAL CABS1
|
|
* ..
|
|
* .. Statement Function Definitions ..
|
|
CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
CLA_GERCOND_X = 0.0E+0
|
|
*
|
|
INFO = 0
|
|
NOTRANS = LSAME( TRANS, 'N' )
|
|
IF ( .NOT. NOTRANS .AND. .NOT. LSAME( TRANS, 'T' ) .AND. .NOT.
|
|
$ LSAME( TRANS, 'C' ) ) THEN
|
|
INFO = -1
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -2
|
|
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
|
|
INFO = -4
|
|
ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
|
|
INFO = -6
|
|
END IF
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'CLA_GERCOND_X', -INFO )
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Compute norm of op(A)*op2(C).
|
|
*
|
|
ANORM = 0.0
|
|
IF ( NOTRANS ) THEN
|
|
DO I = 1, N
|
|
TMP = 0.0E+0
|
|
DO J = 1, N
|
|
TMP = TMP + CABS1( A( I, J ) * X( J ) )
|
|
END DO
|
|
RWORK( I ) = TMP
|
|
ANORM = MAX( ANORM, TMP )
|
|
END DO
|
|
ELSE
|
|
DO I = 1, N
|
|
TMP = 0.0E+0
|
|
DO J = 1, N
|
|
TMP = TMP + CABS1( A( J, I ) * X( J ) )
|
|
END DO
|
|
RWORK( I ) = TMP
|
|
ANORM = MAX( ANORM, TMP )
|
|
END DO
|
|
END IF
|
|
*
|
|
* Quick return if possible.
|
|
*
|
|
IF( N.EQ.0 ) THEN
|
|
CLA_GERCOND_X = 1.0E+0
|
|
RETURN
|
|
ELSE IF( ANORM .EQ. 0.0E+0 ) THEN
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Estimate the norm of inv(op(A)).
|
|
*
|
|
AINVNM = 0.0E+0
|
|
*
|
|
KASE = 0
|
|
10 CONTINUE
|
|
CALL CLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
|
|
IF( KASE.NE.0 ) THEN
|
|
IF( KASE.EQ.2 ) THEN
|
|
* Multiply by R.
|
|
DO I = 1, N
|
|
WORK( I ) = WORK( I ) * RWORK( I )
|
|
END DO
|
|
*
|
|
IF ( NOTRANS ) THEN
|
|
CALL CGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
|
|
$ WORK, N, INFO )
|
|
ELSE
|
|
CALL CGETRS( 'Conjugate transpose', N, 1, AF, LDAF, IPIV,
|
|
$ WORK, N, INFO )
|
|
ENDIF
|
|
*
|
|
* Multiply by inv(X).
|
|
*
|
|
DO I = 1, N
|
|
WORK( I ) = WORK( I ) / X( I )
|
|
END DO
|
|
ELSE
|
|
*
|
|
* Multiply by inv(X**H).
|
|
*
|
|
DO I = 1, N
|
|
WORK( I ) = WORK( I ) / X( I )
|
|
END DO
|
|
*
|
|
IF ( NOTRANS ) THEN
|
|
CALL CGETRS( 'Conjugate transpose', N, 1, AF, LDAF, IPIV,
|
|
$ WORK, N, INFO )
|
|
ELSE
|
|
CALL CGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
|
|
$ WORK, N, INFO )
|
|
END IF
|
|
*
|
|
* Multiply by R.
|
|
*
|
|
DO I = 1, N
|
|
WORK( I ) = WORK( I ) * RWORK( I )
|
|
END DO
|
|
END IF
|
|
GO TO 10
|
|
END IF
|
|
*
|
|
* Compute the estimate of the reciprocal condition number.
|
|
*
|
|
IF( AINVNM .NE. 0.0E+0 )
|
|
$ CLA_GERCOND_X = 1.0E+0 / AINVNM
|
|
*
|
|
RETURN
|
|
*
|
|
* End of CLA_GERCOND_X
|
|
*
|
|
END
|