305 lines
8.1 KiB
Fortran
305 lines
8.1 KiB
Fortran
*> \brief \b CGGBAK
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
*> \htmlonly
|
|
*> Download CGGBAK + dependencies
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cggbak.f">
|
|
*> [TGZ]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cggbak.f">
|
|
*> [ZIP]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cggbak.f">
|
|
*> [TXT]</a>
|
|
*> \endhtmlonly
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* SUBROUTINE CGGBAK( JOB, SIDE, N, ILO, IHI, LSCALE, RSCALE, M, V,
|
|
* LDV, INFO )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* CHARACTER JOB, SIDE
|
|
* INTEGER IHI, ILO, INFO, LDV, M, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* REAL LSCALE( * ), RSCALE( * )
|
|
* COMPLEX V( LDV, * )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> CGGBAK forms the right or left eigenvectors of a complex generalized
|
|
*> eigenvalue problem A*x = lambda*B*x, by backward transformation on
|
|
*> the computed eigenvectors of the balanced pair of matrices output by
|
|
*> CGGBAL.
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] JOB
|
|
*> \verbatim
|
|
*> JOB is CHARACTER*1
|
|
*> Specifies the type of backward transformation required:
|
|
*> = 'N': do nothing, return immediately;
|
|
*> = 'P': do backward transformation for permutation only;
|
|
*> = 'S': do backward transformation for scaling only;
|
|
*> = 'B': do backward transformations for both permutation and
|
|
*> scaling.
|
|
*> JOB must be the same as the argument JOB supplied to CGGBAL.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] SIDE
|
|
*> \verbatim
|
|
*> SIDE is CHARACTER*1
|
|
*> = 'R': V contains right eigenvectors;
|
|
*> = 'L': V contains left eigenvectors.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The number of rows of the matrix V. N >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] ILO
|
|
*> \verbatim
|
|
*> ILO is INTEGER
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] IHI
|
|
*> \verbatim
|
|
*> IHI is INTEGER
|
|
*> The integers ILO and IHI determined by CGGBAL.
|
|
*> 1 <= ILO <= IHI <= N, if N > 0; ILO=1 and IHI=0, if N=0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LSCALE
|
|
*> \verbatim
|
|
*> LSCALE is REAL array, dimension (N)
|
|
*> Details of the permutations and/or scaling factors applied
|
|
*> to the left side of A and B, as returned by CGGBAL.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] RSCALE
|
|
*> \verbatim
|
|
*> RSCALE is REAL array, dimension (N)
|
|
*> Details of the permutations and/or scaling factors applied
|
|
*> to the right side of A and B, as returned by CGGBAL.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] M
|
|
*> \verbatim
|
|
*> M is INTEGER
|
|
*> The number of columns of the matrix V. M >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in,out] V
|
|
*> \verbatim
|
|
*> V is COMPLEX array, dimension (LDV,M)
|
|
*> On entry, the matrix of right or left eigenvectors to be
|
|
*> transformed, as returned by CTGEVC.
|
|
*> On exit, V is overwritten by the transformed eigenvectors.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDV
|
|
*> \verbatim
|
|
*> LDV is INTEGER
|
|
*> The leading dimension of the matrix V. LDV >= max(1,N).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] INFO
|
|
*> \verbatim
|
|
*> INFO is INTEGER
|
|
*> = 0: successful exit.
|
|
*> < 0: if INFO = -i, the i-th argument had an illegal value.
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \ingroup complexGBcomputational
|
|
*
|
|
*> \par Further Details:
|
|
* =====================
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> See R.C. Ward, Balancing the generalized eigenvalue problem,
|
|
*> SIAM J. Sci. Stat. Comp. 2 (1981), 141-152.
|
|
*> \endverbatim
|
|
*>
|
|
* =====================================================================
|
|
SUBROUTINE CGGBAK( JOB, SIDE, N, ILO, IHI, LSCALE, RSCALE, M, V,
|
|
$ LDV, INFO )
|
|
*
|
|
* -- LAPACK computational routine --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER JOB, SIDE
|
|
INTEGER IHI, ILO, INFO, LDV, M, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
REAL LSCALE( * ), RSCALE( * )
|
|
COMPLEX V( LDV, * )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Local Scalars ..
|
|
LOGICAL LEFTV, RIGHTV
|
|
INTEGER I, K
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
EXTERNAL LSAME
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL CSSCAL, CSWAP, XERBLA
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MAX
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Test the input parameters
|
|
*
|
|
RIGHTV = LSAME( SIDE, 'R' )
|
|
LEFTV = LSAME( SIDE, 'L' )
|
|
*
|
|
INFO = 0
|
|
IF( .NOT.LSAME( JOB, 'N' ) .AND. .NOT.LSAME( JOB, 'P' ) .AND.
|
|
$ .NOT.LSAME( JOB, 'S' ) .AND. .NOT.LSAME( JOB, 'B' ) ) THEN
|
|
INFO = -1
|
|
ELSE IF( .NOT.RIGHTV .AND. .NOT.LEFTV ) THEN
|
|
INFO = -2
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -3
|
|
ELSE IF( ILO.LT.1 ) THEN
|
|
INFO = -4
|
|
ELSE IF( N.EQ.0 .AND. IHI.EQ.0 .AND. ILO.NE.1 ) THEN
|
|
INFO = -4
|
|
ELSE IF( N.GT.0 .AND. ( IHI.LT.ILO .OR. IHI.GT.MAX( 1, N ) ) )
|
|
$ THEN
|
|
INFO = -5
|
|
ELSE IF( N.EQ.0 .AND. ILO.EQ.1 .AND. IHI.NE.0 ) THEN
|
|
INFO = -5
|
|
ELSE IF( M.LT.0 ) THEN
|
|
INFO = -8
|
|
ELSE IF( LDV.LT.MAX( 1, N ) ) THEN
|
|
INFO = -10
|
|
END IF
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'CGGBAK', -INFO )
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Quick return if possible
|
|
*
|
|
IF( N.EQ.0 )
|
|
$ RETURN
|
|
IF( M.EQ.0 )
|
|
$ RETURN
|
|
IF( LSAME( JOB, 'N' ) )
|
|
$ RETURN
|
|
*
|
|
IF( ILO.EQ.IHI )
|
|
$ GO TO 30
|
|
*
|
|
* Backward balance
|
|
*
|
|
IF( LSAME( JOB, 'S' ) .OR. LSAME( JOB, 'B' ) ) THEN
|
|
*
|
|
* Backward transformation on right eigenvectors
|
|
*
|
|
IF( RIGHTV ) THEN
|
|
DO 10 I = ILO, IHI
|
|
CALL CSSCAL( M, RSCALE( I ), V( I, 1 ), LDV )
|
|
10 CONTINUE
|
|
END IF
|
|
*
|
|
* Backward transformation on left eigenvectors
|
|
*
|
|
IF( LEFTV ) THEN
|
|
DO 20 I = ILO, IHI
|
|
CALL CSSCAL( M, LSCALE( I ), V( I, 1 ), LDV )
|
|
20 CONTINUE
|
|
END IF
|
|
END IF
|
|
*
|
|
* Backward permutation
|
|
*
|
|
30 CONTINUE
|
|
IF( LSAME( JOB, 'P' ) .OR. LSAME( JOB, 'B' ) ) THEN
|
|
*
|
|
* Backward permutation on right eigenvectors
|
|
*
|
|
IF( RIGHTV ) THEN
|
|
IF( ILO.EQ.1 )
|
|
$ GO TO 50
|
|
DO 40 I = ILO - 1, 1, -1
|
|
K = INT( RSCALE( I ) )
|
|
IF( K.EQ.I )
|
|
$ GO TO 40
|
|
CALL CSWAP( M, V( I, 1 ), LDV, V( K, 1 ), LDV )
|
|
40 CONTINUE
|
|
*
|
|
50 CONTINUE
|
|
IF( IHI.EQ.N )
|
|
$ GO TO 70
|
|
DO 60 I = IHI + 1, N
|
|
K = INT( RSCALE( I ) )
|
|
IF( K.EQ.I )
|
|
$ GO TO 60
|
|
CALL CSWAP( M, V( I, 1 ), LDV, V( K, 1 ), LDV )
|
|
60 CONTINUE
|
|
END IF
|
|
*
|
|
* Backward permutation on left eigenvectors
|
|
*
|
|
70 CONTINUE
|
|
IF( LEFTV ) THEN
|
|
IF( ILO.EQ.1 )
|
|
$ GO TO 90
|
|
DO 80 I = ILO - 1, 1, -1
|
|
K = INT( LSCALE( I ) )
|
|
IF( K.EQ.I )
|
|
$ GO TO 80
|
|
CALL CSWAP( M, V( I, 1 ), LDV, V( K, 1 ), LDV )
|
|
80 CONTINUE
|
|
*
|
|
90 CONTINUE
|
|
IF( IHI.EQ.N )
|
|
$ GO TO 110
|
|
DO 100 I = IHI + 1, N
|
|
K = INT( LSCALE( I ) )
|
|
IF( K.EQ.I )
|
|
$ GO TO 100
|
|
CALL CSWAP( M, V( I, 1 ), LDV, V( K, 1 ), LDV )
|
|
100 CONTINUE
|
|
END IF
|
|
END IF
|
|
*
|
|
110 CONTINUE
|
|
*
|
|
RETURN
|
|
*
|
|
* End of CGGBAK
|
|
*
|
|
END
|