added lapack 3.7.0 with latest patches from git
This commit is contained in:
Werner Saar
@@ -0,0 +1,241 @@
|
||||
*> \brief \b SPPT03
|
||||
*
|
||||
* =========== DOCUMENTATION ===========
|
||||
*
|
||||
* Online html documentation available at
|
||||
* http://www.netlib.org/lapack/explore-html/
|
||||
*
|
||||
* Definition:
|
||||
* ===========
|
||||
*
|
||||
* SUBROUTINE SPPT03( UPLO, N, A, AINV, WORK, LDWORK, RWORK, RCOND,
|
||||
* RESID )
|
||||
*
|
||||
* .. Scalar Arguments ..
|
||||
* CHARACTER UPLO
|
||||
* INTEGER LDWORK, N
|
||||
* REAL RCOND, RESID
|
||||
* ..
|
||||
* .. Array Arguments ..
|
||||
* REAL A( * ), AINV( * ), RWORK( * ),
|
||||
* $ WORK( LDWORK, * )
|
||||
* ..
|
||||
*
|
||||
*
|
||||
*> \par Purpose:
|
||||
* =============
|
||||
*>
|
||||
*> \verbatim
|
||||
*>
|
||||
*> SPPT03 computes the residual for a symmetric packed matrix times its
|
||||
*> inverse:
|
||||
*> norm( I - A*AINV ) / ( N * norm(A) * norm(AINV) * EPS ),
|
||||
*> where EPS is the machine epsilon.
|
||||
*> \endverbatim
|
||||
*
|
||||
* Arguments:
|
||||
* ==========
|
||||
*
|
||||
*> \param[in] UPLO
|
||||
*> \verbatim
|
||||
*> UPLO is CHARACTER*1
|
||||
*> Specifies whether the upper or lower triangular part of the
|
||||
*> symmetric matrix A is stored:
|
||||
*> = 'U': Upper triangular
|
||||
*> = 'L': Lower triangular
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] N
|
||||
*> \verbatim
|
||||
*> N is INTEGER
|
||||
*> The number of rows and columns of the matrix A. N >= 0.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] A
|
||||
*> \verbatim
|
||||
*> A is REAL array, dimension (N*(N+1)/2)
|
||||
*> The original symmetric matrix A, stored as a packed
|
||||
*> triangular matrix.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] AINV
|
||||
*> \verbatim
|
||||
*> AINV is REAL array, dimension (N*(N+1)/2)
|
||||
*> The (symmetric) inverse of the matrix A, stored as a packed
|
||||
*> triangular matrix.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[out] WORK
|
||||
*> \verbatim
|
||||
*> WORK is REAL array, dimension (LDWORK,N)
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] LDWORK
|
||||
*> \verbatim
|
||||
*> LDWORK is INTEGER
|
||||
*> The leading dimension of the array WORK. LDWORK >= max(1,N).
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[out] RWORK
|
||||
*> \verbatim
|
||||
*> RWORK is REAL array, dimension (N)
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[out] RCOND
|
||||
*> \verbatim
|
||||
*> RCOND is REAL
|
||||
*> The reciprocal of the condition number of A, computed as
|
||||
*> ( 1/norm(A) ) / norm(AINV).
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[out] RESID
|
||||
*> \verbatim
|
||||
*> RESID is REAL
|
||||
*> norm(I - A*AINV) / ( N * norm(A) * norm(AINV) * EPS )
|
||||
*> \endverbatim
|
||||
*
|
||||
* Authors:
|
||||
* ========
|
||||
*
|
||||
*> \author Univ. of Tennessee
|
||||
*> \author Univ. of California Berkeley
|
||||
*> \author Univ. of Colorado Denver
|
||||
*> \author NAG Ltd.
|
||||
*
|
||||
*> \date December 2016
|
||||
*
|
||||
*> \ingroup single_lin
|
||||
*
|
||||
* =====================================================================
|
||||
SUBROUTINE SPPT03( UPLO, N, A, AINV, WORK, LDWORK, RWORK, RCOND,
|
||||
$ RESID )
|
||||
*
|
||||
* -- LAPACK test routine (version 3.7.0) --
|
||||
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
||||
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
||||
* December 2016
|
||||
*
|
||||
* .. Scalar Arguments ..
|
||||
CHARACTER UPLO
|
||||
INTEGER LDWORK, N
|
||||
REAL RCOND, RESID
|
||||
* ..
|
||||
* .. Array Arguments ..
|
||||
REAL A( * ), AINV( * ), RWORK( * ),
|
||||
$ WORK( LDWORK, * )
|
||||
* ..
|
||||
*
|
||||
* =====================================================================
|
||||
*
|
||||
* .. Parameters ..
|
||||
REAL ZERO, ONE
|
||||
PARAMETER ( ZERO = 0.0E+0, ONE = 1.0E+0 )
|
||||
* ..
|
||||
* .. Local Scalars ..
|
||||
INTEGER I, J, JJ
|
||||
REAL AINVNM, ANORM, EPS
|
||||
* ..
|
||||
* .. External Functions ..
|
||||
LOGICAL LSAME
|
||||
REAL SLAMCH, SLANGE, SLANSP
|
||||
EXTERNAL LSAME, SLAMCH, SLANGE, SLANSP
|
||||
* ..
|
||||
* .. Intrinsic Functions ..
|
||||
INTRINSIC REAL
|
||||
* ..
|
||||
* .. External Subroutines ..
|
||||
EXTERNAL SCOPY, SSPMV
|
||||
* ..
|
||||
* .. Executable Statements ..
|
||||
*
|
||||
* Quick exit if N = 0.
|
||||
*
|
||||
IF( N.LE.0 ) THEN
|
||||
RCOND = ONE
|
||||
RESID = ZERO
|
||||
RETURN
|
||||
END IF
|
||||
*
|
||||
* Exit with RESID = 1/EPS if ANORM = 0 or AINVNM = 0.
|
||||
*
|
||||
EPS = SLAMCH( 'Epsilon' )
|
||||
ANORM = SLANSP( '1', UPLO, N, A, RWORK )
|
||||
AINVNM = SLANSP( '1', UPLO, N, AINV, RWORK )
|
||||
IF( ANORM.LE.ZERO .OR. AINVNM.EQ.ZERO ) THEN
|
||||
RCOND = ZERO
|
||||
RESID = ONE / EPS
|
||||
RETURN
|
||||
END IF
|
||||
RCOND = ( ONE / ANORM ) / AINVNM
|
||||
*
|
||||
* UPLO = 'U':
|
||||
* Copy the leading N-1 x N-1 submatrix of AINV to WORK(1:N,2:N) and
|
||||
* expand it to a full matrix, then multiply by A one column at a
|
||||
* time, moving the result one column to the left.
|
||||
*
|
||||
IF( LSAME( UPLO, 'U' ) ) THEN
|
||||
*
|
||||
* Copy AINV
|
||||
*
|
||||
JJ = 1
|
||||
DO 10 J = 1, N - 1
|
||||
CALL SCOPY( J, AINV( JJ ), 1, WORK( 1, J+1 ), 1 )
|
||||
CALL SCOPY( J-1, AINV( JJ ), 1, WORK( J, 2 ), LDWORK )
|
||||
JJ = JJ + J
|
||||
10 CONTINUE
|
||||
JJ = ( ( N-1 )*N ) / 2 + 1
|
||||
CALL SCOPY( N-1, AINV( JJ ), 1, WORK( N, 2 ), LDWORK )
|
||||
*
|
||||
* Multiply by A
|
||||
*
|
||||
DO 20 J = 1, N - 1
|
||||
CALL SSPMV( 'Upper', N, -ONE, A, WORK( 1, J+1 ), 1, ZERO,
|
||||
$ WORK( 1, J ), 1 )
|
||||
20 CONTINUE
|
||||
CALL SSPMV( 'Upper', N, -ONE, A, AINV( JJ ), 1, ZERO,
|
||||
$ WORK( 1, N ), 1 )
|
||||
*
|
||||
* UPLO = 'L':
|
||||
* Copy the trailing N-1 x N-1 submatrix of AINV to WORK(1:N,1:N-1)
|
||||
* and multiply by A, moving each column to the right.
|
||||
*
|
||||
ELSE
|
||||
*
|
||||
* Copy AINV
|
||||
*
|
||||
CALL SCOPY( N-1, AINV( 2 ), 1, WORK( 1, 1 ), LDWORK )
|
||||
JJ = N + 1
|
||||
DO 30 J = 2, N
|
||||
CALL SCOPY( N-J+1, AINV( JJ ), 1, WORK( J, J-1 ), 1 )
|
||||
CALL SCOPY( N-J, AINV( JJ+1 ), 1, WORK( J, J ), LDWORK )
|
||||
JJ = JJ + N - J + 1
|
||||
30 CONTINUE
|
||||
*
|
||||
* Multiply by A
|
||||
*
|
||||
DO 40 J = N, 2, -1
|
||||
CALL SSPMV( 'Lower', N, -ONE, A, WORK( 1, J-1 ), 1, ZERO,
|
||||
$ WORK( 1, J ), 1 )
|
||||
40 CONTINUE
|
||||
CALL SSPMV( 'Lower', N, -ONE, A, AINV( 1 ), 1, ZERO,
|
||||
$ WORK( 1, 1 ), 1 )
|
||||
*
|
||||
END IF
|
||||
*
|
||||
* Add the identity matrix to WORK .
|
||||
*
|
||||
DO 50 I = 1, N
|
||||
WORK( I, I ) = WORK( I, I ) + ONE
|
||||
50 CONTINUE
|
||||
*
|
||||
* Compute norm(I - A*AINV) / (N * norm(A) * norm(AINV) * EPS)
|
||||
*
|
||||
RESID = SLANGE( '1', N, N, WORK, LDWORK, RWORK )
|
||||
*
|
||||
RESID = ( ( RESID*RCOND ) / EPS ) / REAL( N )
|
||||
*
|
||||
RETURN
|
||||
*
|
||||
* End of SPPT03
|
||||
*
|
||||
END
|
||||
Reference in New Issue
Block a user