338 lines
9.3 KiB
Fortran
338 lines
9.3 KiB
Fortran
*> \brief \b CHEMV
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* SUBROUTINE CHEMV(UPLO,N,ALPHA,A,LDA,X,INCX,BETA,Y,INCY)
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* COMPLEX ALPHA,BETA
|
|
* INTEGER INCX,INCY,LDA,N
|
|
* CHARACTER UPLO
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* COMPLEX A(LDA,*),X(*),Y(*)
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> CHEMV performs the matrix-vector operation
|
|
*>
|
|
*> y := alpha*A*x + beta*y,
|
|
*>
|
|
*> where alpha and beta are scalars, x and y are n element vectors and
|
|
*> A is an n by n hermitian matrix.
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] UPLO
|
|
*> \verbatim
|
|
*> UPLO is CHARACTER*1
|
|
*> On entry, UPLO specifies whether the upper or lower
|
|
*> triangular part of the array A is to be referenced as
|
|
*> follows:
|
|
*>
|
|
*> UPLO = 'U' or 'u' Only the upper triangular part of A
|
|
*> is to be referenced.
|
|
*>
|
|
*> UPLO = 'L' or 'l' Only the lower triangular part of A
|
|
*> is to be referenced.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> On entry, N specifies the order of the matrix A.
|
|
*> N must be at least zero.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] ALPHA
|
|
*> \verbatim
|
|
*> ALPHA is COMPLEX
|
|
*> On entry, ALPHA specifies the scalar alpha.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] A
|
|
*> \verbatim
|
|
*> A is COMPLEX array of DIMENSION ( LDA, n ).
|
|
*> Before entry with UPLO = 'U' or 'u', the leading n by n
|
|
*> upper triangular part of the array A must contain the upper
|
|
*> triangular part of the hermitian matrix and the strictly
|
|
*> lower triangular part of A is not referenced.
|
|
*> Before entry with UPLO = 'L' or 'l', the leading n by n
|
|
*> lower triangular part of the array A must contain the lower
|
|
*> triangular part of the hermitian matrix and the strictly
|
|
*> upper triangular part of A is not referenced.
|
|
*> Note that the imaginary parts of the diagonal elements need
|
|
*> not be set and are assumed to be zero.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDA
|
|
*> \verbatim
|
|
*> LDA is INTEGER
|
|
*> On entry, LDA specifies the first dimension of A as declared
|
|
*> in the calling (sub) program. LDA must be at least
|
|
*> max( 1, n ).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] X
|
|
*> \verbatim
|
|
*> X is COMPLEX array of dimension at least
|
|
*> ( 1 + ( n - 1 )*abs( INCX ) ).
|
|
*> Before entry, the incremented array X must contain the n
|
|
*> element vector x.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] INCX
|
|
*> \verbatim
|
|
*> INCX is INTEGER
|
|
*> On entry, INCX specifies the increment for the elements of
|
|
*> X. INCX must not be zero.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] BETA
|
|
*> \verbatim
|
|
*> BETA is COMPLEX
|
|
*> On entry, BETA specifies the scalar beta. When BETA is
|
|
*> supplied as zero then Y need not be set on input.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in,out] Y
|
|
*> \verbatim
|
|
*> Y is COMPLEX array of dimension at least
|
|
*> ( 1 + ( n - 1 )*abs( INCY ) ).
|
|
*> Before entry, the incremented array Y must contain the n
|
|
*> element vector y. On exit, Y is overwritten by the updated
|
|
*> vector y.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] INCY
|
|
*> \verbatim
|
|
*> INCY is INTEGER
|
|
*> On entry, INCY specifies the increment for the elements of
|
|
*> Y. INCY must not be zero.
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \date November 2011
|
|
*
|
|
*> \ingroup complex_blas_level2
|
|
*
|
|
*> \par Further Details:
|
|
* =====================
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> Level 2 Blas routine.
|
|
*> The vector and matrix arguments are not referenced when N = 0, or M = 0
|
|
*>
|
|
*> -- Written on 22-October-1986.
|
|
*> Jack Dongarra, Argonne National Lab.
|
|
*> Jeremy Du Croz, Nag Central Office.
|
|
*> Sven Hammarling, Nag Central Office.
|
|
*> Richard Hanson, Sandia National Labs.
|
|
*> \endverbatim
|
|
*>
|
|
* =====================================================================
|
|
SUBROUTINE CHEMV(UPLO,N,ALPHA,A,LDA,X,INCX,BETA,Y,INCY)
|
|
*
|
|
* -- Reference BLAS level2 routine (version 3.4.0) --
|
|
* -- Reference BLAS is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
* November 2011
|
|
*
|
|
* .. Scalar Arguments ..
|
|
COMPLEX ALPHA,BETA
|
|
INTEGER INCX,INCY,LDA,N
|
|
CHARACTER UPLO
|
|
* ..
|
|
* .. Array Arguments ..
|
|
COMPLEX A(LDA,*),X(*),Y(*)
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
COMPLEX ONE
|
|
PARAMETER (ONE= (1.0E+0,0.0E+0))
|
|
COMPLEX ZERO
|
|
PARAMETER (ZERO= (0.0E+0,0.0E+0))
|
|
* ..
|
|
* .. Local Scalars ..
|
|
COMPLEX TEMP1,TEMP2
|
|
INTEGER I,INFO,IX,IY,J,JX,JY,KX,KY
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
EXTERNAL LSAME
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL XERBLA
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC CONJG,MAX,REAL
|
|
* ..
|
|
*
|
|
* Test the input parameters.
|
|
*
|
|
INFO = 0
|
|
IF (.NOT.LSAME(UPLO,'U') .AND. .NOT.LSAME(UPLO,'L')) THEN
|
|
INFO = 1
|
|
ELSE IF (N.LT.0) THEN
|
|
INFO = 2
|
|
ELSE IF (LDA.LT.MAX(1,N)) THEN
|
|
INFO = 5
|
|
ELSE IF (INCX.EQ.0) THEN
|
|
INFO = 7
|
|
ELSE IF (INCY.EQ.0) THEN
|
|
INFO = 10
|
|
END IF
|
|
IF (INFO.NE.0) THEN
|
|
CALL XERBLA('CHEMV ',INFO)
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Quick return if possible.
|
|
*
|
|
IF ((N.EQ.0) .OR. ((ALPHA.EQ.ZERO).AND. (BETA.EQ.ONE))) RETURN
|
|
*
|
|
* Set up the start points in X and Y.
|
|
*
|
|
IF (INCX.GT.0) THEN
|
|
KX = 1
|
|
ELSE
|
|
KX = 1 - (N-1)*INCX
|
|
END IF
|
|
IF (INCY.GT.0) THEN
|
|
KY = 1
|
|
ELSE
|
|
KY = 1 - (N-1)*INCY
|
|
END IF
|
|
*
|
|
* Start the operations. In this version the elements of A are
|
|
* accessed sequentially with one pass through the triangular part
|
|
* of A.
|
|
*
|
|
* First form y := beta*y.
|
|
*
|
|
IF (BETA.NE.ONE) THEN
|
|
IF (INCY.EQ.1) THEN
|
|
IF (BETA.EQ.ZERO) THEN
|
|
DO 10 I = 1,N
|
|
Y(I) = ZERO
|
|
10 CONTINUE
|
|
ELSE
|
|
DO 20 I = 1,N
|
|
Y(I) = BETA*Y(I)
|
|
20 CONTINUE
|
|
END IF
|
|
ELSE
|
|
IY = KY
|
|
IF (BETA.EQ.ZERO) THEN
|
|
DO 30 I = 1,N
|
|
Y(IY) = ZERO
|
|
IY = IY + INCY
|
|
30 CONTINUE
|
|
ELSE
|
|
DO 40 I = 1,N
|
|
Y(IY) = BETA*Y(IY)
|
|
IY = IY + INCY
|
|
40 CONTINUE
|
|
END IF
|
|
END IF
|
|
END IF
|
|
IF (ALPHA.EQ.ZERO) RETURN
|
|
IF (LSAME(UPLO,'U')) THEN
|
|
*
|
|
* Form y when A is stored in upper triangle.
|
|
*
|
|
IF ((INCX.EQ.1) .AND. (INCY.EQ.1)) THEN
|
|
DO 60 J = 1,N
|
|
TEMP1 = ALPHA*X(J)
|
|
TEMP2 = ZERO
|
|
DO 50 I = 1,J - 1
|
|
Y(I) = Y(I) + TEMP1*A(I,J)
|
|
TEMP2 = TEMP2 + CONJG(A(I,J))*X(I)
|
|
50 CONTINUE
|
|
Y(J) = Y(J) + TEMP1*REAL(A(J,J)) + ALPHA*TEMP2
|
|
60 CONTINUE
|
|
ELSE
|
|
JX = KX
|
|
JY = KY
|
|
DO 80 J = 1,N
|
|
TEMP1 = ALPHA*X(JX)
|
|
TEMP2 = ZERO
|
|
IX = KX
|
|
IY = KY
|
|
DO 70 I = 1,J - 1
|
|
Y(IY) = Y(IY) + TEMP1*A(I,J)
|
|
TEMP2 = TEMP2 + CONJG(A(I,J))*X(IX)
|
|
IX = IX + INCX
|
|
IY = IY + INCY
|
|
70 CONTINUE
|
|
Y(JY) = Y(JY) + TEMP1*REAL(A(J,J)) + ALPHA*TEMP2
|
|
JX = JX + INCX
|
|
JY = JY + INCY
|
|
80 CONTINUE
|
|
END IF
|
|
ELSE
|
|
*
|
|
* Form y when A is stored in lower triangle.
|
|
*
|
|
IF ((INCX.EQ.1) .AND. (INCY.EQ.1)) THEN
|
|
DO 100 J = 1,N
|
|
TEMP1 = ALPHA*X(J)
|
|
TEMP2 = ZERO
|
|
Y(J) = Y(J) + TEMP1*REAL(A(J,J))
|
|
DO 90 I = J + 1,N
|
|
Y(I) = Y(I) + TEMP1*A(I,J)
|
|
TEMP2 = TEMP2 + CONJG(A(I,J))*X(I)
|
|
90 CONTINUE
|
|
Y(J) = Y(J) + ALPHA*TEMP2
|
|
100 CONTINUE
|
|
ELSE
|
|
JX = KX
|
|
JY = KY
|
|
DO 120 J = 1,N
|
|
TEMP1 = ALPHA*X(JX)
|
|
TEMP2 = ZERO
|
|
Y(JY) = Y(JY) + TEMP1*REAL(A(J,J))
|
|
IX = JX
|
|
IY = JY
|
|
DO 110 I = J + 1,N
|
|
IX = IX + INCX
|
|
IY = IY + INCY
|
|
Y(IY) = Y(IY) + TEMP1*A(I,J)
|
|
TEMP2 = TEMP2 + CONJG(A(I,J))*X(IX)
|
|
110 CONTINUE
|
|
Y(JY) = Y(JY) + ALPHA*TEMP2
|
|
JX = JX + INCX
|
|
JY = JY + INCY
|
|
120 CONTINUE
|
|
END IF
|
|
END IF
|
|
*
|
|
RETURN
|
|
*
|
|
* End of CHEMV .
|
|
*
|
|
END
|