Refs #247. Included lapack source codes. Avoid downloading tar.gz from netlib.org
Based on 3.4.2 version, apply patch.for_lapack-3.4.2.
This commit is contained in:
Zhang Xianyi
329
lapack-netlib/SRC/dla_gercond.f
Normal file
329
lapack-netlib/SRC/dla_gercond.f
Normal file
@@ -0,0 +1,329 @@
|
||||
*> \brief \b DLA_GERCOND estimates the Skeel condition number for a general matrix.
|
||||
*
|
||||
* =========== DOCUMENTATION ===========
|
||||
*
|
||||
* Online html documentation available at
|
||||
* http://www.netlib.org/lapack/explore-html/
|
||||
*
|
||||
*> \htmlonly
|
||||
*> Download DLA_GERCOND + dependencies
|
||||
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dla_gercond.f">
|
||||
*> [TGZ]</a>
|
||||
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dla_gercond.f">
|
||||
*> [ZIP]</a>
|
||||
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dla_gercond.f">
|
||||
*> [TXT]</a>
|
||||
*> \endhtmlonly
|
||||
*
|
||||
* Definition:
|
||||
* ===========
|
||||
*
|
||||
* DOUBLE PRECISION FUNCTION DLA_GERCOND ( TRANS, N, A, LDA, AF,
|
||||
* LDAF, IPIV, CMODE, C,
|
||||
* INFO, WORK, IWORK )
|
||||
*
|
||||
* .. Scalar Arguments ..
|
||||
* CHARACTER TRANS
|
||||
* INTEGER N, LDA, LDAF, INFO, CMODE
|
||||
* ..
|
||||
* .. Array Arguments ..
|
||||
* INTEGER IPIV( * ), IWORK( * )
|
||||
* DOUBLE PRECISION A( LDA, * ), AF( LDAF, * ), WORK( * ),
|
||||
* $ C( * )
|
||||
* ..
|
||||
*
|
||||
*
|
||||
*> \par Purpose:
|
||||
* =============
|
||||
*>
|
||||
*> \verbatim
|
||||
*>
|
||||
*> DLA_GERCOND estimates the Skeel condition number of op(A) * op2(C)
|
||||
*> where op2 is determined by CMODE as follows
|
||||
*> CMODE = 1 op2(C) = C
|
||||
*> CMODE = 0 op2(C) = I
|
||||
*> CMODE = -1 op2(C) = inv(C)
|
||||
*> The Skeel condition number cond(A) = norminf( |inv(A)||A| )
|
||||
*> is computed by computing scaling factors R such that
|
||||
*> diag(R)*A*op2(C) is row equilibrated and computing the standard
|
||||
*> infinity-norm condition number.
|
||||
*> \endverbatim
|
||||
*
|
||||
* Arguments:
|
||||
* ==========
|
||||
*
|
||||
*> \param[in] TRANS
|
||||
*> \verbatim
|
||||
*> TRANS is CHARACTER*1
|
||||
*> Specifies the form of the system of equations:
|
||||
*> = 'N': A * X = B (No transpose)
|
||||
*> = 'T': A**T * X = B (Transpose)
|
||||
*> = 'C': A**H * X = B (Conjugate Transpose = Transpose)
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] N
|
||||
*> \verbatim
|
||||
*> N is INTEGER
|
||||
*> The number of linear equations, i.e., the order of the
|
||||
*> matrix A. N >= 0.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] A
|
||||
*> \verbatim
|
||||
*> A is DOUBLE PRECISION array, dimension (LDA,N)
|
||||
*> On entry, the N-by-N matrix A.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] LDA
|
||||
*> \verbatim
|
||||
*> LDA is INTEGER
|
||||
*> The leading dimension of the array A. LDA >= max(1,N).
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] AF
|
||||
*> \verbatim
|
||||
*> AF is DOUBLE PRECISION array, dimension (LDAF,N)
|
||||
*> The factors L and U from the factorization
|
||||
*> A = P*L*U as computed by DGETRF.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] LDAF
|
||||
*> \verbatim
|
||||
*> LDAF is INTEGER
|
||||
*> The leading dimension of the array AF. LDAF >= max(1,N).
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] IPIV
|
||||
*> \verbatim
|
||||
*> IPIV is INTEGER array, dimension (N)
|
||||
*> The pivot indices from the factorization A = P*L*U
|
||||
*> as computed by DGETRF; row i of the matrix was interchanged
|
||||
*> with row IPIV(i).
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] CMODE
|
||||
*> \verbatim
|
||||
*> CMODE is INTEGER
|
||||
*> Determines op2(C) in the formula op(A) * op2(C) as follows:
|
||||
*> CMODE = 1 op2(C) = C
|
||||
*> CMODE = 0 op2(C) = I
|
||||
*> CMODE = -1 op2(C) = inv(C)
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] C
|
||||
*> \verbatim
|
||||
*> C is DOUBLE PRECISION array, dimension (N)
|
||||
*> The vector C in the formula op(A) * op2(C).
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[out] INFO
|
||||
*> \verbatim
|
||||
*> INFO is INTEGER
|
||||
*> = 0: Successful exit.
|
||||
*> i > 0: The ith argument is invalid.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] WORK
|
||||
*> \verbatim
|
||||
*> WORK is DOUBLE PRECISION array, dimension (3*N).
|
||||
*> Workspace.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] IWORK
|
||||
*> \verbatim
|
||||
*> IWORK is INTEGER array, dimension (N).
|
||||
*> Workspace.
|
||||
*> \endverbatim
|
||||
*
|
||||
* Authors:
|
||||
* ========
|
||||
*
|
||||
*> \author Univ. of Tennessee
|
||||
*> \author Univ. of California Berkeley
|
||||
*> \author Univ. of Colorado Denver
|
||||
*> \author NAG Ltd.
|
||||
*
|
||||
*> \date September 2012
|
||||
*
|
||||
*> \ingroup doubleGEcomputational
|
||||
*
|
||||
* =====================================================================
|
||||
DOUBLE PRECISION FUNCTION DLA_GERCOND ( TRANS, N, A, LDA, AF,
|
||||
$ LDAF, IPIV, CMODE, C,
|
||||
$ INFO, WORK, IWORK )
|
||||
*
|
||||
* -- LAPACK computational routine (version 3.4.2) --
|
||||
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
||||
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
||||
* September 2012
|
||||
*
|
||||
* .. Scalar Arguments ..
|
||||
CHARACTER TRANS
|
||||
INTEGER N, LDA, LDAF, INFO, CMODE
|
||||
* ..
|
||||
* .. Array Arguments ..
|
||||
INTEGER IPIV( * ), IWORK( * )
|
||||
DOUBLE PRECISION A( LDA, * ), AF( LDAF, * ), WORK( * ),
|
||||
$ C( * )
|
||||
* ..
|
||||
*
|
||||
* =====================================================================
|
||||
*
|
||||
* .. Local Scalars ..
|
||||
LOGICAL NOTRANS
|
||||
INTEGER KASE, I, J
|
||||
DOUBLE PRECISION AINVNM, TMP
|
||||
* ..
|
||||
* .. Local Arrays ..
|
||||
INTEGER ISAVE( 3 )
|
||||
* ..
|
||||
* .. External Functions ..
|
||||
LOGICAL LSAME
|
||||
EXTERNAL LSAME
|
||||
* ..
|
||||
* .. External Subroutines ..
|
||||
EXTERNAL DLACN2, DGETRS, XERBLA
|
||||
* ..
|
||||
* .. Intrinsic Functions ..
|
||||
INTRINSIC ABS, MAX
|
||||
* ..
|
||||
* .. Executable Statements ..
|
||||
*
|
||||
DLA_GERCOND = 0.0D+0
|
||||
*
|
||||
INFO = 0
|
||||
NOTRANS = LSAME( TRANS, 'N' )
|
||||
IF ( .NOT. NOTRANS .AND. .NOT. LSAME(TRANS, 'T')
|
||||
$ .AND. .NOT. LSAME(TRANS, 'C') ) THEN
|
||||
INFO = -1
|
||||
ELSE IF( N.LT.0 ) THEN
|
||||
INFO = -2
|
||||
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
|
||||
INFO = -4
|
||||
ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
|
||||
INFO = -6
|
||||
END IF
|
||||
IF( INFO.NE.0 ) THEN
|
||||
CALL XERBLA( 'DLA_GERCOND', -INFO )
|
||||
RETURN
|
||||
END IF
|
||||
IF( N.EQ.0 ) THEN
|
||||
DLA_GERCOND = 1.0D+0
|
||||
RETURN
|
||||
END IF
|
||||
*
|
||||
* Compute the equilibration matrix R such that
|
||||
* inv(R)*A*C has unit 1-norm.
|
||||
*
|
||||
IF (NOTRANS) THEN
|
||||
DO I = 1, N
|
||||
TMP = 0.0D+0
|
||||
IF ( CMODE .EQ. 1 ) THEN
|
||||
DO J = 1, N
|
||||
TMP = TMP + ABS( A( I, J ) * C( J ) )
|
||||
END DO
|
||||
ELSE IF ( CMODE .EQ. 0 ) THEN
|
||||
DO J = 1, N
|
||||
TMP = TMP + ABS( A( I, J ) )
|
||||
END DO
|
||||
ELSE
|
||||
DO J = 1, N
|
||||
TMP = TMP + ABS( A( I, J ) / C( J ) )
|
||||
END DO
|
||||
END IF
|
||||
WORK( 2*N+I ) = TMP
|
||||
END DO
|
||||
ELSE
|
||||
DO I = 1, N
|
||||
TMP = 0.0D+0
|
||||
IF ( CMODE .EQ. 1 ) THEN
|
||||
DO J = 1, N
|
||||
TMP = TMP + ABS( A( J, I ) * C( J ) )
|
||||
END DO
|
||||
ELSE IF ( CMODE .EQ. 0 ) THEN
|
||||
DO J = 1, N
|
||||
TMP = TMP + ABS( A( J, I ) )
|
||||
END DO
|
||||
ELSE
|
||||
DO J = 1, N
|
||||
TMP = TMP + ABS( A( J, I ) / C( J ) )
|
||||
END DO
|
||||
END IF
|
||||
WORK( 2*N+I ) = TMP
|
||||
END DO
|
||||
END IF
|
||||
*
|
||||
* Estimate the norm of inv(op(A)).
|
||||
*
|
||||
AINVNM = 0.0D+0
|
||||
|
||||
KASE = 0
|
||||
10 CONTINUE
|
||||
CALL DLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
|
||||
IF( KASE.NE.0 ) THEN
|
||||
IF( KASE.EQ.2 ) THEN
|
||||
*
|
||||
* Multiply by R.
|
||||
*
|
||||
DO I = 1, N
|
||||
WORK(I) = WORK(I) * WORK(2*N+I)
|
||||
END DO
|
||||
|
||||
IF (NOTRANS) THEN
|
||||
CALL DGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
|
||||
$ WORK, N, INFO )
|
||||
ELSE
|
||||
CALL DGETRS( 'Transpose', N, 1, AF, LDAF, IPIV,
|
||||
$ WORK, N, INFO )
|
||||
END IF
|
||||
*
|
||||
* Multiply by inv(C).
|
||||
*
|
||||
IF ( CMODE .EQ. 1 ) THEN
|
||||
DO I = 1, N
|
||||
WORK( I ) = WORK( I ) / C( I )
|
||||
END DO
|
||||
ELSE IF ( CMODE .EQ. -1 ) THEN
|
||||
DO I = 1, N
|
||||
WORK( I ) = WORK( I ) * C( I )
|
||||
END DO
|
||||
END IF
|
||||
ELSE
|
||||
*
|
||||
* Multiply by inv(C**T).
|
||||
*
|
||||
IF ( CMODE .EQ. 1 ) THEN
|
||||
DO I = 1, N
|
||||
WORK( I ) = WORK( I ) / C( I )
|
||||
END DO
|
||||
ELSE IF ( CMODE .EQ. -1 ) THEN
|
||||
DO I = 1, N
|
||||
WORK( I ) = WORK( I ) * C( I )
|
||||
END DO
|
||||
END IF
|
||||
|
||||
IF (NOTRANS) THEN
|
||||
CALL DGETRS( 'Transpose', N, 1, AF, LDAF, IPIV,
|
||||
$ WORK, N, INFO )
|
||||
ELSE
|
||||
CALL DGETRS( 'No transpose', N, 1, AF, LDAF, IPIV,
|
||||
$ WORK, N, INFO )
|
||||
END IF
|
||||
*
|
||||
* Multiply by R.
|
||||
*
|
||||
DO I = 1, N
|
||||
WORK( I ) = WORK( I ) * WORK( 2*N+I )
|
||||
END DO
|
||||
END IF
|
||||
GO TO 10
|
||||
END IF
|
||||
*
|
||||
* Compute the estimate of the reciprocal condition number.
|
||||
*
|
||||
IF( AINVNM .NE. 0.0D+0 )
|
||||
$ DLA_GERCOND = ( 1.0D+0 / AINVNM )
|
||||
*
|
||||
RETURN
|
||||
*
|
||||
END
|
||||
Reference in New Issue
Block a user