206 lines
5.4 KiB
Fortran
206 lines
5.4 KiB
Fortran
*> \brief \b ZGEQR2P computes the QR factorization of a general rectangular matrix with non-negative diagonal elements using an unblocked algorithm.
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
*> \htmlonly
|
|
*> Download ZGEQR2P + dependencies
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zgeqr2p.f">
|
|
*> [TGZ]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zgeqr2p.f">
|
|
*> [ZIP]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zgeqr2p.f">
|
|
*> [TXT]</a>
|
|
*> \endhtmlonly
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* SUBROUTINE ZGEQR2P( M, N, A, LDA, TAU, WORK, INFO )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* INTEGER INFO, LDA, M, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* COMPLEX*16 A( LDA, * ), TAU( * ), WORK( * )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> ZGEQR2P computes a QR factorization of a complex m-by-n matrix A:
|
|
*>
|
|
*> A = Q * ( R ),
|
|
*> ( 0 )
|
|
*>
|
|
*> where:
|
|
*>
|
|
*> Q is a m-by-m orthogonal matrix;
|
|
*> R is an upper-triangular n-by-n matrix with nonnegative diagonal
|
|
*> entries;
|
|
*> 0 is a (m-n)-by-n zero matrix, if m > n.
|
|
*>
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] M
|
|
*> \verbatim
|
|
*> M is INTEGER
|
|
*> The number of rows of the matrix A. M >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The number of columns of the matrix A. N >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in,out] A
|
|
*> \verbatim
|
|
*> A is COMPLEX*16 array, dimension (LDA,N)
|
|
*> On entry, the m by n matrix A.
|
|
*> On exit, the elements on and above the diagonal of the array
|
|
*> contain the min(m,n) by n upper trapezoidal matrix R (R is
|
|
*> upper triangular if m >= n). The diagonal entries of R
|
|
*> are real and nonnegative; the elements below the diagonal,
|
|
*> with the array TAU, represent the unitary matrix Q as a
|
|
*> product of elementary reflectors (see Further Details).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDA
|
|
*> \verbatim
|
|
*> LDA is INTEGER
|
|
*> The leading dimension of the array A. LDA >= max(1,M).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] TAU
|
|
*> \verbatim
|
|
*> TAU is COMPLEX*16 array, dimension (min(M,N))
|
|
*> The scalar factors of the elementary reflectors (see Further
|
|
*> Details).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] WORK
|
|
*> \verbatim
|
|
*> WORK is COMPLEX*16 array, dimension (N)
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] INFO
|
|
*> \verbatim
|
|
*> INFO is INTEGER
|
|
*> = 0: successful exit
|
|
*> < 0: if INFO = -i, the i-th argument had an illegal value
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \date November 2019
|
|
*
|
|
*> \ingroup complex16GEcomputational
|
|
*
|
|
*> \par Further Details:
|
|
* =====================
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> The matrix Q is represented as a product of elementary reflectors
|
|
*>
|
|
*> Q = H(1) H(2) . . . H(k), where k = min(m,n).
|
|
*>
|
|
*> Each H(i) has the form
|
|
*>
|
|
*> H(i) = I - tau * v * v**H
|
|
*>
|
|
*> where tau is a complex scalar, and v is a complex vector with
|
|
*> v(1:i-1) = 0 and v(i) = 1; v(i+1:m) is stored on exit in A(i+1:m,i),
|
|
*> and tau in TAU(i).
|
|
*>
|
|
*> See Lapack Working Note 203 for details
|
|
*> \endverbatim
|
|
*>
|
|
* =====================================================================
|
|
SUBROUTINE ZGEQR2P( M, N, A, LDA, TAU, WORK, INFO )
|
|
*
|
|
* -- LAPACK computational routine (version 3.9.0) --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
* November 2019
|
|
*
|
|
* .. Scalar Arguments ..
|
|
INTEGER INFO, LDA, M, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
COMPLEX*16 A( LDA, * ), TAU( * ), WORK( * )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
COMPLEX*16 ONE
|
|
PARAMETER ( ONE = ( 1.0D+0, 0.0D+0 ) )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER I, K
|
|
COMPLEX*16 ALPHA
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL XERBLA, ZLARF, ZLARFGP
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC DCONJG, MAX, MIN
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Test the input arguments
|
|
*
|
|
INFO = 0
|
|
IF( M.LT.0 ) THEN
|
|
INFO = -1
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -2
|
|
ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
|
|
INFO = -4
|
|
END IF
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'ZGEQR2P', -INFO )
|
|
RETURN
|
|
END IF
|
|
*
|
|
K = MIN( M, N )
|
|
*
|
|
DO 10 I = 1, K
|
|
*
|
|
* Generate elementary reflector H(i) to annihilate A(i+1:m,i)
|
|
*
|
|
CALL ZLARFGP( M-I+1, A( I, I ), A( MIN( I+1, M ), I ), 1,
|
|
$ TAU( I ) )
|
|
IF( I.LT.N ) THEN
|
|
*
|
|
* Apply H(i)**H to A(i:m,i+1:n) from the left
|
|
*
|
|
ALPHA = A( I, I )
|
|
A( I, I ) = ONE
|
|
CALL ZLARF( 'Left', M-I+1, N-I, A( I, I ), 1,
|
|
$ DCONJG( TAU( I ) ), A( I, I+1 ), LDA, WORK )
|
|
A( I, I ) = ALPHA
|
|
END IF
|
|
10 CONTINUE
|
|
RETURN
|
|
*
|
|
* End of ZGEQR2P
|
|
*
|
|
END
|