237 lines
6.5 KiB
Fortran
237 lines
6.5 KiB
Fortran
*> \brief \b STBT02
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* SUBROUTINE STBT02( UPLO, TRANS, DIAG, N, KD, NRHS, AB, LDAB, X,
|
|
* LDX, B, LDB, WORK, RESID )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* CHARACTER DIAG, TRANS, UPLO
|
|
* INTEGER KD, LDAB, LDB, LDX, N, NRHS
|
|
* REAL RESID
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* REAL AB( LDAB, * ), B( LDB, * ), WORK( * ),
|
|
* $ X( LDX, * )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> STBT02 computes the residual for the computed solution to a
|
|
*> triangular system of linear equations op(A)*X = B, when A is a
|
|
*> triangular band matrix. The test ratio is the maximum over
|
|
*> norm(b - op(A)*x) / ( ||op(A)||_1 * norm(x) * EPS ),
|
|
*> where op(A) = A or A**T, b is the column of B, x is the solution
|
|
*> vector, and EPS is the machine epsilon.
|
|
*> The norm used is the 1-norm.
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] UPLO
|
|
*> \verbatim
|
|
*> UPLO is CHARACTER*1
|
|
*> Specifies whether the matrix A is upper or lower triangular.
|
|
*> = 'U': Upper triangular
|
|
*> = 'L': Lower triangular
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] TRANS
|
|
*> \verbatim
|
|
*> TRANS is CHARACTER*1
|
|
*> Specifies the operation applied to A.
|
|
*> = 'N': A * X = B (No transpose)
|
|
*> = 'T': A**T * X = B (Transpose)
|
|
*> = 'C': A**H * X = B (Conjugate transpose = Transpose)
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] DIAG
|
|
*> \verbatim
|
|
*> DIAG is CHARACTER*1
|
|
*> Specifies whether or not the matrix A is unit triangular.
|
|
*> = 'N': Non-unit triangular
|
|
*> = 'U': Unit triangular
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The order of the matrix A. N >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] KD
|
|
*> \verbatim
|
|
*> KD is INTEGER
|
|
*> The number of superdiagonals or subdiagonals of the
|
|
*> triangular band matrix A. KD >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] NRHS
|
|
*> \verbatim
|
|
*> NRHS is INTEGER
|
|
*> The number of right hand sides, i.e., the number of columns
|
|
*> of the matrices X and B. NRHS >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] AB
|
|
*> \verbatim
|
|
*> AB is REAL array, dimension (LDAB,N)
|
|
*> The upper or lower triangular band matrix A, stored in the
|
|
*> first kd+1 rows of the array. The j-th column of A is stored
|
|
*> in the j-th column of the array AB as follows:
|
|
*> if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j;
|
|
*> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDAB
|
|
*> \verbatim
|
|
*> LDAB is INTEGER
|
|
*> The leading dimension of the array AB. LDAB >= KD+1.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] X
|
|
*> \verbatim
|
|
*> X is REAL array, dimension (LDX,NRHS)
|
|
*> The computed solution vectors for the system of linear
|
|
*> equations.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDX
|
|
*> \verbatim
|
|
*> LDX is INTEGER
|
|
*> The leading dimension of the array X. LDX >= max(1,N).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] B
|
|
*> \verbatim
|
|
*> B is REAL array, dimension (LDB,NRHS)
|
|
*> The right hand side vectors for the system of linear
|
|
*> equations.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDB
|
|
*> \verbatim
|
|
*> LDB is INTEGER
|
|
*> The leading dimension of the array B. LDB >= max(1,N).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] WORK
|
|
*> \verbatim
|
|
*> WORK is REAL array, dimension (N)
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] RESID
|
|
*> \verbatim
|
|
*> RESID is REAL
|
|
*> The maximum over the number of right hand sides of
|
|
*> norm(op(A)*x - b) / ( norm(op(A)) * norm(x) * EPS ).
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \ingroup single_lin
|
|
*
|
|
* =====================================================================
|
|
SUBROUTINE STBT02( UPLO, TRANS, DIAG, N, KD, NRHS, AB, LDAB, X,
|
|
$ LDX, B, LDB, WORK, RESID )
|
|
*
|
|
* -- LAPACK test routine --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER DIAG, TRANS, UPLO
|
|
INTEGER KD, LDAB, LDB, LDX, N, NRHS
|
|
REAL RESID
|
|
* ..
|
|
* .. Array Arguments ..
|
|
REAL AB( LDAB, * ), B( LDB, * ), WORK( * ),
|
|
$ X( LDX, * )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
REAL ZERO, ONE
|
|
PARAMETER ( ZERO = 0.0E+0, ONE = 1.0E+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER J
|
|
REAL ANORM, BNORM, EPS, XNORM
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
REAL SASUM, SLAMCH, SLANTB
|
|
EXTERNAL LSAME, SASUM, SLAMCH, SLANTB
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL SAXPY, SCOPY, STBMV
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MAX
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Quick exit if N = 0 or NRHS = 0
|
|
*
|
|
IF( N.LE.0 .OR. NRHS.LE.0 ) THEN
|
|
RESID = ZERO
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Compute the 1-norm of op(A).
|
|
*
|
|
IF( LSAME( TRANS, 'N' ) ) THEN
|
|
ANORM = SLANTB( '1', UPLO, DIAG, N, KD, AB, LDAB, WORK )
|
|
ELSE
|
|
ANORM = SLANTB( 'I', UPLO, DIAG, N, KD, AB, LDAB, WORK )
|
|
END IF
|
|
*
|
|
* Exit with RESID = 1/EPS if ANORM = 0.
|
|
*
|
|
EPS = SLAMCH( 'Epsilon' )
|
|
IF( ANORM.LE.ZERO ) THEN
|
|
RESID = ONE / EPS
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Compute the maximum over the number of right hand sides of
|
|
* norm(op(A)*x - b) / ( norm(op(A)) * norm(x) * EPS ).
|
|
*
|
|
RESID = ZERO
|
|
DO 10 J = 1, NRHS
|
|
CALL SCOPY( N, X( 1, J ), 1, WORK, 1 )
|
|
CALL STBMV( UPLO, TRANS, DIAG, N, KD, AB, LDAB, WORK, 1 )
|
|
CALL SAXPY( N, -ONE, B( 1, J ), 1, WORK, 1 )
|
|
BNORM = SASUM( N, WORK, 1 )
|
|
XNORM = SASUM( N, X( 1, J ), 1 )
|
|
IF( XNORM.LE.ZERO ) THEN
|
|
RESID = ONE / EPS
|
|
ELSE
|
|
RESID = MAX( RESID, ( ( BNORM / ANORM ) / XNORM ) / EPS )
|
|
END IF
|
|
10 CONTINUE
|
|
*
|
|
RETURN
|
|
*
|
|
* End of STBT02
|
|
*
|
|
END
|