added lapack 3.7.0 with latest patches from git
This commit is contained in:
Werner Saar
208
lapack-netlib/SRC/zlangt.f
Normal file
208
lapack-netlib/SRC/zlangt.f
Normal file
@@ -0,0 +1,208 @@
|
||||
*> \brief \b ZLANGT returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of a general tridiagonal matrix.
|
||||
*
|
||||
* =========== DOCUMENTATION ===========
|
||||
*
|
||||
* Online html documentation available at
|
||||
* http://www.netlib.org/lapack/explore-html/
|
||||
*
|
||||
*> \htmlonly
|
||||
*> Download ZLANGT + dependencies
|
||||
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlangt.f">
|
||||
*> [TGZ]</a>
|
||||
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlangt.f">
|
||||
*> [ZIP]</a>
|
||||
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlangt.f">
|
||||
*> [TXT]</a>
|
||||
*> \endhtmlonly
|
||||
*
|
||||
* Definition:
|
||||
* ===========
|
||||
*
|
||||
* DOUBLE PRECISION FUNCTION ZLANGT( NORM, N, DL, D, DU )
|
||||
*
|
||||
* .. Scalar Arguments ..
|
||||
* CHARACTER NORM
|
||||
* INTEGER N
|
||||
* ..
|
||||
* .. Array Arguments ..
|
||||
* COMPLEX*16 D( * ), DL( * ), DU( * )
|
||||
* ..
|
||||
*
|
||||
*
|
||||
*> \par Purpose:
|
||||
* =============
|
||||
*>
|
||||
*> \verbatim
|
||||
*>
|
||||
*> ZLANGT returns the value of the one norm, or the Frobenius norm, or
|
||||
*> the infinity norm, or the element of largest absolute value of a
|
||||
*> complex tridiagonal matrix A.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \return ZLANGT
|
||||
*> \verbatim
|
||||
*>
|
||||
*> ZLANGT = ( max(abs(A(i,j))), NORM = 'M' or 'm'
|
||||
*> (
|
||||
*> ( norm1(A), NORM = '1', 'O' or 'o'
|
||||
*> (
|
||||
*> ( normI(A), NORM = 'I' or 'i'
|
||||
*> (
|
||||
*> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
|
||||
*>
|
||||
*> where norm1 denotes the one norm of a matrix (maximum column sum),
|
||||
*> normI denotes the infinity norm of a matrix (maximum row sum) and
|
||||
*> normF denotes the Frobenius norm of a matrix (square root of sum of
|
||||
*> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
|
||||
*> \endverbatim
|
||||
*
|
||||
* Arguments:
|
||||
* ==========
|
||||
*
|
||||
*> \param[in] NORM
|
||||
*> \verbatim
|
||||
*> NORM is CHARACTER*1
|
||||
*> Specifies the value to be returned in ZLANGT as described
|
||||
*> above.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] N
|
||||
*> \verbatim
|
||||
*> N is INTEGER
|
||||
*> The order of the matrix A. N >= 0. When N = 0, ZLANGT is
|
||||
*> set to zero.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] DL
|
||||
*> \verbatim
|
||||
*> DL is COMPLEX*16 array, dimension (N-1)
|
||||
*> The (n-1) sub-diagonal elements of A.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] D
|
||||
*> \verbatim
|
||||
*> D is COMPLEX*16 array, dimension (N)
|
||||
*> The diagonal elements of A.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] DU
|
||||
*> \verbatim
|
||||
*> DU is COMPLEX*16 array, dimension (N-1)
|
||||
*> The (n-1) super-diagonal elements of A.
|
||||
*> \endverbatim
|
||||
*
|
||||
* Authors:
|
||||
* ========
|
||||
*
|
||||
*> \author Univ. of Tennessee
|
||||
*> \author Univ. of California Berkeley
|
||||
*> \author Univ. of Colorado Denver
|
||||
*> \author NAG Ltd.
|
||||
*
|
||||
*> \date December 2016
|
||||
*
|
||||
*> \ingroup complex16OTHERauxiliary
|
||||
*
|
||||
* =====================================================================
|
||||
DOUBLE PRECISION FUNCTION ZLANGT( NORM, N, DL, D, DU )
|
||||
*
|
||||
* -- LAPACK auxiliary routine (version 3.7.0) --
|
||||
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
||||
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
||||
* December 2016
|
||||
*
|
||||
* .. Scalar Arguments ..
|
||||
CHARACTER NORM
|
||||
INTEGER N
|
||||
* ..
|
||||
* .. Array Arguments ..
|
||||
COMPLEX*16 D( * ), DL( * ), DU( * )
|
||||
* ..
|
||||
*
|
||||
* =====================================================================
|
||||
*
|
||||
* .. Parameters ..
|
||||
DOUBLE PRECISION ONE, ZERO
|
||||
PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
|
||||
* ..
|
||||
* .. Local Scalars ..
|
||||
INTEGER I
|
||||
DOUBLE PRECISION ANORM, SCALE, SUM, TEMP
|
||||
* ..
|
||||
* .. External Functions ..
|
||||
LOGICAL LSAME, DISNAN
|
||||
EXTERNAL LSAME, DISNAN
|
||||
* ..
|
||||
* .. External Subroutines ..
|
||||
EXTERNAL ZLASSQ
|
||||
* ..
|
||||
* .. Intrinsic Functions ..
|
||||
INTRINSIC ABS, SQRT
|
||||
* ..
|
||||
* .. Executable Statements ..
|
||||
*
|
||||
IF( N.LE.0 ) THEN
|
||||
ANORM = ZERO
|
||||
ELSE IF( LSAME( NORM, 'M' ) ) THEN
|
||||
*
|
||||
* Find max(abs(A(i,j))).
|
||||
*
|
||||
ANORM = ABS( D( N ) )
|
||||
DO 10 I = 1, N - 1
|
||||
IF( ANORM.LT.ABS( DL( I ) ) .OR. DISNAN( ABS( DL( I ) ) ) )
|
||||
$ ANORM = ABS(DL(I))
|
||||
IF( ANORM.LT.ABS( D( I ) ) .OR. DISNAN( ABS( D( I ) ) ) )
|
||||
$ ANORM = ABS(D(I))
|
||||
IF( ANORM.LT.ABS( DU( I ) ) .OR. DISNAN (ABS( DU( I ) ) ) )
|
||||
$ ANORM = ABS(DU(I))
|
||||
10 CONTINUE
|
||||
ELSE IF( LSAME( NORM, 'O' ) .OR. NORM.EQ.'1' ) THEN
|
||||
*
|
||||
* Find norm1(A).
|
||||
*
|
||||
IF( N.EQ.1 ) THEN
|
||||
ANORM = ABS( D( 1 ) )
|
||||
ELSE
|
||||
ANORM = ABS( D( 1 ) )+ABS( DL( 1 ) )
|
||||
TEMP = ABS( D( N ) )+ABS( DU( N-1 ) )
|
||||
IF( ANORM .LT. TEMP .OR. DISNAN( TEMP ) ) ANORM = TEMP
|
||||
DO 20 I = 2, N - 1
|
||||
TEMP = ABS( D( I ) )+ABS( DL( I ) )+ABS( DU( I-1 ) )
|
||||
IF( ANORM .LT. TEMP .OR. DISNAN( TEMP ) ) ANORM = TEMP
|
||||
20 CONTINUE
|
||||
END IF
|
||||
ELSE IF( LSAME( NORM, 'I' ) ) THEN
|
||||
*
|
||||
* Find normI(A).
|
||||
*
|
||||
IF( N.EQ.1 ) THEN
|
||||
ANORM = ABS( D( 1 ) )
|
||||
ELSE
|
||||
ANORM = ABS( D( 1 ) )+ABS( DU( 1 ) )
|
||||
TEMP = ABS( D( N ) )+ABS( DL( N-1 ) )
|
||||
IF( ANORM .LT. TEMP .OR. DISNAN( TEMP ) ) ANORM = TEMP
|
||||
DO 30 I = 2, N - 1
|
||||
TEMP = ABS( D( I ) )+ABS( DU( I ) )+ABS( DL( I-1 ) )
|
||||
IF( ANORM .LT. TEMP .OR. DISNAN( TEMP ) ) ANORM = TEMP
|
||||
30 CONTINUE
|
||||
END IF
|
||||
ELSE IF( ( LSAME( NORM, 'F' ) ) .OR. ( LSAME( NORM, 'E' ) ) ) THEN
|
||||
*
|
||||
* Find normF(A).
|
||||
*
|
||||
SCALE = ZERO
|
||||
SUM = ONE
|
||||
CALL ZLASSQ( N, D, 1, SCALE, SUM )
|
||||
IF( N.GT.1 ) THEN
|
||||
CALL ZLASSQ( N-1, DL, 1, SCALE, SUM )
|
||||
CALL ZLASSQ( N-1, DU, 1, SCALE, SUM )
|
||||
END IF
|
||||
ANORM = SCALE*SQRT( SUM )
|
||||
END IF
|
||||
*
|
||||
ZLANGT = ANORM
|
||||
RETURN
|
||||
*
|
||||
* End of ZLANGT
|
||||
*
|
||||
END
|
||||
Reference in New Issue
Block a user