357 lines
11 KiB
Fortran
357 lines
11 KiB
Fortran
*> \brief \b SSPGVD
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
*> \htmlonly
|
|
*> Download SSPGVD + dependencies
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sspgvd.f">
|
|
*> [TGZ]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sspgvd.f">
|
|
*> [ZIP]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sspgvd.f">
|
|
*> [TXT]</a>
|
|
*> \endhtmlonly
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* SUBROUTINE SSPGVD( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
|
|
* LWORK, IWORK, LIWORK, INFO )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* CHARACTER JOBZ, UPLO
|
|
* INTEGER INFO, ITYPE, LDZ, LIWORK, LWORK, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* INTEGER IWORK( * )
|
|
* REAL AP( * ), BP( * ), W( * ), WORK( * ),
|
|
* $ Z( LDZ, * )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> SSPGVD computes all the eigenvalues, and optionally, the eigenvectors
|
|
*> of a real generalized symmetric-definite eigenproblem, of the form
|
|
*> A*x=(lambda)*B*x, A*Bx=(lambda)*x, or B*A*x=(lambda)*x. Here A and
|
|
*> B are assumed to be symmetric, stored in packed format, and B is also
|
|
*> positive definite.
|
|
*> If eigenvectors are desired, it uses a divide and conquer algorithm.
|
|
*>
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] ITYPE
|
|
*> \verbatim
|
|
*> ITYPE is INTEGER
|
|
*> Specifies the problem type to be solved:
|
|
*> = 1: A*x = (lambda)*B*x
|
|
*> = 2: A*B*x = (lambda)*x
|
|
*> = 3: B*A*x = (lambda)*x
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] JOBZ
|
|
*> \verbatim
|
|
*> JOBZ is CHARACTER*1
|
|
*> = 'N': Compute eigenvalues only;
|
|
*> = 'V': Compute eigenvalues and eigenvectors.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] UPLO
|
|
*> \verbatim
|
|
*> UPLO is CHARACTER*1
|
|
*> = 'U': Upper triangles of A and B are stored;
|
|
*> = 'L': Lower triangles of A and B are stored.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The order of the matrices A and B. N >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in,out] AP
|
|
*> \verbatim
|
|
*> AP is REAL array, dimension (N*(N+1)/2)
|
|
*> On entry, the upper or lower triangle of the symmetric matrix
|
|
*> A, packed columnwise in a linear array. The j-th column of A
|
|
*> is stored in the array AP as follows:
|
|
*> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
|
|
*> if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
|
|
*>
|
|
*> On exit, the contents of AP are destroyed.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in,out] BP
|
|
*> \verbatim
|
|
*> BP is REAL array, dimension (N*(N+1)/2)
|
|
*> On entry, the upper or lower triangle of the symmetric matrix
|
|
*> B, packed columnwise in a linear array. The j-th column of B
|
|
*> is stored in the array BP as follows:
|
|
*> if UPLO = 'U', BP(i + (j-1)*j/2) = B(i,j) for 1<=i<=j;
|
|
*> if UPLO = 'L', BP(i + (j-1)*(2*n-j)/2) = B(i,j) for j<=i<=n.
|
|
*>
|
|
*> On exit, the triangular factor U or L from the Cholesky
|
|
*> factorization B = U**T*U or B = L*L**T, in the same storage
|
|
*> format as B.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] W
|
|
*> \verbatim
|
|
*> W is REAL array, dimension (N)
|
|
*> If INFO = 0, the eigenvalues in ascending order.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] Z
|
|
*> \verbatim
|
|
*> Z is REAL array, dimension (LDZ, N)
|
|
*> If JOBZ = 'V', then if INFO = 0, Z contains the matrix Z of
|
|
*> eigenvectors. The eigenvectors are normalized as follows:
|
|
*> if ITYPE = 1 or 2, Z**T*B*Z = I;
|
|
*> if ITYPE = 3, Z**T*inv(B)*Z = I.
|
|
*> If JOBZ = 'N', then Z is not referenced.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDZ
|
|
*> \verbatim
|
|
*> LDZ is INTEGER
|
|
*> The leading dimension of the array Z. LDZ >= 1, and if
|
|
*> JOBZ = 'V', LDZ >= max(1,N).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] WORK
|
|
*> \verbatim
|
|
*> WORK is REAL array, dimension (MAX(1,LWORK))
|
|
*> On exit, if INFO = 0, WORK(1) returns the required LWORK.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LWORK
|
|
*> \verbatim
|
|
*> LWORK is INTEGER
|
|
*> The dimension of the array WORK.
|
|
*> If N <= 1, LWORK >= 1.
|
|
*> If JOBZ = 'N' and N > 1, LWORK >= 2*N.
|
|
*> If JOBZ = 'V' and N > 1, LWORK >= 1 + 6*N + 2*N**2.
|
|
*>
|
|
*> If LWORK = -1, then a workspace query is assumed; the routine
|
|
*> only calculates the required sizes of the WORK and IWORK
|
|
*> arrays, returns these values as the first entries of the WORK
|
|
*> and IWORK arrays, and no error message related to LWORK or
|
|
*> LIWORK is issued by XERBLA.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] IWORK
|
|
*> \verbatim
|
|
*> IWORK is INTEGER array, dimension (MAX(1,LIWORK))
|
|
*> On exit, if INFO = 0, IWORK(1) returns the required LIWORK.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LIWORK
|
|
*> \verbatim
|
|
*> LIWORK is INTEGER
|
|
*> The dimension of the array IWORK.
|
|
*> If JOBZ = 'N' or N <= 1, LIWORK >= 1.
|
|
*> If JOBZ = 'V' and N > 1, LIWORK >= 3 + 5*N.
|
|
*>
|
|
*> If LIWORK = -1, then a workspace query is assumed; the
|
|
*> routine only calculates the required sizes of the WORK and
|
|
*> IWORK arrays, returns these values as the first entries of
|
|
*> the WORK and IWORK arrays, and no error message related to
|
|
*> LWORK or LIWORK is issued by XERBLA.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] INFO
|
|
*> \verbatim
|
|
*> INFO is INTEGER
|
|
*> = 0: successful exit
|
|
*> < 0: if INFO = -i, the i-th argument had an illegal value
|
|
*> > 0: SPPTRF or SSPEVD returned an error code:
|
|
*> <= N: if INFO = i, SSPEVD failed to converge;
|
|
*> i off-diagonal elements of an intermediate
|
|
*> tridiagonal form did not converge to zero;
|
|
*> > N: if INFO = N + i, for 1 <= i <= N, then the leading
|
|
*> principal minor of order i of B is not positive.
|
|
*> The factorization of B could not be completed and
|
|
*> no eigenvalues or eigenvectors were computed.
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \ingroup hpgvd
|
|
*
|
|
*> \par Contributors:
|
|
* ==================
|
|
*>
|
|
*> Mark Fahey, Department of Mathematics, Univ. of Kentucky, USA
|
|
*
|
|
* =====================================================================
|
|
SUBROUTINE SSPGVD( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
|
|
$ LWORK, IWORK, LIWORK, INFO )
|
|
*
|
|
* -- LAPACK driver routine --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER JOBZ, UPLO
|
|
INTEGER INFO, ITYPE, LDZ, LIWORK, LWORK, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
INTEGER IWORK( * )
|
|
REAL AP( * ), BP( * ), W( * ), WORK( * ),
|
|
$ Z( LDZ, * )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Local Scalars ..
|
|
LOGICAL LQUERY, UPPER, WANTZ
|
|
CHARACTER TRANS
|
|
INTEGER J, LIWMIN, LWMIN, NEIG
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
REAL SROUNDUP_LWORK
|
|
EXTERNAL LSAME, SROUNDUP_LWORK
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL SPPTRF, SSPEVD, SSPGST, STPMV, STPSV, XERBLA
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MAX, REAL
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Test the input parameters.
|
|
*
|
|
WANTZ = LSAME( JOBZ, 'V' )
|
|
UPPER = LSAME( UPLO, 'U' )
|
|
LQUERY = ( LWORK.EQ.-1 .OR. LIWORK.EQ.-1 )
|
|
*
|
|
INFO = 0
|
|
IF( ITYPE.LT.1 .OR. ITYPE.GT.3 ) THEN
|
|
INFO = -1
|
|
ELSE IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
|
|
INFO = -2
|
|
ELSE IF( .NOT.( UPPER .OR. LSAME( UPLO, 'L' ) ) ) THEN
|
|
INFO = -3
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -4
|
|
ELSE IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) ) THEN
|
|
INFO = -9
|
|
END IF
|
|
*
|
|
IF( INFO.EQ.0 ) THEN
|
|
IF( N.LE.1 ) THEN
|
|
LIWMIN = 1
|
|
LWMIN = 1
|
|
ELSE
|
|
IF( WANTZ ) THEN
|
|
LIWMIN = 3 + 5*N
|
|
LWMIN = 1 + 6*N + 2*N**2
|
|
ELSE
|
|
LIWMIN = 1
|
|
LWMIN = 2*N
|
|
END IF
|
|
END IF
|
|
WORK( 1 ) = SROUNDUP_LWORK(LWMIN)
|
|
IWORK( 1 ) = LIWMIN
|
|
IF( LWORK.LT.LWMIN .AND. .NOT.LQUERY ) THEN
|
|
INFO = -11
|
|
ELSE IF( LIWORK.LT.LIWMIN .AND. .NOT.LQUERY ) THEN
|
|
INFO = -13
|
|
END IF
|
|
END IF
|
|
*
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'SSPGVD', -INFO )
|
|
RETURN
|
|
ELSE IF( LQUERY ) THEN
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Quick return if possible
|
|
*
|
|
IF( N.EQ.0 )
|
|
$ RETURN
|
|
*
|
|
* Form a Cholesky factorization of BP.
|
|
*
|
|
CALL SPPTRF( UPLO, N, BP, INFO )
|
|
IF( INFO.NE.0 ) THEN
|
|
INFO = N + INFO
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Transform problem to standard eigenvalue problem and solve.
|
|
*
|
|
CALL SSPGST( ITYPE, UPLO, N, AP, BP, INFO )
|
|
CALL SSPEVD( JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, LWORK, IWORK,
|
|
$ LIWORK, INFO )
|
|
LWMIN = INT( MAX( REAL( LWMIN ), REAL( WORK( 1 ) ) ) )
|
|
LIWMIN = INT( MAX( REAL( LIWMIN ), REAL( IWORK( 1 ) ) ) )
|
|
*
|
|
IF( WANTZ ) THEN
|
|
*
|
|
* Backtransform eigenvectors to the original problem.
|
|
*
|
|
NEIG = N
|
|
IF( INFO.GT.0 )
|
|
$ NEIG = INFO - 1
|
|
IF( ITYPE.EQ.1 .OR. ITYPE.EQ.2 ) THEN
|
|
*
|
|
* For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
|
|
* backtransform eigenvectors: x = inv(L)**T *y or inv(U)*y
|
|
*
|
|
IF( UPPER ) THEN
|
|
TRANS = 'N'
|
|
ELSE
|
|
TRANS = 'T'
|
|
END IF
|
|
*
|
|
DO 10 J = 1, NEIG
|
|
CALL STPSV( UPLO, TRANS, 'Non-unit', N, BP, Z( 1, J ),
|
|
$ 1 )
|
|
10 CONTINUE
|
|
*
|
|
ELSE IF( ITYPE.EQ.3 ) THEN
|
|
*
|
|
* For B*A*x=(lambda)*x;
|
|
* backtransform eigenvectors: x = L*y or U**T *y
|
|
*
|
|
IF( UPPER ) THEN
|
|
TRANS = 'T'
|
|
ELSE
|
|
TRANS = 'N'
|
|
END IF
|
|
*
|
|
DO 20 J = 1, NEIG
|
|
CALL STPMV( UPLO, TRANS, 'Non-unit', N, BP, Z( 1, J ),
|
|
$ 1 )
|
|
20 CONTINUE
|
|
END IF
|
|
END IF
|
|
*
|
|
WORK( 1 ) = SROUNDUP_LWORK(LWMIN)
|
|
IWORK( 1 ) = LIWMIN
|
|
*
|
|
RETURN
|
|
*
|
|
* End of SSPGVD
|
|
*
|
|
END
|