291 lines
7.5 KiB
Fortran
291 lines
7.5 KiB
Fortran
*> \brief \b ZLA_PORCOND_X computes the infinity norm condition number of op(A)*diag(x) for Hermitian positive-definite matrices.
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
*> \htmlonly
|
|
*> Download ZLA_PORCOND_X + dependencies
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zla_porcond_x.f">
|
|
*> [TGZ]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zla_porcond_x.f">
|
|
*> [ZIP]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zla_porcond_x.f">
|
|
*> [TXT]</a>
|
|
*> \endhtmlonly
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* DOUBLE PRECISION FUNCTION ZLA_PORCOND_X( UPLO, N, A, LDA, AF,
|
|
* LDAF, X, INFO, WORK,
|
|
* RWORK )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* CHARACTER UPLO
|
|
* INTEGER N, LDA, LDAF, INFO
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* COMPLEX*16 A( LDA, * ), AF( LDAF, * ), WORK( * ), X( * )
|
|
* DOUBLE PRECISION RWORK( * )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> ZLA_PORCOND_X Computes the infinity norm condition number of
|
|
*> op(A) * diag(X) where X is a COMPLEX*16 vector.
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] UPLO
|
|
*> \verbatim
|
|
*> UPLO is CHARACTER*1
|
|
*> = 'U': Upper triangle of A is stored;
|
|
*> = 'L': Lower triangle of A is stored.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The number of linear equations, i.e., the order of the
|
|
*> matrix A. N >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] A
|
|
*> \verbatim
|
|
*> A is COMPLEX*16 array, dimension (LDA,N)
|
|
*> On entry, the N-by-N matrix A.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDA
|
|
*> \verbatim
|
|
*> LDA is INTEGER
|
|
*> The leading dimension of the array A. LDA >= max(1,N).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] AF
|
|
*> \verbatim
|
|
*> AF is COMPLEX*16 array, dimension (LDAF,N)
|
|
*> The triangular factor U or L from the Cholesky factorization
|
|
*> A = U**H*U or A = L*L**H, as computed by ZPOTRF.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDAF
|
|
*> \verbatim
|
|
*> LDAF is INTEGER
|
|
*> The leading dimension of the array AF. LDAF >= max(1,N).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] X
|
|
*> \verbatim
|
|
*> X is COMPLEX*16 array, dimension (N)
|
|
*> The vector X in the formula op(A) * diag(X).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] INFO
|
|
*> \verbatim
|
|
*> INFO is INTEGER
|
|
*> = 0: Successful exit.
|
|
*> i > 0: The ith argument is invalid.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] WORK
|
|
*> \verbatim
|
|
*> WORK is COMPLEX*16 array, dimension (2*N).
|
|
*> Workspace.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] RWORK
|
|
*> \verbatim
|
|
*> RWORK is DOUBLE PRECISION array, dimension (N).
|
|
*> Workspace.
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \date September 2012
|
|
*
|
|
*> \ingroup complex16POcomputational
|
|
*
|
|
* =====================================================================
|
|
DOUBLE PRECISION FUNCTION ZLA_PORCOND_X( UPLO, N, A, LDA, AF,
|
|
$ LDAF, X, INFO, WORK,
|
|
$ RWORK )
|
|
*
|
|
* -- LAPACK computational routine (version 3.4.2) --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
* September 2012
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER UPLO
|
|
INTEGER N, LDA, LDAF, INFO
|
|
* ..
|
|
* .. Array Arguments ..
|
|
COMPLEX*16 A( LDA, * ), AF( LDAF, * ), WORK( * ), X( * )
|
|
DOUBLE PRECISION RWORK( * )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Local Scalars ..
|
|
INTEGER KASE, I, J
|
|
DOUBLE PRECISION AINVNM, ANORM, TMP
|
|
LOGICAL UP, UPPER
|
|
COMPLEX*16 ZDUM
|
|
* ..
|
|
* .. Local Arrays ..
|
|
INTEGER ISAVE( 3 )
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
EXTERNAL LSAME
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL ZLACN2, ZPOTRS, XERBLA
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC ABS, MAX, REAL, DIMAG
|
|
* ..
|
|
* .. Statement Functions ..
|
|
DOUBLE PRECISION CABS1
|
|
* ..
|
|
* .. Statement Function Definitions ..
|
|
CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
ZLA_PORCOND_X = 0.0D+0
|
|
*
|
|
INFO = 0
|
|
UPPER = LSAME( UPLO, 'U' )
|
|
IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
|
|
INFO = -1
|
|
ELSE IF ( N.LT.0 ) THEN
|
|
INFO = -2
|
|
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
|
|
INFO = -4
|
|
ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
|
|
INFO = -6
|
|
END IF
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'ZLA_PORCOND_X', -INFO )
|
|
RETURN
|
|
END IF
|
|
UP = .FALSE.
|
|
IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
|
|
*
|
|
* Compute norm of op(A)*op2(C).
|
|
*
|
|
ANORM = 0.0D+0
|
|
IF ( UP ) THEN
|
|
DO I = 1, N
|
|
TMP = 0.0D+0
|
|
DO J = 1, I
|
|
TMP = TMP + CABS1( A( J, I ) * X( J ) )
|
|
END DO
|
|
DO J = I+1, N
|
|
TMP = TMP + CABS1( A( I, J ) * X( J ) )
|
|
END DO
|
|
RWORK( I ) = TMP
|
|
ANORM = MAX( ANORM, TMP )
|
|
END DO
|
|
ELSE
|
|
DO I = 1, N
|
|
TMP = 0.0D+0
|
|
DO J = 1, I
|
|
TMP = TMP + CABS1( A( I, J ) * X( J ) )
|
|
END DO
|
|
DO J = I+1, N
|
|
TMP = TMP + CABS1( A( J, I ) * X( J ) )
|
|
END DO
|
|
RWORK( I ) = TMP
|
|
ANORM = MAX( ANORM, TMP )
|
|
END DO
|
|
END IF
|
|
*
|
|
* Quick return if possible.
|
|
*
|
|
IF( N.EQ.0 ) THEN
|
|
ZLA_PORCOND_X = 1.0D+0
|
|
RETURN
|
|
ELSE IF( ANORM .EQ. 0.0D+0 ) THEN
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Estimate the norm of inv(op(A)).
|
|
*
|
|
AINVNM = 0.0D+0
|
|
*
|
|
KASE = 0
|
|
10 CONTINUE
|
|
CALL ZLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
|
|
IF( KASE.NE.0 ) THEN
|
|
IF( KASE.EQ.2 ) THEN
|
|
*
|
|
* Multiply by R.
|
|
*
|
|
DO I = 1, N
|
|
WORK( I ) = WORK( I ) * RWORK( I )
|
|
END DO
|
|
*
|
|
IF ( UP ) THEN
|
|
CALL ZPOTRS( 'U', N, 1, AF, LDAF,
|
|
$ WORK, N, INFO )
|
|
ELSE
|
|
CALL ZPOTRS( 'L', N, 1, AF, LDAF,
|
|
$ WORK, N, INFO )
|
|
ENDIF
|
|
*
|
|
* Multiply by inv(X).
|
|
*
|
|
DO I = 1, N
|
|
WORK( I ) = WORK( I ) / X( I )
|
|
END DO
|
|
ELSE
|
|
*
|
|
* Multiply by inv(X**H).
|
|
*
|
|
DO I = 1, N
|
|
WORK( I ) = WORK( I ) / X( I )
|
|
END DO
|
|
*
|
|
IF ( UP ) THEN
|
|
CALL ZPOTRS( 'U', N, 1, AF, LDAF,
|
|
$ WORK, N, INFO )
|
|
ELSE
|
|
CALL ZPOTRS( 'L', N, 1, AF, LDAF,
|
|
$ WORK, N, INFO )
|
|
END IF
|
|
*
|
|
* Multiply by R.
|
|
*
|
|
DO I = 1, N
|
|
WORK( I ) = WORK( I ) * RWORK( I )
|
|
END DO
|
|
END IF
|
|
GO TO 10
|
|
END IF
|
|
*
|
|
* Compute the estimate of the reciprocal condition number.
|
|
*
|
|
IF( AINVNM .NE. 0.0D+0 )
|
|
$ ZLA_PORCOND_X = 1.0D+0 / AINVNM
|
|
*
|
|
RETURN
|
|
*
|
|
END
|