2df1e3372d
Inf values in the input vector will survive rescaling, causing an infinite loop. The value of 1000 is arbitrarily chosen as a large but finite value with the intention to never interfere with regular calculations.
204 lines
5.3 KiB
Fortran
204 lines
5.3 KiB
Fortran
*> \brief \b ZLARFG generates an elementary reflector (Householder matrix).
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
*> \htmlonly
|
|
*> Download ZLARFG + dependencies
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlarfg.f">
|
|
*> [TGZ]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlarfg.f">
|
|
*> [ZIP]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlarfg.f">
|
|
*> [TXT]</a>
|
|
*> \endhtmlonly
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* SUBROUTINE ZLARFG( N, ALPHA, X, INCX, TAU )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* INTEGER INCX, N
|
|
* COMPLEX*16 ALPHA, TAU
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* COMPLEX*16 X( * )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> ZLARFG generates a complex elementary reflector H of order n, such
|
|
*> that
|
|
*>
|
|
*> H**H * ( alpha ) = ( beta ), H**H * H = I.
|
|
*> ( x ) ( 0 )
|
|
*>
|
|
*> where alpha and beta are scalars, with beta real, and x is an
|
|
*> (n-1)-element complex vector. H is represented in the form
|
|
*>
|
|
*> H = I - tau * ( 1 ) * ( 1 v**H ) ,
|
|
*> ( v )
|
|
*>
|
|
*> where tau is a complex scalar and v is a complex (n-1)-element
|
|
*> vector. Note that H is not hermitian.
|
|
*>
|
|
*> If the elements of x are all zero and alpha is real, then tau = 0
|
|
*> and H is taken to be the unit matrix.
|
|
*>
|
|
*> Otherwise 1 <= real(tau) <= 2 and abs(tau-1) <= 1 .
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The order of the elementary reflector.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in,out] ALPHA
|
|
*> \verbatim
|
|
*> ALPHA is COMPLEX*16
|
|
*> On entry, the value alpha.
|
|
*> On exit, it is overwritten with the value beta.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in,out] X
|
|
*> \verbatim
|
|
*> X is COMPLEX*16 array, dimension
|
|
*> (1+(N-2)*abs(INCX))
|
|
*> On entry, the vector x.
|
|
*> On exit, it is overwritten with the vector v.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] INCX
|
|
*> \verbatim
|
|
*> INCX is INTEGER
|
|
*> The increment between elements of X. INCX > 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] TAU
|
|
*> \verbatim
|
|
*> TAU is COMPLEX*16
|
|
*> The value tau.
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \date December 2016
|
|
*
|
|
*> \ingroup complex16OTHERauxiliary
|
|
*
|
|
* =====================================================================
|
|
SUBROUTINE ZLARFG( N, ALPHA, X, INCX, TAU )
|
|
*
|
|
* -- LAPACK auxiliary routine (version 3.7.0) --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
* December 2016
|
|
*
|
|
* .. Scalar Arguments ..
|
|
INTEGER INCX, N
|
|
COMPLEX*16 ALPHA, TAU
|
|
* ..
|
|
* .. Array Arguments ..
|
|
COMPLEX*16 X( * )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
DOUBLE PRECISION ONE, ZERO
|
|
PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER J, KNT
|
|
DOUBLE PRECISION ALPHI, ALPHR, BETA, RSAFMN, SAFMIN, XNORM
|
|
* ..
|
|
* .. External Functions ..
|
|
DOUBLE PRECISION DLAMCH, DLAPY3, DZNRM2
|
|
COMPLEX*16 ZLADIV
|
|
EXTERNAL DLAMCH, DLAPY3, DZNRM2, ZLADIV
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC ABS, DBLE, DCMPLX, DIMAG, SIGN
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL ZDSCAL, ZSCAL
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
IF( N.LE.0 ) THEN
|
|
TAU = ZERO
|
|
RETURN
|
|
END IF
|
|
*
|
|
XNORM = DZNRM2( N-1, X, INCX )
|
|
ALPHR = DBLE( ALPHA )
|
|
ALPHI = DIMAG( ALPHA )
|
|
*
|
|
IF( XNORM.EQ.ZERO .AND. ALPHI.EQ.ZERO ) THEN
|
|
*
|
|
* H = I
|
|
*
|
|
TAU = ZERO
|
|
ELSE
|
|
*
|
|
* general case
|
|
*
|
|
BETA = -SIGN( DLAPY3( ALPHR, ALPHI, XNORM ), ALPHR )
|
|
SAFMIN = DLAMCH( 'S' ) / DLAMCH( 'E' )
|
|
RSAFMN = ONE / SAFMIN
|
|
*
|
|
KNT = 0
|
|
IF( ABS( BETA ).LT.SAFMIN ) THEN
|
|
*
|
|
* XNORM, BETA may be inaccurate; scale X and recompute them
|
|
*
|
|
10 CONTINUE
|
|
KNT = KNT + 1
|
|
CALL ZDSCAL( N-1, RSAFMN, X, INCX )
|
|
BETA = BETA*RSAFMN
|
|
ALPHI = ALPHI*RSAFMN
|
|
ALPHR = ALPHR*RSAFMN
|
|
IF( ABS( BETA ).LT.SAFMIN .AND. KNT .LT. 1000)
|
|
$ GO TO 10
|
|
*
|
|
* New BETA is at most 1, at least SAFMIN
|
|
*
|
|
XNORM = DZNRM2( N-1, X, INCX )
|
|
ALPHA = DCMPLX( ALPHR, ALPHI )
|
|
BETA = -SIGN( DLAPY3( ALPHR, ALPHI, XNORM ), ALPHR )
|
|
END IF
|
|
TAU = DCMPLX( ( BETA-ALPHR ) / BETA, -ALPHI / BETA )
|
|
ALPHA = ZLADIV( DCMPLX( ONE ), ALPHA-BETA )
|
|
CALL ZSCAL( N-1, ALPHA, X, INCX )
|
|
*
|
|
* If ALPHA is subnormal, it may lose relative accuracy
|
|
*
|
|
DO 20 J = 1, KNT
|
|
BETA = BETA*SAFMIN
|
|
20 CONTINUE
|
|
ALPHA = BETA
|
|
END IF
|
|
*
|
|
RETURN
|
|
*
|
|
* End of ZLARFG
|
|
*
|
|
END
|