211 lines
5.7 KiB
Fortran
211 lines
5.7 KiB
Fortran
*> \brief \b CLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of a general rectangular matrix.
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
*> \htmlonly
|
|
*> Download CLANGE + dependencies
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/clange.f">
|
|
*> [TGZ]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/clange.f">
|
|
*> [ZIP]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/clange.f">
|
|
*> [TXT]</a>
|
|
*> \endhtmlonly
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* REAL FUNCTION CLANGE( NORM, M, N, A, LDA, WORK )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* CHARACTER NORM
|
|
* INTEGER LDA, M, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* REAL WORK( * )
|
|
* COMPLEX A( LDA, * )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> CLANGE returns the value of the one norm, or the Frobenius norm, or
|
|
*> the infinity norm, or the element of largest absolute value of a
|
|
*> complex matrix A.
|
|
*> \endverbatim
|
|
*>
|
|
*> \return CLANGE
|
|
*> \verbatim
|
|
*>
|
|
*> CLANGE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
|
|
*> (
|
|
*> ( norm1(A), NORM = '1', 'O' or 'o'
|
|
*> (
|
|
*> ( normI(A), NORM = 'I' or 'i'
|
|
*> (
|
|
*> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
|
|
*>
|
|
*> where norm1 denotes the one norm of a matrix (maximum column sum),
|
|
*> normI denotes the infinity norm of a matrix (maximum row sum) and
|
|
*> normF denotes the Frobenius norm of a matrix (square root of sum of
|
|
*> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] NORM
|
|
*> \verbatim
|
|
*> NORM is CHARACTER*1
|
|
*> Specifies the value to be returned in CLANGE as described
|
|
*> above.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] M
|
|
*> \verbatim
|
|
*> M is INTEGER
|
|
*> The number of rows of the matrix A. M >= 0. When M = 0,
|
|
*> CLANGE is set to zero.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The number of columns of the matrix A. N >= 0. When N = 0,
|
|
*> CLANGE is set to zero.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] A
|
|
*> \verbatim
|
|
*> A is COMPLEX array, dimension (LDA,N)
|
|
*> The m by n matrix A.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDA
|
|
*> \verbatim
|
|
*> LDA is INTEGER
|
|
*> The leading dimension of the array A. LDA >= max(M,1).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] WORK
|
|
*> \verbatim
|
|
*> WORK is REAL array, dimension (MAX(1,LWORK)),
|
|
*> where LWORK >= M when NORM = 'I'; otherwise, WORK is not
|
|
*> referenced.
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \ingroup complexGEauxiliary
|
|
*
|
|
* =====================================================================
|
|
REAL FUNCTION CLANGE( NORM, M, N, A, LDA, WORK )
|
|
*
|
|
* -- LAPACK auxiliary routine --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER NORM
|
|
INTEGER LDA, M, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
REAL WORK( * )
|
|
COMPLEX A( LDA, * )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
REAL ONE, ZERO
|
|
PARAMETER ( ONE = 1.0E+0, ZERO = 0.0E+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER I, J
|
|
REAL SCALE, SUM, VALUE, TEMP
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME, SISNAN
|
|
EXTERNAL LSAME, SISNAN
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL CLASSQ
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC ABS, MIN, SQRT
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
IF( MIN( M, N ).EQ.0 ) THEN
|
|
VALUE = ZERO
|
|
ELSE IF( LSAME( NORM, 'M' ) ) THEN
|
|
*
|
|
* Find max(abs(A(i,j))).
|
|
*
|
|
VALUE = ZERO
|
|
DO 20 J = 1, N
|
|
DO 10 I = 1, M
|
|
TEMP = ABS( A( I, J ) )
|
|
IF( VALUE.LT.TEMP .OR. SISNAN( TEMP ) ) VALUE = TEMP
|
|
10 CONTINUE
|
|
20 CONTINUE
|
|
ELSE IF( ( LSAME( NORM, 'O' ) ) .OR. ( NORM.EQ.'1' ) ) THEN
|
|
*
|
|
* Find norm1(A).
|
|
*
|
|
VALUE = ZERO
|
|
DO 40 J = 1, N
|
|
SUM = ZERO
|
|
DO 30 I = 1, M
|
|
SUM = SUM + ABS( A( I, J ) )
|
|
30 CONTINUE
|
|
IF( VALUE.LT.SUM .OR. SISNAN( SUM ) ) VALUE = SUM
|
|
40 CONTINUE
|
|
ELSE IF( LSAME( NORM, 'I' ) ) THEN
|
|
*
|
|
* Find normI(A).
|
|
*
|
|
DO 50 I = 1, M
|
|
WORK( I ) = ZERO
|
|
50 CONTINUE
|
|
DO 70 J = 1, N
|
|
DO 60 I = 1, M
|
|
WORK( I ) = WORK( I ) + ABS( A( I, J ) )
|
|
60 CONTINUE
|
|
70 CONTINUE
|
|
VALUE = ZERO
|
|
DO 80 I = 1, M
|
|
TEMP = WORK( I )
|
|
IF( VALUE.LT.TEMP .OR. SISNAN( TEMP ) ) VALUE = TEMP
|
|
80 CONTINUE
|
|
ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
|
|
*
|
|
* Find normF(A).
|
|
*
|
|
SCALE = ZERO
|
|
SUM = ONE
|
|
DO 90 J = 1, N
|
|
CALL CLASSQ( M, A( 1, J ), 1, SCALE, SUM )
|
|
90 CONTINUE
|
|
VALUE = SCALE*SQRT( SUM )
|
|
END IF
|
|
*
|
|
CLANGE = VALUE
|
|
RETURN
|
|
*
|
|
* End of CLANGE
|
|
*
|
|
END
|