203 lines
5.4 KiB
Fortran
203 lines
5.4 KiB
Fortran
*> \brief \b ZGESC2 solves a system of linear equations using the LU factorization with complete pivoting computed by sgetc2.
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
*> \htmlonly
|
|
*> Download ZGESC2 + dependencies
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zgesc2.f">
|
|
*> [TGZ]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zgesc2.f">
|
|
*> [ZIP]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zgesc2.f">
|
|
*> [TXT]</a>
|
|
*> \endhtmlonly
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* SUBROUTINE ZGESC2( N, A, LDA, RHS, IPIV, JPIV, SCALE )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* INTEGER LDA, N
|
|
* DOUBLE PRECISION SCALE
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* INTEGER IPIV( * ), JPIV( * )
|
|
* COMPLEX*16 A( LDA, * ), RHS( * )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> ZGESC2 solves a system of linear equations
|
|
*>
|
|
*> A * X = scale* RHS
|
|
*>
|
|
*> with a general N-by-N matrix A using the LU factorization with
|
|
*> complete pivoting computed by ZGETC2.
|
|
*>
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The number of columns of the matrix A.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] A
|
|
*> \verbatim
|
|
*> A is COMPLEX*16 array, dimension (LDA, N)
|
|
*> On entry, the LU part of the factorization of the n-by-n
|
|
*> matrix A computed by ZGETC2: A = P * L * U * Q
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDA
|
|
*> \verbatim
|
|
*> LDA is INTEGER
|
|
*> The leading dimension of the array A. LDA >= max(1, N).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in,out] RHS
|
|
*> \verbatim
|
|
*> RHS is COMPLEX*16 array, dimension N.
|
|
*> On entry, the right hand side vector b.
|
|
*> On exit, the solution vector X.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] IPIV
|
|
*> \verbatim
|
|
*> IPIV is INTEGER array, dimension (N).
|
|
*> The pivot indices; for 1 <= i <= N, row i of the
|
|
*> matrix has been interchanged with row IPIV(i).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] JPIV
|
|
*> \verbatim
|
|
*> JPIV is INTEGER array, dimension (N).
|
|
*> The pivot indices; for 1 <= j <= N, column j of the
|
|
*> matrix has been interchanged with column JPIV(j).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] SCALE
|
|
*> \verbatim
|
|
*> SCALE is DOUBLE PRECISION
|
|
*> On exit, SCALE contains the scale factor. SCALE is chosen
|
|
*> 0 <= SCALE <= 1 to prevent overflow in the solution.
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \date November 2017
|
|
*
|
|
*> \ingroup complex16GEauxiliary
|
|
*
|
|
*> \par Contributors:
|
|
* ==================
|
|
*>
|
|
*> Bo Kagstrom and Peter Poromaa, Department of Computing Science,
|
|
*> Umea University, S-901 87 Umea, Sweden.
|
|
*
|
|
* =====================================================================
|
|
SUBROUTINE ZGESC2( N, A, LDA, RHS, IPIV, JPIV, SCALE )
|
|
*
|
|
* -- LAPACK auxiliary routine (version 3.8.0) --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
* November 2017
|
|
*
|
|
* .. Scalar Arguments ..
|
|
INTEGER LDA, N
|
|
DOUBLE PRECISION SCALE
|
|
* ..
|
|
* .. Array Arguments ..
|
|
INTEGER IPIV( * ), JPIV( * )
|
|
COMPLEX*16 A( LDA, * ), RHS( * )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
DOUBLE PRECISION ZERO, ONE, TWO
|
|
PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0, TWO = 2.0D+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER I, J
|
|
DOUBLE PRECISION BIGNUM, EPS, SMLNUM
|
|
COMPLEX*16 TEMP
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL ZLASWP, ZSCAL, DLABAD
|
|
* ..
|
|
* .. External Functions ..
|
|
INTEGER IZAMAX
|
|
DOUBLE PRECISION DLAMCH
|
|
EXTERNAL IZAMAX, DLAMCH
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC ABS, DBLE, DCMPLX
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Set constant to control overflow
|
|
*
|
|
EPS = DLAMCH( 'P' )
|
|
SMLNUM = DLAMCH( 'S' ) / EPS
|
|
BIGNUM = ONE / SMLNUM
|
|
CALL DLABAD( SMLNUM, BIGNUM )
|
|
*
|
|
* Apply permutations IPIV to RHS
|
|
*
|
|
CALL ZLASWP( 1, RHS, LDA, 1, N-1, IPIV, 1 )
|
|
*
|
|
* Solve for L part
|
|
*
|
|
DO 20 I = 1, N - 1
|
|
DO 10 J = I + 1, N
|
|
RHS( J ) = RHS( J ) - A( J, I )*RHS( I )
|
|
10 CONTINUE
|
|
20 CONTINUE
|
|
*
|
|
* Solve for U part
|
|
*
|
|
SCALE = ONE
|
|
*
|
|
* Check for scaling
|
|
*
|
|
I = IZAMAX( N, RHS, 1 )
|
|
IF( TWO*SMLNUM*ABS( RHS( I ) ).GT.ABS( A( N, N ) ) ) THEN
|
|
TEMP = DCMPLX( ONE / TWO, ZERO ) / ABS( RHS( I ) )
|
|
CALL ZSCAL( N, TEMP, RHS( 1 ), 1 )
|
|
SCALE = SCALE*DBLE( TEMP )
|
|
END IF
|
|
DO 40 I = N, 1, -1
|
|
TEMP = DCMPLX( ONE, ZERO ) / A( I, I )
|
|
RHS( I ) = RHS( I )*TEMP
|
|
DO 30 J = I + 1, N
|
|
RHS( I ) = RHS( I ) - RHS( J )*( A( I, J )*TEMP )
|
|
30 CONTINUE
|
|
40 CONTINUE
|
|
*
|
|
* Apply permutations JPIV to the solution (RHS)
|
|
*
|
|
CALL ZLASWP( 1, RHS, LDA, 1, N-1, JPIV, -1 )
|
|
RETURN
|
|
*
|
|
* End of ZGESC2
|
|
*
|
|
END
|