169 lines
3.9 KiB
Fortran
169 lines
3.9 KiB
Fortran
*> \brief \b CRZT02
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* REAL FUNCTION CRZT02( M, N, AF, LDA, TAU, WORK,
|
|
* LWORK )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* INTEGER LDA, LWORK, M, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* COMPLEX AF( LDA, * ), TAU( * ), WORK( LWORK )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> CRZT02 returns
|
|
*> || I - Q'*Q || / ( M * eps)
|
|
*> where the matrix Q is defined by the Householder transformations
|
|
*> generated by CTZRZF.
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] M
|
|
*> \verbatim
|
|
*> M is INTEGER
|
|
*> The number of rows of the matrix AF.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The number of columns of the matrix AF.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] AF
|
|
*> \verbatim
|
|
*> AF is COMPLEX array, dimension (LDA,N)
|
|
*> The output of CTZRZF.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDA
|
|
*> \verbatim
|
|
*> LDA is INTEGER
|
|
*> The leading dimension of the array AF.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] TAU
|
|
*> \verbatim
|
|
*> TAU is COMPLEX array, dimension (M)
|
|
*> Details of the Householder transformations as returned by
|
|
*> CTZRZF.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] WORK
|
|
*> \verbatim
|
|
*> WORK is COMPLEX array, dimension (LWORK)
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LWORK
|
|
*> \verbatim
|
|
*> LWORK is INTEGER
|
|
*> Length of WORK array. LWORK >= N*N+N.
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \date November 2011
|
|
*
|
|
*> \ingroup complex_lin
|
|
*
|
|
* =====================================================================
|
|
REAL FUNCTION CRZT02( M, N, AF, LDA, TAU, WORK,
|
|
$ LWORK )
|
|
*
|
|
* -- LAPACK test routine (version 3.4.0) --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
* November 2011
|
|
*
|
|
* .. Scalar Arguments ..
|
|
INTEGER LDA, LWORK, M, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
COMPLEX AF( LDA, * ), TAU( * ), WORK( LWORK )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
REAL ZERO, ONE
|
|
PARAMETER ( ZERO = 0.0E0, ONE = 1.0E0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER I, INFO
|
|
* ..
|
|
* .. Local Arrays ..
|
|
REAL RWORK( 1 )
|
|
* ..
|
|
* .. External Functions ..
|
|
REAL CLANGE, SLAMCH
|
|
EXTERNAL CLANGE, SLAMCH
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL CLASET, CUNMRZ, XERBLA
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC CMPLX, MAX, REAL
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
CRZT02 = ZERO
|
|
*
|
|
IF( LWORK.LT.N*N+N ) THEN
|
|
CALL XERBLA( 'CRZT02', 7 )
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Quick return if possible
|
|
*
|
|
IF( M.LE.0 .OR. N.LE.0 )
|
|
$ RETURN
|
|
*
|
|
* Q := I
|
|
*
|
|
CALL CLASET( 'Full', N, N, CMPLX( ZERO ), CMPLX( ONE ), WORK, N )
|
|
*
|
|
* Q := P(1) * ... * P(m) * Q
|
|
*
|
|
CALL CUNMRZ( 'Left', 'No transpose', N, N, M, N-M, AF, LDA, TAU,
|
|
$ WORK, N, WORK( N*N+1 ), LWORK-N*N, INFO )
|
|
*
|
|
* Q := P(m)' * ... * P(1)' * Q
|
|
*
|
|
CALL CUNMRZ( 'Left', 'Conjugate transpose', N, N, M, N-M, AF, LDA,
|
|
$ TAU, WORK, N, WORK( N*N+1 ), LWORK-N*N, INFO )
|
|
*
|
|
* Q := Q - I
|
|
*
|
|
DO 10 I = 1, N
|
|
WORK( ( I-1 )*N+I ) = WORK( ( I-1 )*N+I ) - ONE
|
|
10 CONTINUE
|
|
*
|
|
CRZT02 = CLANGE( 'One-norm', N, N, WORK, N, RWORK ) /
|
|
$ ( SLAMCH( 'Epsilon' )*REAL( MAX( M, N ) ) )
|
|
RETURN
|
|
*
|
|
* End of CRZT02
|
|
*
|
|
END
|