280 lines
8.5 KiB
Fortran
280 lines
8.5 KiB
Fortran
*> \brief \b CLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix.
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
*> \htmlonly
|
|
*> Download CLANHE + dependencies
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/clanhe.f">
|
|
*> [TGZ]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/clanhe.f">
|
|
*> [ZIP]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/clanhe.f">
|
|
*> [TXT]</a>
|
|
*> \endhtmlonly
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* REAL FUNCTION CLANHE( NORM, UPLO, N, A, LDA, WORK )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* CHARACTER NORM, UPLO
|
|
* INTEGER LDA, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* REAL WORK( * )
|
|
* COMPLEX A( LDA, * )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> CLANHE returns the value of the one norm, or the Frobenius norm, or
|
|
*> the infinity norm, or the element of largest absolute value of a
|
|
*> complex hermitian matrix A.
|
|
*> \endverbatim
|
|
*>
|
|
*> \return CLANHE
|
|
*> \verbatim
|
|
*>
|
|
*> CLANHE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
|
|
*> (
|
|
*> ( norm1(A), NORM = '1', 'O' or 'o'
|
|
*> (
|
|
*> ( normI(A), NORM = 'I' or 'i'
|
|
*> (
|
|
*> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
|
|
*>
|
|
*> where norm1 denotes the one norm of a matrix (maximum column sum),
|
|
*> normI denotes the infinity norm of a matrix (maximum row sum) and
|
|
*> normF denotes the Frobenius norm of a matrix (square root of sum of
|
|
*> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] NORM
|
|
*> \verbatim
|
|
*> NORM is CHARACTER*1
|
|
*> Specifies the value to be returned in CLANHE as described
|
|
*> above.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] UPLO
|
|
*> \verbatim
|
|
*> UPLO is CHARACTER*1
|
|
*> Specifies whether the upper or lower triangular part of the
|
|
*> hermitian matrix A is to be referenced.
|
|
*> = 'U': Upper triangular part of A is referenced
|
|
*> = 'L': Lower triangular part of A is referenced
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The order of the matrix A. N >= 0. When N = 0, CLANHE is
|
|
*> set to zero.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] A
|
|
*> \verbatim
|
|
*> A is COMPLEX array, dimension (LDA,N)
|
|
*> The hermitian matrix A. If UPLO = 'U', the leading n by n
|
|
*> upper triangular part of A contains the upper triangular part
|
|
*> of the matrix A, and the strictly lower triangular part of A
|
|
*> is not referenced. If UPLO = 'L', the leading n by n lower
|
|
*> triangular part of A contains the lower triangular part of
|
|
*> the matrix A, and the strictly upper triangular part of A is
|
|
*> not referenced. Note that the imaginary parts of the diagonal
|
|
*> elements need not be set and are assumed to be zero.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDA
|
|
*> \verbatim
|
|
*> LDA is INTEGER
|
|
*> The leading dimension of the array A. LDA >= max(N,1).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] WORK
|
|
*> \verbatim
|
|
*> WORK is REAL array, dimension (MAX(1,LWORK)),
|
|
*> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
|
|
*> WORK is not referenced.
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \date December 2016
|
|
*
|
|
*> \ingroup complexHEauxiliary
|
|
*
|
|
* =====================================================================
|
|
REAL FUNCTION CLANHE( NORM, UPLO, N, A, LDA, WORK )
|
|
*
|
|
* -- LAPACK auxiliary routine (version 3.7.0) --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
* December 2016
|
|
*
|
|
IMPLICIT NONE
|
|
* .. Scalar Arguments ..
|
|
CHARACTER NORM, UPLO
|
|
INTEGER LDA, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
REAL WORK( * )
|
|
COMPLEX A( LDA, * )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
REAL ONE, ZERO
|
|
PARAMETER ( ONE = 1.0E+0, ZERO = 0.0E+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER I, J
|
|
REAL ABSA, SUM, VALUE
|
|
* ..
|
|
* .. Local Arrays ..
|
|
REAL SSQ( 2 ), COLSSQ( 2 )
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME, SISNAN
|
|
EXTERNAL LSAME, SISNAN
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL CLASSQ, SCOMBSSQ
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC ABS, REAL, SQRT
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
IF( N.EQ.0 ) THEN
|
|
VALUE = ZERO
|
|
ELSE IF( LSAME( NORM, 'M' ) ) THEN
|
|
*
|
|
* Find max(abs(A(i,j))).
|
|
*
|
|
VALUE = ZERO
|
|
IF( LSAME( UPLO, 'U' ) ) THEN
|
|
DO 20 J = 1, N
|
|
DO 10 I = 1, J - 1
|
|
SUM = ABS( A( I, J ) )
|
|
IF( VALUE .LT. SUM .OR. SISNAN( SUM ) ) VALUE = SUM
|
|
10 CONTINUE
|
|
SUM = ABS( REAL( A( J, J ) ) )
|
|
IF( VALUE .LT. SUM .OR. SISNAN( SUM ) ) VALUE = SUM
|
|
20 CONTINUE
|
|
ELSE
|
|
DO 40 J = 1, N
|
|
SUM = ABS( REAL( A( J, J ) ) )
|
|
IF( VALUE .LT. SUM .OR. SISNAN( SUM ) ) VALUE = SUM
|
|
DO 30 I = J + 1, N
|
|
SUM = ABS( A( I, J ) )
|
|
IF( VALUE .LT. SUM .OR. SISNAN( SUM ) ) VALUE = SUM
|
|
30 CONTINUE
|
|
40 CONTINUE
|
|
END IF
|
|
ELSE IF( ( LSAME( NORM, 'I' ) ) .OR. ( LSAME( NORM, 'O' ) ) .OR.
|
|
$ ( NORM.EQ.'1' ) ) THEN
|
|
*
|
|
* Find normI(A) ( = norm1(A), since A is hermitian).
|
|
*
|
|
VALUE = ZERO
|
|
IF( LSAME( UPLO, 'U' ) ) THEN
|
|
DO 60 J = 1, N
|
|
SUM = ZERO
|
|
DO 50 I = 1, J - 1
|
|
ABSA = ABS( A( I, J ) )
|
|
SUM = SUM + ABSA
|
|
WORK( I ) = WORK( I ) + ABSA
|
|
50 CONTINUE
|
|
WORK( J ) = SUM + ABS( REAL( A( J, J ) ) )
|
|
60 CONTINUE
|
|
DO 70 I = 1, N
|
|
SUM = WORK( I )
|
|
IF( VALUE .LT. SUM .OR. SISNAN( SUM ) ) VALUE = SUM
|
|
70 CONTINUE
|
|
ELSE
|
|
DO 80 I = 1, N
|
|
WORK( I ) = ZERO
|
|
80 CONTINUE
|
|
DO 100 J = 1, N
|
|
SUM = WORK( J ) + ABS( REAL( A( J, J ) ) )
|
|
DO 90 I = J + 1, N
|
|
ABSA = ABS( A( I, J ) )
|
|
SUM = SUM + ABSA
|
|
WORK( I ) = WORK( I ) + ABSA
|
|
90 CONTINUE
|
|
IF( VALUE .LT. SUM .OR. SISNAN( SUM ) ) VALUE = SUM
|
|
100 CONTINUE
|
|
END IF
|
|
ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
|
|
*
|
|
* Find normF(A).
|
|
* SSQ(1) is scale
|
|
* SSQ(2) is sum-of-squares
|
|
* For better accuracy, sum each column separately.
|
|
*
|
|
SSQ( 1 ) = ZERO
|
|
SSQ( 2 ) = ONE
|
|
*
|
|
* Sum off-diagonals
|
|
*
|
|
IF( LSAME( UPLO, 'U' ) ) THEN
|
|
DO 110 J = 2, N
|
|
COLSSQ( 1 ) = ZERO
|
|
COLSSQ( 2 ) = ONE
|
|
CALL CLASSQ( J-1, A( 1, J ), 1,
|
|
$ COLSSQ( 1 ), COLSSQ( 2 ) )
|
|
CALL SCOMBSSQ( SSQ, COLSSQ )
|
|
110 CONTINUE
|
|
ELSE
|
|
DO 120 J = 1, N - 1
|
|
COLSSQ( 1 ) = ZERO
|
|
COLSSQ( 2 ) = ONE
|
|
CALL CLASSQ( N-J, A( J+1, J ), 1,
|
|
$ COLSSQ( 1 ), COLSSQ( 2 ) )
|
|
CALL SCOMBSSQ( SSQ, COLSSQ )
|
|
120 CONTINUE
|
|
END IF
|
|
SSQ( 2 ) = 2*SSQ( 2 )
|
|
*
|
|
* Sum diagonal
|
|
*
|
|
DO 130 I = 1, N
|
|
IF( REAL( A( I, I ) ).NE.ZERO ) THEN
|
|
ABSA = ABS( REAL( A( I, I ) ) )
|
|
IF( SSQ( 1 ).LT.ABSA ) THEN
|
|
SSQ( 2 ) = ONE + SSQ( 2 )*( SSQ( 1 ) / ABSA )**2
|
|
SSQ( 1 ) = ABSA
|
|
ELSE
|
|
SSQ( 2 ) = SSQ( 2 ) + ( ABSA / SSQ( 1 ) )**2
|
|
END IF
|
|
END IF
|
|
130 CONTINUE
|
|
VALUE = SSQ( 1 )*SQRT( SSQ( 2 ) )
|
|
END IF
|
|
*
|
|
CLANHE = VALUE
|
|
RETURN
|
|
*
|
|
* End of CLANHE
|
|
*
|
|
END
|