328 lines
8.5 KiB
Fortran
328 lines
8.5 KiB
Fortran
*> \brief \b CLA_HERCOND_C computes the infinity norm condition number of op(A)*inv(diag(c)) for Hermitian indefinite matrices.
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
*> \htmlonly
|
|
*> Download CLA_HERCOND_C + dependencies
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cla_hercond_c.f">
|
|
*> [TGZ]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cla_hercond_c.f">
|
|
*> [ZIP]</a>
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cla_hercond_c.f">
|
|
*> [TXT]</a>
|
|
*> \endhtmlonly
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* REAL FUNCTION CLA_HERCOND_C( UPLO, N, A, LDA, AF, LDAF, IPIV, C,
|
|
* CAPPLY, INFO, WORK, RWORK )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* CHARACTER UPLO
|
|
* LOGICAL CAPPLY
|
|
* INTEGER N, LDA, LDAF, INFO
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* INTEGER IPIV( * )
|
|
* COMPLEX A( LDA, * ), AF( LDAF, * ), WORK( * )
|
|
* REAL C ( * ), RWORK( * )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> CLA_HERCOND_C computes the infinity norm condition number of
|
|
*> op(A) * inv(diag(C)) where C is a REAL vector.
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] UPLO
|
|
*> \verbatim
|
|
*> UPLO is CHARACTER*1
|
|
*> = 'U': Upper triangle of A is stored;
|
|
*> = 'L': Lower triangle of A is stored.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The number of linear equations, i.e., the order of the
|
|
*> matrix A. N >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] A
|
|
*> \verbatim
|
|
*> A is COMPLEX array, dimension (LDA,N)
|
|
*> On entry, the N-by-N matrix A
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDA
|
|
*> \verbatim
|
|
*> LDA is INTEGER
|
|
*> The leading dimension of the array A. LDA >= max(1,N).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] AF
|
|
*> \verbatim
|
|
*> AF is COMPLEX array, dimension (LDAF,N)
|
|
*> The block diagonal matrix D and the multipliers used to
|
|
*> obtain the factor U or L as computed by CHETRF.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDAF
|
|
*> \verbatim
|
|
*> LDAF is INTEGER
|
|
*> The leading dimension of the array AF. LDAF >= max(1,N).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] IPIV
|
|
*> \verbatim
|
|
*> IPIV is INTEGER array, dimension (N)
|
|
*> Details of the interchanges and the block structure of D
|
|
*> as determined by CHETRF.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] C
|
|
*> \verbatim
|
|
*> C is REAL array, dimension (N)
|
|
*> The vector C in the formula op(A) * inv(diag(C)).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] CAPPLY
|
|
*> \verbatim
|
|
*> CAPPLY is LOGICAL
|
|
*> If .TRUE. then access the vector C in the formula above.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] INFO
|
|
*> \verbatim
|
|
*> INFO is INTEGER
|
|
*> = 0: Successful exit.
|
|
*> i > 0: The ith argument is invalid.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] WORK
|
|
*> \verbatim
|
|
*> WORK is COMPLEX array, dimension (2*N).
|
|
*> Workspace.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] RWORK
|
|
*> \verbatim
|
|
*> RWORK is REAL array, dimension (N).
|
|
*> Workspace.
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \date September 2012
|
|
*
|
|
*> \ingroup complexHEcomputational
|
|
*
|
|
* =====================================================================
|
|
REAL FUNCTION CLA_HERCOND_C( UPLO, N, A, LDA, AF, LDAF, IPIV, C,
|
|
$ CAPPLY, INFO, WORK, RWORK )
|
|
*
|
|
* -- LAPACK computational routine (version 3.4.2) --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
* September 2012
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER UPLO
|
|
LOGICAL CAPPLY
|
|
INTEGER N, LDA, LDAF, INFO
|
|
* ..
|
|
* .. Array Arguments ..
|
|
INTEGER IPIV( * )
|
|
COMPLEX A( LDA, * ), AF( LDAF, * ), WORK( * )
|
|
REAL C ( * ), RWORK( * )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Local Scalars ..
|
|
INTEGER KASE, I, J
|
|
REAL AINVNM, ANORM, TMP
|
|
LOGICAL UP, UPPER
|
|
COMPLEX ZDUM
|
|
* ..
|
|
* .. Local Arrays ..
|
|
INTEGER ISAVE( 3 )
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
EXTERNAL LSAME
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL CLACN2, CHETRS, XERBLA
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC ABS, MAX
|
|
* ..
|
|
* .. Statement Functions ..
|
|
REAL CABS1
|
|
* ..
|
|
* .. Statement Function Definitions ..
|
|
CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
CLA_HERCOND_C = 0.0E+0
|
|
*
|
|
INFO = 0
|
|
UPPER = LSAME( UPLO, 'U' )
|
|
IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
|
|
INFO = -1
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -2
|
|
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
|
|
INFO = -4
|
|
ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
|
|
INFO = -6
|
|
END IF
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'CLA_HERCOND_C', -INFO )
|
|
RETURN
|
|
END IF
|
|
UP = .FALSE.
|
|
IF ( LSAME( UPLO, 'U' ) ) UP = .TRUE.
|
|
*
|
|
* Compute norm of op(A)*op2(C).
|
|
*
|
|
ANORM = 0.0E+0
|
|
IF ( UP ) THEN
|
|
DO I = 1, N
|
|
TMP = 0.0E+0
|
|
IF ( CAPPLY ) THEN
|
|
DO J = 1, I
|
|
TMP = TMP + CABS1( A( J, I ) ) / C( J )
|
|
END DO
|
|
DO J = I+1, N
|
|
TMP = TMP + CABS1( A( I, J ) ) / C( J )
|
|
END DO
|
|
ELSE
|
|
DO J = 1, I
|
|
TMP = TMP + CABS1( A( J, I ) )
|
|
END DO
|
|
DO J = I+1, N
|
|
TMP = TMP + CABS1( A( I, J ) )
|
|
END DO
|
|
END IF
|
|
RWORK( I ) = TMP
|
|
ANORM = MAX( ANORM, TMP )
|
|
END DO
|
|
ELSE
|
|
DO I = 1, N
|
|
TMP = 0.0E+0
|
|
IF ( CAPPLY ) THEN
|
|
DO J = 1, I
|
|
TMP = TMP + CABS1( A( I, J ) ) / C( J )
|
|
END DO
|
|
DO J = I+1, N
|
|
TMP = TMP + CABS1( A( J, I ) ) / C( J )
|
|
END DO
|
|
ELSE
|
|
DO J = 1, I
|
|
TMP = TMP + CABS1( A( I, J ) )
|
|
END DO
|
|
DO J = I+1, N
|
|
TMP = TMP + CABS1( A( J, I ) )
|
|
END DO
|
|
END IF
|
|
RWORK( I ) = TMP
|
|
ANORM = MAX( ANORM, TMP )
|
|
END DO
|
|
END IF
|
|
*
|
|
* Quick return if possible.
|
|
*
|
|
IF( N.EQ.0 ) THEN
|
|
CLA_HERCOND_C = 1.0E+0
|
|
RETURN
|
|
ELSE IF( ANORM .EQ. 0.0E+0 ) THEN
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Estimate the norm of inv(op(A)).
|
|
*
|
|
AINVNM = 0.0E+0
|
|
*
|
|
KASE = 0
|
|
10 CONTINUE
|
|
CALL CLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
|
|
IF( KASE.NE.0 ) THEN
|
|
IF( KASE.EQ.2 ) THEN
|
|
*
|
|
* Multiply by R.
|
|
*
|
|
DO I = 1, N
|
|
WORK( I ) = WORK( I ) * RWORK( I )
|
|
END DO
|
|
*
|
|
IF ( UP ) THEN
|
|
CALL CHETRS( 'U', N, 1, AF, LDAF, IPIV,
|
|
$ WORK, N, INFO )
|
|
ELSE
|
|
CALL CHETRS( 'L', N, 1, AF, LDAF, IPIV,
|
|
$ WORK, N, INFO )
|
|
ENDIF
|
|
*
|
|
* Multiply by inv(C).
|
|
*
|
|
IF ( CAPPLY ) THEN
|
|
DO I = 1, N
|
|
WORK( I ) = WORK( I ) * C( I )
|
|
END DO
|
|
END IF
|
|
ELSE
|
|
*
|
|
* Multiply by inv(C**H).
|
|
*
|
|
IF ( CAPPLY ) THEN
|
|
DO I = 1, N
|
|
WORK( I ) = WORK( I ) * C( I )
|
|
END DO
|
|
END IF
|
|
*
|
|
IF ( UP ) THEN
|
|
CALL CHETRS( 'U', N, 1, AF, LDAF, IPIV,
|
|
$ WORK, N, INFO )
|
|
ELSE
|
|
CALL CHETRS( 'L', N, 1, AF, LDAF, IPIV,
|
|
$ WORK, N, INFO )
|
|
END IF
|
|
*
|
|
* Multiply by R.
|
|
*
|
|
DO I = 1, N
|
|
WORK( I ) = WORK( I ) * RWORK( I )
|
|
END DO
|
|
END IF
|
|
GO TO 10
|
|
END IF
|
|
*
|
|
* Compute the estimate of the reciprocal condition number.
|
|
*
|
|
IF( AINVNM .NE. 0.0E+0 )
|
|
$ CLA_HERCOND_C = 1.0E+0 / AINVNM
|
|
*
|
|
RETURN
|
|
*
|
|
END
|