230 lines
5.9 KiB
Fortran
230 lines
5.9 KiB
Fortran
*> \brief \b DOPGTR
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
*> \htmlonly
|
|
*> Download DOPGTR + dependencies
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dopgtr.f">
|
|
*> [TGZ]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dopgtr.f">
|
|
*> [ZIP]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dopgtr.f">
|
|
*> [TXT]</a>
|
|
*> \endhtmlonly
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* SUBROUTINE DOPGTR( UPLO, N, AP, TAU, Q, LDQ, WORK, INFO )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* CHARACTER UPLO
|
|
* INTEGER INFO, LDQ, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* DOUBLE PRECISION AP( * ), Q( LDQ, * ), TAU( * ), WORK( * )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> DOPGTR generates a real orthogonal matrix Q which is defined as the
|
|
*> product of n-1 elementary reflectors H(i) of order n, as returned by
|
|
*> DSPTRD using packed storage:
|
|
*>
|
|
*> if UPLO = 'U', Q = H(n-1) . . . H(2) H(1),
|
|
*>
|
|
*> if UPLO = 'L', Q = H(1) H(2) . . . H(n-1).
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] UPLO
|
|
*> \verbatim
|
|
*> UPLO is CHARACTER*1
|
|
*> = 'U': Upper triangular packed storage used in previous
|
|
*> call to DSPTRD;
|
|
*> = 'L': Lower triangular packed storage used in previous
|
|
*> call to DSPTRD.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The order of the matrix Q. N >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] AP
|
|
*> \verbatim
|
|
*> AP is DOUBLE PRECISION array, dimension (N*(N+1)/2)
|
|
*> The vectors which define the elementary reflectors, as
|
|
*> returned by DSPTRD.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] TAU
|
|
*> \verbatim
|
|
*> TAU is DOUBLE PRECISION array, dimension (N-1)
|
|
*> TAU(i) must contain the scalar factor of the elementary
|
|
*> reflector H(i), as returned by DSPTRD.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] Q
|
|
*> \verbatim
|
|
*> Q is DOUBLE PRECISION array, dimension (LDQ,N)
|
|
*> The N-by-N orthogonal matrix Q.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDQ
|
|
*> \verbatim
|
|
*> LDQ is INTEGER
|
|
*> The leading dimension of the array Q. LDQ >= max(1,N).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] WORK
|
|
*> \verbatim
|
|
*> WORK is DOUBLE PRECISION array, dimension (N-1)
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] INFO
|
|
*> \verbatim
|
|
*> INFO is INTEGER
|
|
*> = 0: successful exit
|
|
*> < 0: if INFO = -i, the i-th argument had an illegal value
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \ingroup doubleOTHERcomputational
|
|
*
|
|
* =====================================================================
|
|
SUBROUTINE DOPGTR( UPLO, N, AP, TAU, Q, LDQ, WORK, INFO )
|
|
*
|
|
* -- LAPACK computational routine --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER UPLO
|
|
INTEGER INFO, LDQ, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
DOUBLE PRECISION AP( * ), Q( LDQ, * ), TAU( * ), WORK( * )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
DOUBLE PRECISION ZERO, ONE
|
|
PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
LOGICAL UPPER
|
|
INTEGER I, IINFO, IJ, J
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
EXTERNAL LSAME
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL DORG2L, DORG2R, XERBLA
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MAX
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Test the input arguments
|
|
*
|
|
INFO = 0
|
|
UPPER = LSAME( UPLO, 'U' )
|
|
IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
|
|
INFO = -1
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -2
|
|
ELSE IF( LDQ.LT.MAX( 1, N ) ) THEN
|
|
INFO = -6
|
|
END IF
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'DOPGTR', -INFO )
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Quick return if possible
|
|
*
|
|
IF( N.EQ.0 )
|
|
$ RETURN
|
|
*
|
|
IF( UPPER ) THEN
|
|
*
|
|
* Q was determined by a call to DSPTRD with UPLO = 'U'
|
|
*
|
|
* Unpack the vectors which define the elementary reflectors and
|
|
* set the last row and column of Q equal to those of the unit
|
|
* matrix
|
|
*
|
|
IJ = 2
|
|
DO 20 J = 1, N - 1
|
|
DO 10 I = 1, J - 1
|
|
Q( I, J ) = AP( IJ )
|
|
IJ = IJ + 1
|
|
10 CONTINUE
|
|
IJ = IJ + 2
|
|
Q( N, J ) = ZERO
|
|
20 CONTINUE
|
|
DO 30 I = 1, N - 1
|
|
Q( I, N ) = ZERO
|
|
30 CONTINUE
|
|
Q( N, N ) = ONE
|
|
*
|
|
* Generate Q(1:n-1,1:n-1)
|
|
*
|
|
CALL DORG2L( N-1, N-1, N-1, Q, LDQ, TAU, WORK, IINFO )
|
|
*
|
|
ELSE
|
|
*
|
|
* Q was determined by a call to DSPTRD with UPLO = 'L'.
|
|
*
|
|
* Unpack the vectors which define the elementary reflectors and
|
|
* set the first row and column of Q equal to those of the unit
|
|
* matrix
|
|
*
|
|
Q( 1, 1 ) = ONE
|
|
DO 40 I = 2, N
|
|
Q( I, 1 ) = ZERO
|
|
40 CONTINUE
|
|
IJ = 3
|
|
DO 60 J = 2, N
|
|
Q( 1, J ) = ZERO
|
|
DO 50 I = J + 1, N
|
|
Q( I, J ) = AP( IJ )
|
|
IJ = IJ + 1
|
|
50 CONTINUE
|
|
IJ = IJ + 2
|
|
60 CONTINUE
|
|
IF( N.GT.1 ) THEN
|
|
*
|
|
* Generate Q(2:n,2:n)
|
|
*
|
|
CALL DORG2R( N-1, N-1, N-1, Q( 2, 2 ), LDQ, TAU, WORK,
|
|
$ IINFO )
|
|
END IF
|
|
END IF
|
|
RETURN
|
|
*
|
|
* End of DOPGTR
|
|
*
|
|
END
|