1373 lines
44 KiB
Fortran
1373 lines
44 KiB
Fortran
*> \brief \b SHGEQZ
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
*> \htmlonly
|
|
*> Download SHGEQZ + dependencies
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/shgeqz.f">
|
|
*> [TGZ]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/shgeqz.f">
|
|
*> [ZIP]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/shgeqz.f">
|
|
*> [TXT]</a>
|
|
*> \endhtmlonly
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* SUBROUTINE SHGEQZ( JOB, COMPQ, COMPZ, N, ILO, IHI, H, LDH, T, LDT,
|
|
* ALPHAR, ALPHAI, BETA, Q, LDQ, Z, LDZ, WORK,
|
|
* LWORK, INFO )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* CHARACTER COMPQ, COMPZ, JOB
|
|
* INTEGER IHI, ILO, INFO, LDH, LDQ, LDT, LDZ, LWORK, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* REAL ALPHAI( * ), ALPHAR( * ), BETA( * ),
|
|
* $ H( LDH, * ), Q( LDQ, * ), T( LDT, * ),
|
|
* $ WORK( * ), Z( LDZ, * )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> SHGEQZ computes the eigenvalues of a real matrix pair (H,T),
|
|
*> where H is an upper Hessenberg matrix and T is upper triangular,
|
|
*> using the double-shift QZ method.
|
|
*> Matrix pairs of this type are produced by the reduction to
|
|
*> generalized upper Hessenberg form of a real matrix pair (A,B):
|
|
*>
|
|
*> A = Q1*H*Z1**T, B = Q1*T*Z1**T,
|
|
*>
|
|
*> as computed by SGGHRD.
|
|
*>
|
|
*> If JOB='S', then the Hessenberg-triangular pair (H,T) is
|
|
*> also reduced to generalized Schur form,
|
|
*>
|
|
*> H = Q*S*Z**T, T = Q*P*Z**T,
|
|
*>
|
|
*> where Q and Z are orthogonal matrices, P is an upper triangular
|
|
*> matrix, and S is a quasi-triangular matrix with 1-by-1 and 2-by-2
|
|
*> diagonal blocks.
|
|
*>
|
|
*> The 1-by-1 blocks correspond to real eigenvalues of the matrix pair
|
|
*> (H,T) and the 2-by-2 blocks correspond to complex conjugate pairs of
|
|
*> eigenvalues.
|
|
*>
|
|
*> Additionally, the 2-by-2 upper triangular diagonal blocks of P
|
|
*> corresponding to 2-by-2 blocks of S are reduced to positive diagonal
|
|
*> form, i.e., if S(j+1,j) is non-zero, then P(j+1,j) = P(j,j+1) = 0,
|
|
*> P(j,j) > 0, and P(j+1,j+1) > 0.
|
|
*>
|
|
*> Optionally, the orthogonal matrix Q from the generalized Schur
|
|
*> factorization may be postmultiplied into an input matrix Q1, and the
|
|
*> orthogonal matrix Z may be postmultiplied into an input matrix Z1.
|
|
*> If Q1 and Z1 are the orthogonal matrices from SGGHRD that reduced
|
|
*> the matrix pair (A,B) to generalized upper Hessenberg form, then the
|
|
*> output matrices Q1*Q and Z1*Z are the orthogonal factors from the
|
|
*> generalized Schur factorization of (A,B):
|
|
*>
|
|
*> A = (Q1*Q)*S*(Z1*Z)**T, B = (Q1*Q)*P*(Z1*Z)**T.
|
|
*>
|
|
*> To avoid overflow, eigenvalues of the matrix pair (H,T) (equivalently,
|
|
*> of (A,B)) are computed as a pair of values (alpha,beta), where alpha is
|
|
*> complex and beta real.
|
|
*> If beta is nonzero, lambda = alpha / beta is an eigenvalue of the
|
|
*> generalized nonsymmetric eigenvalue problem (GNEP)
|
|
*> A*x = lambda*B*x
|
|
*> and if alpha is nonzero, mu = beta / alpha is an eigenvalue of the
|
|
*> alternate form of the GNEP
|
|
*> mu*A*y = B*y.
|
|
*> Real eigenvalues can be read directly from the generalized Schur
|
|
*> form:
|
|
*> alpha = S(i,i), beta = P(i,i).
|
|
*>
|
|
*> Ref: C.B. Moler & G.W. Stewart, "An Algorithm for Generalized Matrix
|
|
*> Eigenvalue Problems", SIAM J. Numer. Anal., 10(1973),
|
|
*> pp. 241--256.
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] JOB
|
|
*> \verbatim
|
|
*> JOB is CHARACTER*1
|
|
*> = 'E': Compute eigenvalues only;
|
|
*> = 'S': Compute eigenvalues and the Schur form.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] COMPQ
|
|
*> \verbatim
|
|
*> COMPQ is CHARACTER*1
|
|
*> = 'N': Left Schur vectors (Q) are not computed;
|
|
*> = 'I': Q is initialized to the unit matrix and the matrix Q
|
|
*> of left Schur vectors of (H,T) is returned;
|
|
*> = 'V': Q must contain an orthogonal matrix Q1 on entry and
|
|
*> the product Q1*Q is returned.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] COMPZ
|
|
*> \verbatim
|
|
*> COMPZ is CHARACTER*1
|
|
*> = 'N': Right Schur vectors (Z) are not computed;
|
|
*> = 'I': Z is initialized to the unit matrix and the matrix Z
|
|
*> of right Schur vectors of (H,T) is returned;
|
|
*> = 'V': Z must contain an orthogonal matrix Z1 on entry and
|
|
*> the product Z1*Z is returned.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The order of the matrices H, T, Q, and Z. N >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] ILO
|
|
*> \verbatim
|
|
*> ILO is INTEGER
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] IHI
|
|
*> \verbatim
|
|
*> IHI is INTEGER
|
|
*> ILO and IHI mark the rows and columns of H which are in
|
|
*> Hessenberg form. It is assumed that A is already upper
|
|
*> triangular in rows and columns 1:ILO-1 and IHI+1:N.
|
|
*> If N > 0, 1 <= ILO <= IHI <= N; if N = 0, ILO=1 and IHI=0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in,out] H
|
|
*> \verbatim
|
|
*> H is REAL array, dimension (LDH, N)
|
|
*> On entry, the N-by-N upper Hessenberg matrix H.
|
|
*> On exit, if JOB = 'S', H contains the upper quasi-triangular
|
|
*> matrix S from the generalized Schur factorization.
|
|
*> If JOB = 'E', the diagonal blocks of H match those of S, but
|
|
*> the rest of H is unspecified.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDH
|
|
*> \verbatim
|
|
*> LDH is INTEGER
|
|
*> The leading dimension of the array H. LDH >= max( 1, N ).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in,out] T
|
|
*> \verbatim
|
|
*> T is REAL array, dimension (LDT, N)
|
|
*> On entry, the N-by-N upper triangular matrix T.
|
|
*> On exit, if JOB = 'S', T contains the upper triangular
|
|
*> matrix P from the generalized Schur factorization;
|
|
*> 2-by-2 diagonal blocks of P corresponding to 2-by-2 blocks of S
|
|
*> are reduced to positive diagonal form, i.e., if H(j+1,j) is
|
|
*> non-zero, then T(j+1,j) = T(j,j+1) = 0, T(j,j) > 0, and
|
|
*> T(j+1,j+1) > 0.
|
|
*> If JOB = 'E', the diagonal blocks of T match those of P, but
|
|
*> the rest of T is unspecified.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDT
|
|
*> \verbatim
|
|
*> LDT is INTEGER
|
|
*> The leading dimension of the array T. LDT >= max( 1, N ).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] ALPHAR
|
|
*> \verbatim
|
|
*> ALPHAR is REAL array, dimension (N)
|
|
*> The real parts of each scalar alpha defining an eigenvalue
|
|
*> of GNEP.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] ALPHAI
|
|
*> \verbatim
|
|
*> ALPHAI is REAL array, dimension (N)
|
|
*> The imaginary parts of each scalar alpha defining an
|
|
*> eigenvalue of GNEP.
|
|
*> If ALPHAI(j) is zero, then the j-th eigenvalue is real; if
|
|
*> positive, then the j-th and (j+1)-st eigenvalues are a
|
|
*> complex conjugate pair, with ALPHAI(j+1) = -ALPHAI(j).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] BETA
|
|
*> \verbatim
|
|
*> BETA is REAL array, dimension (N)
|
|
*> The scalars beta that define the eigenvalues of GNEP.
|
|
*> Together, the quantities alpha = (ALPHAR(j),ALPHAI(j)) and
|
|
*> beta = BETA(j) represent the j-th eigenvalue of the matrix
|
|
*> pair (A,B), in one of the forms lambda = alpha/beta or
|
|
*> mu = beta/alpha. Since either lambda or mu may overflow,
|
|
*> they should not, in general, be computed.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in,out] Q
|
|
*> \verbatim
|
|
*> Q is REAL array, dimension (LDQ, N)
|
|
*> On entry, if COMPQ = 'V', the orthogonal matrix Q1 used in
|
|
*> the reduction of (A,B) to generalized Hessenberg form.
|
|
*> On exit, if COMPQ = 'I', the orthogonal matrix of left Schur
|
|
*> vectors of (H,T), and if COMPQ = 'V', the orthogonal matrix
|
|
*> of left Schur vectors of (A,B).
|
|
*> Not referenced if COMPQ = 'N'.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDQ
|
|
*> \verbatim
|
|
*> LDQ is INTEGER
|
|
*> The leading dimension of the array Q. LDQ >= 1.
|
|
*> If COMPQ='V' or 'I', then LDQ >= N.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in,out] Z
|
|
*> \verbatim
|
|
*> Z is REAL array, dimension (LDZ, N)
|
|
*> On entry, if COMPZ = 'V', the orthogonal matrix Z1 used in
|
|
*> the reduction of (A,B) to generalized Hessenberg form.
|
|
*> On exit, if COMPZ = 'I', the orthogonal matrix of
|
|
*> right Schur vectors of (H,T), and if COMPZ = 'V', the
|
|
*> orthogonal matrix of right Schur vectors of (A,B).
|
|
*> Not referenced if COMPZ = 'N'.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDZ
|
|
*> \verbatim
|
|
*> LDZ is INTEGER
|
|
*> The leading dimension of the array Z. LDZ >= 1.
|
|
*> If COMPZ='V' or 'I', then LDZ >= N.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] WORK
|
|
*> \verbatim
|
|
*> WORK is REAL array, dimension (MAX(1,LWORK))
|
|
*> On exit, if INFO >= 0, WORK(1) returns the optimal LWORK.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LWORK
|
|
*> \verbatim
|
|
*> LWORK is INTEGER
|
|
*> The dimension of the array WORK. LWORK >= max(1,N).
|
|
*>
|
|
*> If LWORK = -1, then a workspace query is assumed; the routine
|
|
*> only calculates the optimal size of the WORK array, returns
|
|
*> this value as the first entry of the WORK array, and no error
|
|
*> message related to LWORK is issued by XERBLA.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] INFO
|
|
*> \verbatim
|
|
*> INFO is INTEGER
|
|
*> = 0: successful exit
|
|
*> < 0: if INFO = -i, the i-th argument had an illegal value
|
|
*> = 1,...,N: the QZ iteration did not converge. (H,T) is not
|
|
*> in Schur form, but ALPHAR(i), ALPHAI(i), and
|
|
*> BETA(i), i=INFO+1,...,N should be correct.
|
|
*> = N+1,...,2*N: the shift calculation failed. (H,T) is not
|
|
*> in Schur form, but ALPHAR(i), ALPHAI(i), and
|
|
*> BETA(i), i=INFO-N+1,...,N should be correct.
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \ingroup realGEcomputational
|
|
*
|
|
*> \par Further Details:
|
|
* =====================
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> Iteration counters:
|
|
*>
|
|
*> JITER -- counts iterations.
|
|
*> IITER -- counts iterations run since ILAST was last
|
|
*> changed. This is therefore reset only when a 1-by-1 or
|
|
*> 2-by-2 block deflates off the bottom.
|
|
*> \endverbatim
|
|
*>
|
|
* =====================================================================
|
|
SUBROUTINE SHGEQZ( JOB, COMPQ, COMPZ, N, ILO, IHI, H, LDH, T, LDT,
|
|
$ ALPHAR, ALPHAI, BETA, Q, LDQ, Z, LDZ, WORK,
|
|
$ LWORK, INFO )
|
|
*
|
|
* -- LAPACK computational routine --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER COMPQ, COMPZ, JOB
|
|
INTEGER IHI, ILO, INFO, LDH, LDQ, LDT, LDZ, LWORK, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
REAL ALPHAI( * ), ALPHAR( * ), BETA( * ),
|
|
$ H( LDH, * ), Q( LDQ, * ), T( LDT, * ),
|
|
$ WORK( * ), Z( LDZ, * )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
* $ SAFETY = 1.0E+0 )
|
|
REAL HALF, ZERO, ONE, SAFETY
|
|
PARAMETER ( HALF = 0.5E+0, ZERO = 0.0E+0, ONE = 1.0E+0,
|
|
$ SAFETY = 1.0E+2 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
LOGICAL ILAZR2, ILAZRO, ILPIVT, ILQ, ILSCHR, ILZ,
|
|
$ LQUERY
|
|
INTEGER ICOMPQ, ICOMPZ, IFIRST, IFRSTM, IITER, ILAST,
|
|
$ ILASTM, IN, ISCHUR, ISTART, J, JC, JCH, JITER,
|
|
$ JR, MAXIT
|
|
REAL A11, A12, A1I, A1R, A21, A22, A2I, A2R, AD11,
|
|
$ AD11L, AD12, AD12L, AD21, AD21L, AD22, AD22L,
|
|
$ AD32L, AN, ANORM, ASCALE, ATOL, B11, B1A, B1I,
|
|
$ B1R, B22, B2A, B2I, B2R, BN, BNORM, BSCALE,
|
|
$ BTOL, C, C11I, C11R, C12, C21, C22I, C22R, CL,
|
|
$ CQ, CR, CZ, ESHIFT, S, S1, S1INV, S2, SAFMAX,
|
|
$ SAFMIN, SCALE, SL, SQI, SQR, SR, SZI, SZR, T1,
|
|
$ T2, T3, TAU, TEMP, TEMP2, TEMPI, TEMPR, U1,
|
|
$ U12, U12L, U2, ULP, VS, W11, W12, W21, W22,
|
|
$ WABS, WI, WR, WR2
|
|
* ..
|
|
* .. Local Arrays ..
|
|
REAL V( 3 )
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
REAL SLAMCH, SLANHS, SLAPY2, SLAPY3
|
|
EXTERNAL LSAME, SLAMCH, SLANHS, SLAPY2, SLAPY3
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL SLAG2, SLARFG, SLARTG, SLASET, SLASV2, SROT,
|
|
$ XERBLA
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC ABS, MAX, MIN, REAL, SQRT
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Decode JOB, COMPQ, COMPZ
|
|
*
|
|
IF( LSAME( JOB, 'E' ) ) THEN
|
|
ILSCHR = .FALSE.
|
|
ISCHUR = 1
|
|
ELSE IF( LSAME( JOB, 'S' ) ) THEN
|
|
ILSCHR = .TRUE.
|
|
ISCHUR = 2
|
|
ELSE
|
|
ISCHUR = 0
|
|
END IF
|
|
*
|
|
IF( LSAME( COMPQ, 'N' ) ) THEN
|
|
ILQ = .FALSE.
|
|
ICOMPQ = 1
|
|
ELSE IF( LSAME( COMPQ, 'V' ) ) THEN
|
|
ILQ = .TRUE.
|
|
ICOMPQ = 2
|
|
ELSE IF( LSAME( COMPQ, 'I' ) ) THEN
|
|
ILQ = .TRUE.
|
|
ICOMPQ = 3
|
|
ELSE
|
|
ICOMPQ = 0
|
|
END IF
|
|
*
|
|
IF( LSAME( COMPZ, 'N' ) ) THEN
|
|
ILZ = .FALSE.
|
|
ICOMPZ = 1
|
|
ELSE IF( LSAME( COMPZ, 'V' ) ) THEN
|
|
ILZ = .TRUE.
|
|
ICOMPZ = 2
|
|
ELSE IF( LSAME( COMPZ, 'I' ) ) THEN
|
|
ILZ = .TRUE.
|
|
ICOMPZ = 3
|
|
ELSE
|
|
ICOMPZ = 0
|
|
END IF
|
|
*
|
|
* Check Argument Values
|
|
*
|
|
INFO = 0
|
|
WORK( 1 ) = MAX( 1, N )
|
|
LQUERY = ( LWORK.EQ.-1 )
|
|
IF( ISCHUR.EQ.0 ) THEN
|
|
INFO = -1
|
|
ELSE IF( ICOMPQ.EQ.0 ) THEN
|
|
INFO = -2
|
|
ELSE IF( ICOMPZ.EQ.0 ) THEN
|
|
INFO = -3
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -4
|
|
ELSE IF( ILO.LT.1 ) THEN
|
|
INFO = -5
|
|
ELSE IF( IHI.GT.N .OR. IHI.LT.ILO-1 ) THEN
|
|
INFO = -6
|
|
ELSE IF( LDH.LT.N ) THEN
|
|
INFO = -8
|
|
ELSE IF( LDT.LT.N ) THEN
|
|
INFO = -10
|
|
ELSE IF( LDQ.LT.1 .OR. ( ILQ .AND. LDQ.LT.N ) ) THEN
|
|
INFO = -15
|
|
ELSE IF( LDZ.LT.1 .OR. ( ILZ .AND. LDZ.LT.N ) ) THEN
|
|
INFO = -17
|
|
ELSE IF( LWORK.LT.MAX( 1, N ) .AND. .NOT.LQUERY ) THEN
|
|
INFO = -19
|
|
END IF
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'SHGEQZ', -INFO )
|
|
RETURN
|
|
ELSE IF( LQUERY ) THEN
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Quick return if possible
|
|
*
|
|
IF( N.LE.0 ) THEN
|
|
WORK( 1 ) = REAL( 1 )
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Initialize Q and Z
|
|
*
|
|
IF( ICOMPQ.EQ.3 )
|
|
$ CALL SLASET( 'Full', N, N, ZERO, ONE, Q, LDQ )
|
|
IF( ICOMPZ.EQ.3 )
|
|
$ CALL SLASET( 'Full', N, N, ZERO, ONE, Z, LDZ )
|
|
*
|
|
* Machine Constants
|
|
*
|
|
IN = IHI + 1 - ILO
|
|
SAFMIN = SLAMCH( 'S' )
|
|
SAFMAX = ONE / SAFMIN
|
|
ULP = SLAMCH( 'E' )*SLAMCH( 'B' )
|
|
ANORM = SLANHS( 'F', IN, H( ILO, ILO ), LDH, WORK )
|
|
BNORM = SLANHS( 'F', IN, T( ILO, ILO ), LDT, WORK )
|
|
ATOL = MAX( SAFMIN, ULP*ANORM )
|
|
BTOL = MAX( SAFMIN, ULP*BNORM )
|
|
ASCALE = ONE / MAX( SAFMIN, ANORM )
|
|
BSCALE = ONE / MAX( SAFMIN, BNORM )
|
|
*
|
|
* Set Eigenvalues IHI+1:N
|
|
*
|
|
DO 30 J = IHI + 1, N
|
|
IF( T( J, J ).LT.ZERO ) THEN
|
|
IF( ILSCHR ) THEN
|
|
DO 10 JR = 1, J
|
|
H( JR, J ) = -H( JR, J )
|
|
T( JR, J ) = -T( JR, J )
|
|
10 CONTINUE
|
|
ELSE
|
|
H( J, J ) = -H( J, J )
|
|
T( J, J ) = -T( J, J )
|
|
END IF
|
|
IF( ILZ ) THEN
|
|
DO 20 JR = 1, N
|
|
Z( JR, J ) = -Z( JR, J )
|
|
20 CONTINUE
|
|
END IF
|
|
END IF
|
|
ALPHAR( J ) = H( J, J )
|
|
ALPHAI( J ) = ZERO
|
|
BETA( J ) = T( J, J )
|
|
30 CONTINUE
|
|
*
|
|
* If IHI < ILO, skip QZ steps
|
|
*
|
|
IF( IHI.LT.ILO )
|
|
$ GO TO 380
|
|
*
|
|
* MAIN QZ ITERATION LOOP
|
|
*
|
|
* Initialize dynamic indices
|
|
*
|
|
* Eigenvalues ILAST+1:N have been found.
|
|
* Column operations modify rows IFRSTM:whatever.
|
|
* Row operations modify columns whatever:ILASTM.
|
|
*
|
|
* If only eigenvalues are being computed, then
|
|
* IFRSTM is the row of the last splitting row above row ILAST;
|
|
* this is always at least ILO.
|
|
* IITER counts iterations since the last eigenvalue was found,
|
|
* to tell when to use an extraordinary shift.
|
|
* MAXIT is the maximum number of QZ sweeps allowed.
|
|
*
|
|
ILAST = IHI
|
|
IF( ILSCHR ) THEN
|
|
IFRSTM = 1
|
|
ILASTM = N
|
|
ELSE
|
|
IFRSTM = ILO
|
|
ILASTM = IHI
|
|
END IF
|
|
IITER = 0
|
|
ESHIFT = ZERO
|
|
MAXIT = 30*( IHI-ILO+1 )
|
|
*
|
|
DO 360 JITER = 1, MAXIT
|
|
*
|
|
* Split the matrix if possible.
|
|
*
|
|
* Two tests:
|
|
* 1: H(j,j-1)=0 or j=ILO
|
|
* 2: T(j,j)=0
|
|
*
|
|
IF( ILAST.EQ.ILO ) THEN
|
|
*
|
|
* Special case: j=ILAST
|
|
*
|
|
GO TO 80
|
|
ELSE
|
|
IF( ABS( H( ILAST, ILAST-1 ) ).LE.MAX( SAFMIN, ULP*(
|
|
$ ABS( H( ILAST, ILAST ) ) + ABS( H( ILAST-1, ILAST-1 ) )
|
|
$ ) ) ) THEN
|
|
H( ILAST, ILAST-1 ) = ZERO
|
|
GO TO 80
|
|
END IF
|
|
END IF
|
|
*
|
|
IF( ABS( T( ILAST, ILAST ) ).LE.BTOL ) THEN
|
|
T( ILAST, ILAST ) = ZERO
|
|
GO TO 70
|
|
END IF
|
|
*
|
|
* General case: j<ILAST
|
|
*
|
|
DO 60 J = ILAST - 1, ILO, -1
|
|
*
|
|
* Test 1: for H(j,j-1)=0 or j=ILO
|
|
*
|
|
IF( J.EQ.ILO ) THEN
|
|
ILAZRO = .TRUE.
|
|
ELSE
|
|
IF( ABS( H( J, J-1 ) ).LE.MAX( SAFMIN, ULP*(
|
|
$ ABS( H( J, J ) ) + ABS( H( J-1, J-1 ) )
|
|
$ ) ) ) THEN
|
|
H( J, J-1 ) = ZERO
|
|
ILAZRO = .TRUE.
|
|
ELSE
|
|
ILAZRO = .FALSE.
|
|
END IF
|
|
END IF
|
|
*
|
|
* Test 2: for T(j,j)=0
|
|
*
|
|
IF( ABS( T( J, J ) ).LT.BTOL ) THEN
|
|
T( J, J ) = ZERO
|
|
*
|
|
* Test 1a: Check for 2 consecutive small subdiagonals in A
|
|
*
|
|
ILAZR2 = .FALSE.
|
|
IF( .NOT.ILAZRO ) THEN
|
|
TEMP = ABS( H( J, J-1 ) )
|
|
TEMP2 = ABS( H( J, J ) )
|
|
TEMPR = MAX( TEMP, TEMP2 )
|
|
IF( TEMPR.LT.ONE .AND. TEMPR.NE.ZERO ) THEN
|
|
TEMP = TEMP / TEMPR
|
|
TEMP2 = TEMP2 / TEMPR
|
|
END IF
|
|
IF( TEMP*( ASCALE*ABS( H( J+1, J ) ) ).LE.TEMP2*
|
|
$ ( ASCALE*ATOL ) )ILAZR2 = .TRUE.
|
|
END IF
|
|
*
|
|
* If both tests pass (1 & 2), i.e., the leading diagonal
|
|
* element of B in the block is zero, split a 1x1 block off
|
|
* at the top. (I.e., at the J-th row/column) The leading
|
|
* diagonal element of the remainder can also be zero, so
|
|
* this may have to be done repeatedly.
|
|
*
|
|
IF( ILAZRO .OR. ILAZR2 ) THEN
|
|
DO 40 JCH = J, ILAST - 1
|
|
TEMP = H( JCH, JCH )
|
|
CALL SLARTG( TEMP, H( JCH+1, JCH ), C, S,
|
|
$ H( JCH, JCH ) )
|
|
H( JCH+1, JCH ) = ZERO
|
|
CALL SROT( ILASTM-JCH, H( JCH, JCH+1 ), LDH,
|
|
$ H( JCH+1, JCH+1 ), LDH, C, S )
|
|
CALL SROT( ILASTM-JCH, T( JCH, JCH+1 ), LDT,
|
|
$ T( JCH+1, JCH+1 ), LDT, C, S )
|
|
IF( ILQ )
|
|
$ CALL SROT( N, Q( 1, JCH ), 1, Q( 1, JCH+1 ), 1,
|
|
$ C, S )
|
|
IF( ILAZR2 )
|
|
$ H( JCH, JCH-1 ) = H( JCH, JCH-1 )*C
|
|
ILAZR2 = .FALSE.
|
|
IF( ABS( T( JCH+1, JCH+1 ) ).GE.BTOL ) THEN
|
|
IF( JCH+1.GE.ILAST ) THEN
|
|
GO TO 80
|
|
ELSE
|
|
IFIRST = JCH + 1
|
|
GO TO 110
|
|
END IF
|
|
END IF
|
|
T( JCH+1, JCH+1 ) = ZERO
|
|
40 CONTINUE
|
|
GO TO 70
|
|
ELSE
|
|
*
|
|
* Only test 2 passed -- chase the zero to T(ILAST,ILAST)
|
|
* Then process as in the case T(ILAST,ILAST)=0
|
|
*
|
|
DO 50 JCH = J, ILAST - 1
|
|
TEMP = T( JCH, JCH+1 )
|
|
CALL SLARTG( TEMP, T( JCH+1, JCH+1 ), C, S,
|
|
$ T( JCH, JCH+1 ) )
|
|
T( JCH+1, JCH+1 ) = ZERO
|
|
IF( JCH.LT.ILASTM-1 )
|
|
$ CALL SROT( ILASTM-JCH-1, T( JCH, JCH+2 ), LDT,
|
|
$ T( JCH+1, JCH+2 ), LDT, C, S )
|
|
CALL SROT( ILASTM-JCH+2, H( JCH, JCH-1 ), LDH,
|
|
$ H( JCH+1, JCH-1 ), LDH, C, S )
|
|
IF( ILQ )
|
|
$ CALL SROT( N, Q( 1, JCH ), 1, Q( 1, JCH+1 ), 1,
|
|
$ C, S )
|
|
TEMP = H( JCH+1, JCH )
|
|
CALL SLARTG( TEMP, H( JCH+1, JCH-1 ), C, S,
|
|
$ H( JCH+1, JCH ) )
|
|
H( JCH+1, JCH-1 ) = ZERO
|
|
CALL SROT( JCH+1-IFRSTM, H( IFRSTM, JCH ), 1,
|
|
$ H( IFRSTM, JCH-1 ), 1, C, S )
|
|
CALL SROT( JCH-IFRSTM, T( IFRSTM, JCH ), 1,
|
|
$ T( IFRSTM, JCH-1 ), 1, C, S )
|
|
IF( ILZ )
|
|
$ CALL SROT( N, Z( 1, JCH ), 1, Z( 1, JCH-1 ), 1,
|
|
$ C, S )
|
|
50 CONTINUE
|
|
GO TO 70
|
|
END IF
|
|
ELSE IF( ILAZRO ) THEN
|
|
*
|
|
* Only test 1 passed -- work on J:ILAST
|
|
*
|
|
IFIRST = J
|
|
GO TO 110
|
|
END IF
|
|
*
|
|
* Neither test passed -- try next J
|
|
*
|
|
60 CONTINUE
|
|
*
|
|
* (Drop-through is "impossible")
|
|
*
|
|
INFO = N + 1
|
|
GO TO 420
|
|
*
|
|
* T(ILAST,ILAST)=0 -- clear H(ILAST,ILAST-1) to split off a
|
|
* 1x1 block.
|
|
*
|
|
70 CONTINUE
|
|
TEMP = H( ILAST, ILAST )
|
|
CALL SLARTG( TEMP, H( ILAST, ILAST-1 ), C, S,
|
|
$ H( ILAST, ILAST ) )
|
|
H( ILAST, ILAST-1 ) = ZERO
|
|
CALL SROT( ILAST-IFRSTM, H( IFRSTM, ILAST ), 1,
|
|
$ H( IFRSTM, ILAST-1 ), 1, C, S )
|
|
CALL SROT( ILAST-IFRSTM, T( IFRSTM, ILAST ), 1,
|
|
$ T( IFRSTM, ILAST-1 ), 1, C, S )
|
|
IF( ILZ )
|
|
$ CALL SROT( N, Z( 1, ILAST ), 1, Z( 1, ILAST-1 ), 1, C, S )
|
|
*
|
|
* H(ILAST,ILAST-1)=0 -- Standardize B, set ALPHAR, ALPHAI,
|
|
* and BETA
|
|
*
|
|
80 CONTINUE
|
|
IF( T( ILAST, ILAST ).LT.ZERO ) THEN
|
|
IF( ILSCHR ) THEN
|
|
DO 90 J = IFRSTM, ILAST
|
|
H( J, ILAST ) = -H( J, ILAST )
|
|
T( J, ILAST ) = -T( J, ILAST )
|
|
90 CONTINUE
|
|
ELSE
|
|
H( ILAST, ILAST ) = -H( ILAST, ILAST )
|
|
T( ILAST, ILAST ) = -T( ILAST, ILAST )
|
|
END IF
|
|
IF( ILZ ) THEN
|
|
DO 100 J = 1, N
|
|
Z( J, ILAST ) = -Z( J, ILAST )
|
|
100 CONTINUE
|
|
END IF
|
|
END IF
|
|
ALPHAR( ILAST ) = H( ILAST, ILAST )
|
|
ALPHAI( ILAST ) = ZERO
|
|
BETA( ILAST ) = T( ILAST, ILAST )
|
|
*
|
|
* Go to next block -- exit if finished.
|
|
*
|
|
ILAST = ILAST - 1
|
|
IF( ILAST.LT.ILO )
|
|
$ GO TO 380
|
|
*
|
|
* Reset counters
|
|
*
|
|
IITER = 0
|
|
ESHIFT = ZERO
|
|
IF( .NOT.ILSCHR ) THEN
|
|
ILASTM = ILAST
|
|
IF( IFRSTM.GT.ILAST )
|
|
$ IFRSTM = ILO
|
|
END IF
|
|
GO TO 350
|
|
*
|
|
* QZ step
|
|
*
|
|
* This iteration only involves rows/columns IFIRST:ILAST. We
|
|
* assume IFIRST < ILAST, and that the diagonal of B is non-zero.
|
|
*
|
|
110 CONTINUE
|
|
IITER = IITER + 1
|
|
IF( .NOT.ILSCHR ) THEN
|
|
IFRSTM = IFIRST
|
|
END IF
|
|
*
|
|
* Compute single shifts.
|
|
*
|
|
* At this point, IFIRST < ILAST, and the diagonal elements of
|
|
* T(IFIRST:ILAST,IFIRST,ILAST) are larger than BTOL (in
|
|
* magnitude)
|
|
*
|
|
IF( ( IITER / 10 )*10.EQ.IITER ) THEN
|
|
*
|
|
* Exceptional shift. Chosen for no particularly good reason.
|
|
* (Single shift only.)
|
|
*
|
|
IF( ( REAL( MAXIT )*SAFMIN )*ABS( H( ILAST, ILAST-1 ) ).LT.
|
|
$ ABS( T( ILAST-1, ILAST-1 ) ) ) THEN
|
|
ESHIFT = H( ILAST, ILAST-1 ) /
|
|
$ T( ILAST-1, ILAST-1 )
|
|
ELSE
|
|
ESHIFT = ESHIFT + ONE / ( SAFMIN*REAL( MAXIT ) )
|
|
END IF
|
|
S1 = ONE
|
|
WR = ESHIFT
|
|
*
|
|
ELSE
|
|
*
|
|
* Shifts based on the generalized eigenvalues of the
|
|
* bottom-right 2x2 block of A and B. The first eigenvalue
|
|
* returned by SLAG2 is the Wilkinson shift (AEP p.512),
|
|
*
|
|
CALL SLAG2( H( ILAST-1, ILAST-1 ), LDH,
|
|
$ T( ILAST-1, ILAST-1 ), LDT, SAFMIN*SAFETY, S1,
|
|
$ S2, WR, WR2, WI )
|
|
*
|
|
IF ( ABS( (WR/S1)*T( ILAST, ILAST ) - H( ILAST, ILAST ) )
|
|
$ .GT. ABS( (WR2/S2)*T( ILAST, ILAST )
|
|
$ - H( ILAST, ILAST ) ) ) THEN
|
|
TEMP = WR
|
|
WR = WR2
|
|
WR2 = TEMP
|
|
TEMP = S1
|
|
S1 = S2
|
|
S2 = TEMP
|
|
END IF
|
|
TEMP = MAX( S1, SAFMIN*MAX( ONE, ABS( WR ), ABS( WI ) ) )
|
|
IF( WI.NE.ZERO )
|
|
$ GO TO 200
|
|
END IF
|
|
*
|
|
* Fiddle with shift to avoid overflow
|
|
*
|
|
TEMP = MIN( ASCALE, ONE )*( HALF*SAFMAX )
|
|
IF( S1.GT.TEMP ) THEN
|
|
SCALE = TEMP / S1
|
|
ELSE
|
|
SCALE = ONE
|
|
END IF
|
|
*
|
|
TEMP = MIN( BSCALE, ONE )*( HALF*SAFMAX )
|
|
IF( ABS( WR ).GT.TEMP )
|
|
$ SCALE = MIN( SCALE, TEMP / ABS( WR ) )
|
|
S1 = SCALE*S1
|
|
WR = SCALE*WR
|
|
*
|
|
* Now check for two consecutive small subdiagonals.
|
|
*
|
|
DO 120 J = ILAST - 1, IFIRST + 1, -1
|
|
ISTART = J
|
|
TEMP = ABS( S1*H( J, J-1 ) )
|
|
TEMP2 = ABS( S1*H( J, J )-WR*T( J, J ) )
|
|
TEMPR = MAX( TEMP, TEMP2 )
|
|
IF( TEMPR.LT.ONE .AND. TEMPR.NE.ZERO ) THEN
|
|
TEMP = TEMP / TEMPR
|
|
TEMP2 = TEMP2 / TEMPR
|
|
END IF
|
|
IF( ABS( ( ASCALE*H( J+1, J ) )*TEMP ).LE.( ASCALE*ATOL )*
|
|
$ TEMP2 )GO TO 130
|
|
120 CONTINUE
|
|
*
|
|
ISTART = IFIRST
|
|
130 CONTINUE
|
|
*
|
|
* Do an implicit single-shift QZ sweep.
|
|
*
|
|
* Initial Q
|
|
*
|
|
TEMP = S1*H( ISTART, ISTART ) - WR*T( ISTART, ISTART )
|
|
TEMP2 = S1*H( ISTART+1, ISTART )
|
|
CALL SLARTG( TEMP, TEMP2, C, S, TEMPR )
|
|
*
|
|
* Sweep
|
|
*
|
|
DO 190 J = ISTART, ILAST - 1
|
|
IF( J.GT.ISTART ) THEN
|
|
TEMP = H( J, J-1 )
|
|
CALL SLARTG( TEMP, H( J+1, J-1 ), C, S, H( J, J-1 ) )
|
|
H( J+1, J-1 ) = ZERO
|
|
END IF
|
|
*
|
|
DO 140 JC = J, ILASTM
|
|
TEMP = C*H( J, JC ) + S*H( J+1, JC )
|
|
H( J+1, JC ) = -S*H( J, JC ) + C*H( J+1, JC )
|
|
H( J, JC ) = TEMP
|
|
TEMP2 = C*T( J, JC ) + S*T( J+1, JC )
|
|
T( J+1, JC ) = -S*T( J, JC ) + C*T( J+1, JC )
|
|
T( J, JC ) = TEMP2
|
|
140 CONTINUE
|
|
IF( ILQ ) THEN
|
|
DO 150 JR = 1, N
|
|
TEMP = C*Q( JR, J ) + S*Q( JR, J+1 )
|
|
Q( JR, J+1 ) = -S*Q( JR, J ) + C*Q( JR, J+1 )
|
|
Q( JR, J ) = TEMP
|
|
150 CONTINUE
|
|
END IF
|
|
*
|
|
TEMP = T( J+1, J+1 )
|
|
CALL SLARTG( TEMP, T( J+1, J ), C, S, T( J+1, J+1 ) )
|
|
T( J+1, J ) = ZERO
|
|
*
|
|
DO 160 JR = IFRSTM, MIN( J+2, ILAST )
|
|
TEMP = C*H( JR, J+1 ) + S*H( JR, J )
|
|
H( JR, J ) = -S*H( JR, J+1 ) + C*H( JR, J )
|
|
H( JR, J+1 ) = TEMP
|
|
160 CONTINUE
|
|
DO 170 JR = IFRSTM, J
|
|
TEMP = C*T( JR, J+1 ) + S*T( JR, J )
|
|
T( JR, J ) = -S*T( JR, J+1 ) + C*T( JR, J )
|
|
T( JR, J+1 ) = TEMP
|
|
170 CONTINUE
|
|
IF( ILZ ) THEN
|
|
DO 180 JR = 1, N
|
|
TEMP = C*Z( JR, J+1 ) + S*Z( JR, J )
|
|
Z( JR, J ) = -S*Z( JR, J+1 ) + C*Z( JR, J )
|
|
Z( JR, J+1 ) = TEMP
|
|
180 CONTINUE
|
|
END IF
|
|
190 CONTINUE
|
|
*
|
|
GO TO 350
|
|
*
|
|
* Use Francis double-shift
|
|
*
|
|
* Note: the Francis double-shift should work with real shifts,
|
|
* but only if the block is at least 3x3.
|
|
* This code may break if this point is reached with
|
|
* a 2x2 block with real eigenvalues.
|
|
*
|
|
200 CONTINUE
|
|
IF( IFIRST+1.EQ.ILAST ) THEN
|
|
*
|
|
* Special case -- 2x2 block with complex eigenvectors
|
|
*
|
|
* Step 1: Standardize, that is, rotate so that
|
|
*
|
|
* ( B11 0 )
|
|
* B = ( ) with B11 non-negative.
|
|
* ( 0 B22 )
|
|
*
|
|
CALL SLASV2( T( ILAST-1, ILAST-1 ), T( ILAST-1, ILAST ),
|
|
$ T( ILAST, ILAST ), B22, B11, SR, CR, SL, CL )
|
|
*
|
|
IF( B11.LT.ZERO ) THEN
|
|
CR = -CR
|
|
SR = -SR
|
|
B11 = -B11
|
|
B22 = -B22
|
|
END IF
|
|
*
|
|
CALL SROT( ILASTM+1-IFIRST, H( ILAST-1, ILAST-1 ), LDH,
|
|
$ H( ILAST, ILAST-1 ), LDH, CL, SL )
|
|
CALL SROT( ILAST+1-IFRSTM, H( IFRSTM, ILAST-1 ), 1,
|
|
$ H( IFRSTM, ILAST ), 1, CR, SR )
|
|
*
|
|
IF( ILAST.LT.ILASTM )
|
|
$ CALL SROT( ILASTM-ILAST, T( ILAST-1, ILAST+1 ), LDT,
|
|
$ T( ILAST, ILAST+1 ), LDT, CL, SL )
|
|
IF( IFRSTM.LT.ILAST-1 )
|
|
$ CALL SROT( IFIRST-IFRSTM, T( IFRSTM, ILAST-1 ), 1,
|
|
$ T( IFRSTM, ILAST ), 1, CR, SR )
|
|
*
|
|
IF( ILQ )
|
|
$ CALL SROT( N, Q( 1, ILAST-1 ), 1, Q( 1, ILAST ), 1, CL,
|
|
$ SL )
|
|
IF( ILZ )
|
|
$ CALL SROT( N, Z( 1, ILAST-1 ), 1, Z( 1, ILAST ), 1, CR,
|
|
$ SR )
|
|
*
|
|
T( ILAST-1, ILAST-1 ) = B11
|
|
T( ILAST-1, ILAST ) = ZERO
|
|
T( ILAST, ILAST-1 ) = ZERO
|
|
T( ILAST, ILAST ) = B22
|
|
*
|
|
* If B22 is negative, negate column ILAST
|
|
*
|
|
IF( B22.LT.ZERO ) THEN
|
|
DO 210 J = IFRSTM, ILAST
|
|
H( J, ILAST ) = -H( J, ILAST )
|
|
T( J, ILAST ) = -T( J, ILAST )
|
|
210 CONTINUE
|
|
*
|
|
IF( ILZ ) THEN
|
|
DO 220 J = 1, N
|
|
Z( J, ILAST ) = -Z( J, ILAST )
|
|
220 CONTINUE
|
|
END IF
|
|
B22 = -B22
|
|
END IF
|
|
*
|
|
* Step 2: Compute ALPHAR, ALPHAI, and BETA (see refs.)
|
|
*
|
|
* Recompute shift
|
|
*
|
|
CALL SLAG2( H( ILAST-1, ILAST-1 ), LDH,
|
|
$ T( ILAST-1, ILAST-1 ), LDT, SAFMIN*SAFETY, S1,
|
|
$ TEMP, WR, TEMP2, WI )
|
|
*
|
|
* If standardization has perturbed the shift onto real line,
|
|
* do another (real single-shift) QR step.
|
|
*
|
|
IF( WI.EQ.ZERO )
|
|
$ GO TO 350
|
|
S1INV = ONE / S1
|
|
*
|
|
* Do EISPACK (QZVAL) computation of alpha and beta
|
|
*
|
|
A11 = H( ILAST-1, ILAST-1 )
|
|
A21 = H( ILAST, ILAST-1 )
|
|
A12 = H( ILAST-1, ILAST )
|
|
A22 = H( ILAST, ILAST )
|
|
*
|
|
* Compute complex Givens rotation on right
|
|
* (Assume some element of C = (sA - wB) > unfl )
|
|
* __
|
|
* (sA - wB) ( CZ -SZ )
|
|
* ( SZ CZ )
|
|
*
|
|
C11R = S1*A11 - WR*B11
|
|
C11I = -WI*B11
|
|
C12 = S1*A12
|
|
C21 = S1*A21
|
|
C22R = S1*A22 - WR*B22
|
|
C22I = -WI*B22
|
|
*
|
|
IF( ABS( C11R )+ABS( C11I )+ABS( C12 ).GT.ABS( C21 )+
|
|
$ ABS( C22R )+ABS( C22I ) ) THEN
|
|
T1 = SLAPY3( C12, C11R, C11I )
|
|
CZ = C12 / T1
|
|
SZR = -C11R / T1
|
|
SZI = -C11I / T1
|
|
ELSE
|
|
CZ = SLAPY2( C22R, C22I )
|
|
IF( CZ.LE.SAFMIN ) THEN
|
|
CZ = ZERO
|
|
SZR = ONE
|
|
SZI = ZERO
|
|
ELSE
|
|
TEMPR = C22R / CZ
|
|
TEMPI = C22I / CZ
|
|
T1 = SLAPY2( CZ, C21 )
|
|
CZ = CZ / T1
|
|
SZR = -C21*TEMPR / T1
|
|
SZI = C21*TEMPI / T1
|
|
END IF
|
|
END IF
|
|
*
|
|
* Compute Givens rotation on left
|
|
*
|
|
* ( CQ SQ )
|
|
* ( __ ) A or B
|
|
* ( -SQ CQ )
|
|
*
|
|
AN = ABS( A11 ) + ABS( A12 ) + ABS( A21 ) + ABS( A22 )
|
|
BN = ABS( B11 ) + ABS( B22 )
|
|
WABS = ABS( WR ) + ABS( WI )
|
|
IF( S1*AN.GT.WABS*BN ) THEN
|
|
CQ = CZ*B11
|
|
SQR = SZR*B22
|
|
SQI = -SZI*B22
|
|
ELSE
|
|
A1R = CZ*A11 + SZR*A12
|
|
A1I = SZI*A12
|
|
A2R = CZ*A21 + SZR*A22
|
|
A2I = SZI*A22
|
|
CQ = SLAPY2( A1R, A1I )
|
|
IF( CQ.LE.SAFMIN ) THEN
|
|
CQ = ZERO
|
|
SQR = ONE
|
|
SQI = ZERO
|
|
ELSE
|
|
TEMPR = A1R / CQ
|
|
TEMPI = A1I / CQ
|
|
SQR = TEMPR*A2R + TEMPI*A2I
|
|
SQI = TEMPI*A2R - TEMPR*A2I
|
|
END IF
|
|
END IF
|
|
T1 = SLAPY3( CQ, SQR, SQI )
|
|
CQ = CQ / T1
|
|
SQR = SQR / T1
|
|
SQI = SQI / T1
|
|
*
|
|
* Compute diagonal elements of QBZ
|
|
*
|
|
TEMPR = SQR*SZR - SQI*SZI
|
|
TEMPI = SQR*SZI + SQI*SZR
|
|
B1R = CQ*CZ*B11 + TEMPR*B22
|
|
B1I = TEMPI*B22
|
|
B1A = SLAPY2( B1R, B1I )
|
|
B2R = CQ*CZ*B22 + TEMPR*B11
|
|
B2I = -TEMPI*B11
|
|
B2A = SLAPY2( B2R, B2I )
|
|
*
|
|
* Normalize so beta > 0, and Im( alpha1 ) > 0
|
|
*
|
|
BETA( ILAST-1 ) = B1A
|
|
BETA( ILAST ) = B2A
|
|
ALPHAR( ILAST-1 ) = ( WR*B1A )*S1INV
|
|
ALPHAI( ILAST-1 ) = ( WI*B1A )*S1INV
|
|
ALPHAR( ILAST ) = ( WR*B2A )*S1INV
|
|
ALPHAI( ILAST ) = -( WI*B2A )*S1INV
|
|
*
|
|
* Step 3: Go to next block -- exit if finished.
|
|
*
|
|
ILAST = IFIRST - 1
|
|
IF( ILAST.LT.ILO )
|
|
$ GO TO 380
|
|
*
|
|
* Reset counters
|
|
*
|
|
IITER = 0
|
|
ESHIFT = ZERO
|
|
IF( .NOT.ILSCHR ) THEN
|
|
ILASTM = ILAST
|
|
IF( IFRSTM.GT.ILAST )
|
|
$ IFRSTM = ILO
|
|
END IF
|
|
GO TO 350
|
|
ELSE
|
|
*
|
|
* Usual case: 3x3 or larger block, using Francis implicit
|
|
* double-shift
|
|
*
|
|
* 2
|
|
* Eigenvalue equation is w - c w + d = 0,
|
|
*
|
|
* -1 2 -1
|
|
* so compute 1st column of (A B ) - c A B + d
|
|
* using the formula in QZIT (from EISPACK)
|
|
*
|
|
* We assume that the block is at least 3x3
|
|
*
|
|
AD11 = ( ASCALE*H( ILAST-1, ILAST-1 ) ) /
|
|
$ ( BSCALE*T( ILAST-1, ILAST-1 ) )
|
|
AD21 = ( ASCALE*H( ILAST, ILAST-1 ) ) /
|
|
$ ( BSCALE*T( ILAST-1, ILAST-1 ) )
|
|
AD12 = ( ASCALE*H( ILAST-1, ILAST ) ) /
|
|
$ ( BSCALE*T( ILAST, ILAST ) )
|
|
AD22 = ( ASCALE*H( ILAST, ILAST ) ) /
|
|
$ ( BSCALE*T( ILAST, ILAST ) )
|
|
U12 = T( ILAST-1, ILAST ) / T( ILAST, ILAST )
|
|
AD11L = ( ASCALE*H( IFIRST, IFIRST ) ) /
|
|
$ ( BSCALE*T( IFIRST, IFIRST ) )
|
|
AD21L = ( ASCALE*H( IFIRST+1, IFIRST ) ) /
|
|
$ ( BSCALE*T( IFIRST, IFIRST ) )
|
|
AD12L = ( ASCALE*H( IFIRST, IFIRST+1 ) ) /
|
|
$ ( BSCALE*T( IFIRST+1, IFIRST+1 ) )
|
|
AD22L = ( ASCALE*H( IFIRST+1, IFIRST+1 ) ) /
|
|
$ ( BSCALE*T( IFIRST+1, IFIRST+1 ) )
|
|
AD32L = ( ASCALE*H( IFIRST+2, IFIRST+1 ) ) /
|
|
$ ( BSCALE*T( IFIRST+1, IFIRST+1 ) )
|
|
U12L = T( IFIRST, IFIRST+1 ) / T( IFIRST+1, IFIRST+1 )
|
|
*
|
|
V( 1 ) = ( AD11-AD11L )*( AD22-AD11L ) - AD12*AD21 +
|
|
$ AD21*U12*AD11L + ( AD12L-AD11L*U12L )*AD21L
|
|
V( 2 ) = ( ( AD22L-AD11L )-AD21L*U12L-( AD11-AD11L )-
|
|
$ ( AD22-AD11L )+AD21*U12 )*AD21L
|
|
V( 3 ) = AD32L*AD21L
|
|
*
|
|
ISTART = IFIRST
|
|
*
|
|
CALL SLARFG( 3, V( 1 ), V( 2 ), 1, TAU )
|
|
V( 1 ) = ONE
|
|
*
|
|
* Sweep
|
|
*
|
|
DO 290 J = ISTART, ILAST - 2
|
|
*
|
|
* All but last elements: use 3x3 Householder transforms.
|
|
*
|
|
* Zero (j-1)st column of A
|
|
*
|
|
IF( J.GT.ISTART ) THEN
|
|
V( 1 ) = H( J, J-1 )
|
|
V( 2 ) = H( J+1, J-1 )
|
|
V( 3 ) = H( J+2, J-1 )
|
|
*
|
|
CALL SLARFG( 3, H( J, J-1 ), V( 2 ), 1, TAU )
|
|
V( 1 ) = ONE
|
|
H( J+1, J-1 ) = ZERO
|
|
H( J+2, J-1 ) = ZERO
|
|
END IF
|
|
*
|
|
T2 = TAU * V( 2 )
|
|
T3 = TAU * V( 3 )
|
|
DO 230 JC = J, ILASTM
|
|
TEMP = H( J, JC )+V( 2 )*H( J+1, JC )+V( 3 )*
|
|
$ H( J+2, JC )
|
|
H( J, JC ) = H( J, JC ) - TEMP*TAU
|
|
H( J+1, JC ) = H( J+1, JC ) - TEMP*T2
|
|
H( J+2, JC ) = H( J+2, JC ) - TEMP*T3
|
|
TEMP2 = T( J, JC )+V( 2 )*T( J+1, JC )+V( 3 )*
|
|
$ T( J+2, JC )
|
|
T( J, JC ) = T( J, JC ) - TEMP2*TAU
|
|
T( J+1, JC ) = T( J+1, JC ) - TEMP2*T2
|
|
T( J+2, JC ) = T( J+2, JC ) - TEMP2*T3
|
|
230 CONTINUE
|
|
IF( ILQ ) THEN
|
|
DO 240 JR = 1, N
|
|
TEMP = Q( JR, J )+V( 2 )*Q( JR, J+1 )+V( 3 )*
|
|
$ Q( JR, J+2 )
|
|
Q( JR, J ) = Q( JR, J ) - TEMP*TAU
|
|
Q( JR, J+1 ) = Q( JR, J+1 ) - TEMP*T2
|
|
Q( JR, J+2 ) = Q( JR, J+2 ) - TEMP*T3
|
|
240 CONTINUE
|
|
END IF
|
|
*
|
|
* Zero j-th column of B (see SLAGBC for details)
|
|
*
|
|
* Swap rows to pivot
|
|
*
|
|
ILPIVT = .FALSE.
|
|
TEMP = MAX( ABS( T( J+1, J+1 ) ), ABS( T( J+1, J+2 ) ) )
|
|
TEMP2 = MAX( ABS( T( J+2, J+1 ) ), ABS( T( J+2, J+2 ) ) )
|
|
IF( MAX( TEMP, TEMP2 ).LT.SAFMIN ) THEN
|
|
SCALE = ZERO
|
|
U1 = ONE
|
|
U2 = ZERO
|
|
GO TO 250
|
|
ELSE IF( TEMP.GE.TEMP2 ) THEN
|
|
W11 = T( J+1, J+1 )
|
|
W21 = T( J+2, J+1 )
|
|
W12 = T( J+1, J+2 )
|
|
W22 = T( J+2, J+2 )
|
|
U1 = T( J+1, J )
|
|
U2 = T( J+2, J )
|
|
ELSE
|
|
W21 = T( J+1, J+1 )
|
|
W11 = T( J+2, J+1 )
|
|
W22 = T( J+1, J+2 )
|
|
W12 = T( J+2, J+2 )
|
|
U2 = T( J+1, J )
|
|
U1 = T( J+2, J )
|
|
END IF
|
|
*
|
|
* Swap columns if nec.
|
|
*
|
|
IF( ABS( W12 ).GT.ABS( W11 ) ) THEN
|
|
ILPIVT = .TRUE.
|
|
TEMP = W12
|
|
TEMP2 = W22
|
|
W12 = W11
|
|
W22 = W21
|
|
W11 = TEMP
|
|
W21 = TEMP2
|
|
END IF
|
|
*
|
|
* LU-factor
|
|
*
|
|
TEMP = W21 / W11
|
|
U2 = U2 - TEMP*U1
|
|
W22 = W22 - TEMP*W12
|
|
W21 = ZERO
|
|
*
|
|
* Compute SCALE
|
|
*
|
|
SCALE = ONE
|
|
IF( ABS( W22 ).LT.SAFMIN ) THEN
|
|
SCALE = ZERO
|
|
U2 = ONE
|
|
U1 = -W12 / W11
|
|
GO TO 250
|
|
END IF
|
|
IF( ABS( W22 ).LT.ABS( U2 ) )
|
|
$ SCALE = ABS( W22 / U2 )
|
|
IF( ABS( W11 ).LT.ABS( U1 ) )
|
|
$ SCALE = MIN( SCALE, ABS( W11 / U1 ) )
|
|
*
|
|
* Solve
|
|
*
|
|
U2 = ( SCALE*U2 ) / W22
|
|
U1 = ( SCALE*U1-W12*U2 ) / W11
|
|
*
|
|
250 CONTINUE
|
|
IF( ILPIVT ) THEN
|
|
TEMP = U2
|
|
U2 = U1
|
|
U1 = TEMP
|
|
END IF
|
|
*
|
|
* Compute Householder Vector
|
|
*
|
|
T1 = SQRT( SCALE**2+U1**2+U2**2 )
|
|
TAU = ONE + SCALE / T1
|
|
VS = -ONE / ( SCALE+T1 )
|
|
V( 1 ) = ONE
|
|
V( 2 ) = VS*U1
|
|
V( 3 ) = VS*U2
|
|
*
|
|
* Apply transformations from the right.
|
|
*
|
|
T2 = TAU*V( 2 )
|
|
T3 = TAU*V( 3 )
|
|
DO 260 JR = IFRSTM, MIN( J+3, ILAST )
|
|
TEMP = H( JR, J )+V( 2 )*H( JR, J+1 )+V( 3 )*
|
|
$ H( JR, J+2 )
|
|
H( JR, J ) = H( JR, J ) - TEMP*TAU
|
|
H( JR, J+1 ) = H( JR, J+1 ) - TEMP*T2
|
|
H( JR, J+2 ) = H( JR, J+2 ) - TEMP*T3
|
|
260 CONTINUE
|
|
DO 270 JR = IFRSTM, J + 2
|
|
TEMP = T( JR, J )+V( 2 )*T( JR, J+1 )+V( 3 )*
|
|
$ T( JR, J+2 )
|
|
T( JR, J ) = T( JR, J ) - TEMP*TAU
|
|
T( JR, J+1 ) = T( JR, J+1 ) - TEMP*T2
|
|
T( JR, J+2 ) = T( JR, J+2 ) - TEMP*T3
|
|
270 CONTINUE
|
|
IF( ILZ ) THEN
|
|
DO 280 JR = 1, N
|
|
TEMP = Z( JR, J )+V( 2 )*Z( JR, J+1 )+V( 3 )*
|
|
$ Z( JR, J+2 )
|
|
Z( JR, J ) = Z( JR, J ) - TEMP*TAU
|
|
Z( JR, J+1 ) = Z( JR, J+1 ) - TEMP*T2
|
|
Z( JR, J+2 ) = Z( JR, J+2 ) - TEMP*T3
|
|
280 CONTINUE
|
|
END IF
|
|
T( J+1, J ) = ZERO
|
|
T( J+2, J ) = ZERO
|
|
290 CONTINUE
|
|
*
|
|
* Last elements: Use Givens rotations
|
|
*
|
|
* Rotations from the left
|
|
*
|
|
J = ILAST - 1
|
|
TEMP = H( J, J-1 )
|
|
CALL SLARTG( TEMP, H( J+1, J-1 ), C, S, H( J, J-1 ) )
|
|
H( J+1, J-1 ) = ZERO
|
|
*
|
|
DO 300 JC = J, ILASTM
|
|
TEMP = C*H( J, JC ) + S*H( J+1, JC )
|
|
H( J+1, JC ) = -S*H( J, JC ) + C*H( J+1, JC )
|
|
H( J, JC ) = TEMP
|
|
TEMP2 = C*T( J, JC ) + S*T( J+1, JC )
|
|
T( J+1, JC ) = -S*T( J, JC ) + C*T( J+1, JC )
|
|
T( J, JC ) = TEMP2
|
|
300 CONTINUE
|
|
IF( ILQ ) THEN
|
|
DO 310 JR = 1, N
|
|
TEMP = C*Q( JR, J ) + S*Q( JR, J+1 )
|
|
Q( JR, J+1 ) = -S*Q( JR, J ) + C*Q( JR, J+1 )
|
|
Q( JR, J ) = TEMP
|
|
310 CONTINUE
|
|
END IF
|
|
*
|
|
* Rotations from the right.
|
|
*
|
|
TEMP = T( J+1, J+1 )
|
|
CALL SLARTG( TEMP, T( J+1, J ), C, S, T( J+1, J+1 ) )
|
|
T( J+1, J ) = ZERO
|
|
*
|
|
DO 320 JR = IFRSTM, ILAST
|
|
TEMP = C*H( JR, J+1 ) + S*H( JR, J )
|
|
H( JR, J ) = -S*H( JR, J+1 ) + C*H( JR, J )
|
|
H( JR, J+1 ) = TEMP
|
|
320 CONTINUE
|
|
DO 330 JR = IFRSTM, ILAST - 1
|
|
TEMP = C*T( JR, J+1 ) + S*T( JR, J )
|
|
T( JR, J ) = -S*T( JR, J+1 ) + C*T( JR, J )
|
|
T( JR, J+1 ) = TEMP
|
|
330 CONTINUE
|
|
IF( ILZ ) THEN
|
|
DO 340 JR = 1, N
|
|
TEMP = C*Z( JR, J+1 ) + S*Z( JR, J )
|
|
Z( JR, J ) = -S*Z( JR, J+1 ) + C*Z( JR, J )
|
|
Z( JR, J+1 ) = TEMP
|
|
340 CONTINUE
|
|
END IF
|
|
*
|
|
* End of Double-Shift code
|
|
*
|
|
END IF
|
|
*
|
|
GO TO 350
|
|
*
|
|
* End of iteration loop
|
|
*
|
|
350 CONTINUE
|
|
360 CONTINUE
|
|
*
|
|
* Drop-through = non-convergence
|
|
*
|
|
INFO = ILAST
|
|
GO TO 420
|
|
*
|
|
* Successful completion of all QZ steps
|
|
*
|
|
380 CONTINUE
|
|
*
|
|
* Set Eigenvalues 1:ILO-1
|
|
*
|
|
DO 410 J = 1, ILO - 1
|
|
IF( T( J, J ).LT.ZERO ) THEN
|
|
IF( ILSCHR ) THEN
|
|
DO 390 JR = 1, J
|
|
H( JR, J ) = -H( JR, J )
|
|
T( JR, J ) = -T( JR, J )
|
|
390 CONTINUE
|
|
ELSE
|
|
H( J, J ) = -H( J, J )
|
|
T( J, J ) = -T( J, J )
|
|
END IF
|
|
IF( ILZ ) THEN
|
|
DO 400 JR = 1, N
|
|
Z( JR, J ) = -Z( JR, J )
|
|
400 CONTINUE
|
|
END IF
|
|
END IF
|
|
ALPHAR( J ) = H( J, J )
|
|
ALPHAI( J ) = ZERO
|
|
BETA( J ) = T( J, J )
|
|
410 CONTINUE
|
|
*
|
|
* Normal Termination
|
|
*
|
|
INFO = 0
|
|
*
|
|
* Exit (other than argument error) -- return optimal workspace size
|
|
*
|
|
420 CONTINUE
|
|
WORK( 1 ) = REAL( N )
|
|
RETURN
|
|
*
|
|
* End of SHGEQZ
|
|
*
|
|
END
|