Refs #247. Included lapack source codes. Avoid downloading tar.gz from netlib.org
Based on 3.4.2 version, apply patch.for_lapack-3.4.2.
This commit is contained in:
Zhang Xianyi
312
lapack-netlib/SRC/cunmtr.f
Normal file
312
lapack-netlib/SRC/cunmtr.f
Normal file
@@ -0,0 +1,312 @@
|
||||
*> \brief \b CUNMTR
|
||||
*
|
||||
* =========== DOCUMENTATION ===========
|
||||
*
|
||||
* Online html documentation available at
|
||||
* http://www.netlib.org/lapack/explore-html/
|
||||
*
|
||||
*> \htmlonly
|
||||
*> Download CUNMTR + dependencies
|
||||
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cunmtr.f">
|
||||
*> [TGZ]</a>
|
||||
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cunmtr.f">
|
||||
*> [ZIP]</a>
|
||||
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cunmtr.f">
|
||||
*> [TXT]</a>
|
||||
*> \endhtmlonly
|
||||
*
|
||||
* Definition:
|
||||
* ===========
|
||||
*
|
||||
* SUBROUTINE CUNMTR( SIDE, UPLO, TRANS, M, N, A, LDA, TAU, C, LDC,
|
||||
* WORK, LWORK, INFO )
|
||||
*
|
||||
* .. Scalar Arguments ..
|
||||
* CHARACTER SIDE, TRANS, UPLO
|
||||
* INTEGER INFO, LDA, LDC, LWORK, M, N
|
||||
* ..
|
||||
* .. Array Arguments ..
|
||||
* COMPLEX A( LDA, * ), C( LDC, * ), TAU( * ),
|
||||
* $ WORK( * )
|
||||
* ..
|
||||
*
|
||||
*
|
||||
*> \par Purpose:
|
||||
* =============
|
||||
*>
|
||||
*> \verbatim
|
||||
*>
|
||||
*> CUNMTR overwrites the general complex M-by-N matrix C with
|
||||
*>
|
||||
*> SIDE = 'L' SIDE = 'R'
|
||||
*> TRANS = 'N': Q * C C * Q
|
||||
*> TRANS = 'C': Q**H * C C * Q**H
|
||||
*>
|
||||
*> where Q is a complex unitary matrix of order nq, with nq = m if
|
||||
*> SIDE = 'L' and nq = n if SIDE = 'R'. Q is defined as the product of
|
||||
*> nq-1 elementary reflectors, as returned by CHETRD:
|
||||
*>
|
||||
*> if UPLO = 'U', Q = H(nq-1) . . . H(2) H(1);
|
||||
*>
|
||||
*> if UPLO = 'L', Q = H(1) H(2) . . . H(nq-1).
|
||||
*> \endverbatim
|
||||
*
|
||||
* Arguments:
|
||||
* ==========
|
||||
*
|
||||
*> \param[in] SIDE
|
||||
*> \verbatim
|
||||
*> SIDE is CHARACTER*1
|
||||
*> = 'L': apply Q or Q**H from the Left;
|
||||
*> = 'R': apply Q or Q**H from the Right.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] UPLO
|
||||
*> \verbatim
|
||||
*> UPLO is CHARACTER*1
|
||||
*> = 'U': Upper triangle of A contains elementary reflectors
|
||||
*> from CHETRD;
|
||||
*> = 'L': Lower triangle of A contains elementary reflectors
|
||||
*> from CHETRD.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] TRANS
|
||||
*> \verbatim
|
||||
*> TRANS is CHARACTER*1
|
||||
*> = 'N': No transpose, apply Q;
|
||||
*> = 'C': Conjugate transpose, apply Q**H.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] M
|
||||
*> \verbatim
|
||||
*> M is INTEGER
|
||||
*> The number of rows of the matrix C. M >= 0.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] N
|
||||
*> \verbatim
|
||||
*> N is INTEGER
|
||||
*> The number of columns of the matrix C. N >= 0.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] A
|
||||
*> \verbatim
|
||||
*> A is COMPLEX array, dimension
|
||||
*> (LDA,M) if SIDE = 'L'
|
||||
*> (LDA,N) if SIDE = 'R'
|
||||
*> The vectors which define the elementary reflectors, as
|
||||
*> returned by CHETRD.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] LDA
|
||||
*> \verbatim
|
||||
*> LDA is INTEGER
|
||||
*> The leading dimension of the array A.
|
||||
*> LDA >= max(1,M) if SIDE = 'L'; LDA >= max(1,N) if SIDE = 'R'.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] TAU
|
||||
*> \verbatim
|
||||
*> TAU is COMPLEX array, dimension
|
||||
*> (M-1) if SIDE = 'L'
|
||||
*> (N-1) if SIDE = 'R'
|
||||
*> TAU(i) must contain the scalar factor of the elementary
|
||||
*> reflector H(i), as returned by CHETRD.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in,out] C
|
||||
*> \verbatim
|
||||
*> C is COMPLEX array, dimension (LDC,N)
|
||||
*> On entry, the M-by-N matrix C.
|
||||
*> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] LDC
|
||||
*> \verbatim
|
||||
*> LDC is INTEGER
|
||||
*> The leading dimension of the array C. LDC >= max(1,M).
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[out] WORK
|
||||
*> \verbatim
|
||||
*> WORK is COMPLEX array, dimension (MAX(1,LWORK))
|
||||
*> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] LWORK
|
||||
*> \verbatim
|
||||
*> LWORK is INTEGER
|
||||
*> The dimension of the array WORK.
|
||||
*> If SIDE = 'L', LWORK >= max(1,N);
|
||||
*> if SIDE = 'R', LWORK >= max(1,M).
|
||||
*> For optimum performance LWORK >= N*NB if SIDE = 'L', and
|
||||
*> LWORK >=M*NB if SIDE = 'R', where NB is the optimal
|
||||
*> blocksize.
|
||||
*>
|
||||
*> If LWORK = -1, then a workspace query is assumed; the routine
|
||||
*> only calculates the optimal size of the WORK array, returns
|
||||
*> this value as the first entry of the WORK array, and no error
|
||||
*> message related to LWORK is issued by XERBLA.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[out] INFO
|
||||
*> \verbatim
|
||||
*> INFO is INTEGER
|
||||
*> = 0: successful exit
|
||||
*> < 0: if INFO = -i, the i-th argument had an illegal value
|
||||
*> \endverbatim
|
||||
*
|
||||
* Authors:
|
||||
* ========
|
||||
*
|
||||
*> \author Univ. of Tennessee
|
||||
*> \author Univ. of California Berkeley
|
||||
*> \author Univ. of Colorado Denver
|
||||
*> \author NAG Ltd.
|
||||
*
|
||||
*> \date November 2011
|
||||
*
|
||||
*> \ingroup complexOTHERcomputational
|
||||
*
|
||||
* =====================================================================
|
||||
SUBROUTINE CUNMTR( SIDE, UPLO, TRANS, M, N, A, LDA, TAU, C, LDC,
|
||||
$ WORK, LWORK, INFO )
|
||||
*
|
||||
* -- LAPACK computational routine (version 3.4.0) --
|
||||
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
||||
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
||||
* November 2011
|
||||
*
|
||||
* .. Scalar Arguments ..
|
||||
CHARACTER SIDE, TRANS, UPLO
|
||||
INTEGER INFO, LDA, LDC, LWORK, M, N
|
||||
* ..
|
||||
* .. Array Arguments ..
|
||||
COMPLEX A( LDA, * ), C( LDC, * ), TAU( * ),
|
||||
$ WORK( * )
|
||||
* ..
|
||||
*
|
||||
* =====================================================================
|
||||
*
|
||||
* .. Local Scalars ..
|
||||
LOGICAL LEFT, LQUERY, UPPER
|
||||
INTEGER I1, I2, IINFO, LWKOPT, MI, NB, NI, NQ, NW
|
||||
* ..
|
||||
* .. External Functions ..
|
||||
LOGICAL LSAME
|
||||
INTEGER ILAENV
|
||||
EXTERNAL ILAENV, LSAME
|
||||
* ..
|
||||
* .. External Subroutines ..
|
||||
EXTERNAL CUNMQL, CUNMQR, XERBLA
|
||||
* ..
|
||||
* .. Intrinsic Functions ..
|
||||
INTRINSIC MAX
|
||||
* ..
|
||||
* .. Executable Statements ..
|
||||
*
|
||||
* Test the input arguments
|
||||
*
|
||||
INFO = 0
|
||||
LEFT = LSAME( SIDE, 'L' )
|
||||
UPPER = LSAME( UPLO, 'U' )
|
||||
LQUERY = ( LWORK.EQ.-1 )
|
||||
*
|
||||
* NQ is the order of Q and NW is the minimum dimension of WORK
|
||||
*
|
||||
IF( LEFT ) THEN
|
||||
NQ = M
|
||||
NW = N
|
||||
ELSE
|
||||
NQ = N
|
||||
NW = M
|
||||
END IF
|
||||
IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
|
||||
INFO = -1
|
||||
ELSE IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
|
||||
INFO = -2
|
||||
ELSE IF( .NOT.LSAME( TRANS, 'N' ) .AND. .NOT.LSAME( TRANS, 'C' ) )
|
||||
$ THEN
|
||||
INFO = -3
|
||||
ELSE IF( M.LT.0 ) THEN
|
||||
INFO = -4
|
||||
ELSE IF( N.LT.0 ) THEN
|
||||
INFO = -5
|
||||
ELSE IF( LDA.LT.MAX( 1, NQ ) ) THEN
|
||||
INFO = -7
|
||||
ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
|
||||
INFO = -10
|
||||
ELSE IF( LWORK.LT.MAX( 1, NW ) .AND. .NOT.LQUERY ) THEN
|
||||
INFO = -12
|
||||
END IF
|
||||
*
|
||||
IF( INFO.EQ.0 ) THEN
|
||||
IF( UPPER ) THEN
|
||||
IF( LEFT ) THEN
|
||||
NB = ILAENV( 1, 'CUNMQL', SIDE // TRANS, M-1, N, M-1,
|
||||
$ -1 )
|
||||
ELSE
|
||||
NB = ILAENV( 1, 'CUNMQL', SIDE // TRANS, M, N-1, N-1,
|
||||
$ -1 )
|
||||
END IF
|
||||
ELSE
|
||||
IF( LEFT ) THEN
|
||||
NB = ILAENV( 1, 'CUNMQR', SIDE // TRANS, M-1, N, M-1,
|
||||
$ -1 )
|
||||
ELSE
|
||||
NB = ILAENV( 1, 'CUNMQR', SIDE // TRANS, M, N-1, N-1,
|
||||
$ -1 )
|
||||
END IF
|
||||
END IF
|
||||
LWKOPT = MAX( 1, NW )*NB
|
||||
WORK( 1 ) = LWKOPT
|
||||
END IF
|
||||
*
|
||||
IF( INFO.NE.0 ) THEN
|
||||
CALL XERBLA( 'CUNMTR', -INFO )
|
||||
RETURN
|
||||
ELSE IF( LQUERY ) THEN
|
||||
RETURN
|
||||
END IF
|
||||
*
|
||||
* Quick return if possible
|
||||
*
|
||||
IF( M.EQ.0 .OR. N.EQ.0 .OR. NQ.EQ.1 ) THEN
|
||||
WORK( 1 ) = 1
|
||||
RETURN
|
||||
END IF
|
||||
*
|
||||
IF( LEFT ) THEN
|
||||
MI = M - 1
|
||||
NI = N
|
||||
ELSE
|
||||
MI = M
|
||||
NI = N - 1
|
||||
END IF
|
||||
*
|
||||
IF( UPPER ) THEN
|
||||
*
|
||||
* Q was determined by a call to CHETRD with UPLO = 'U'
|
||||
*
|
||||
CALL CUNMQL( SIDE, TRANS, MI, NI, NQ-1, A( 1, 2 ), LDA, TAU, C,
|
||||
$ LDC, WORK, LWORK, IINFO )
|
||||
ELSE
|
||||
*
|
||||
* Q was determined by a call to CHETRD with UPLO = 'L'
|
||||
*
|
||||
IF( LEFT ) THEN
|
||||
I1 = 2
|
||||
I2 = 1
|
||||
ELSE
|
||||
I1 = 1
|
||||
I2 = 2
|
||||
END IF
|
||||
CALL CUNMQR( SIDE, TRANS, MI, NI, NQ-1, A( 2, 1 ), LDA, TAU,
|
||||
$ C( I1, I2 ), LDC, WORK, LWORK, IINFO )
|
||||
END IF
|
||||
WORK( 1 ) = LWKOPT
|
||||
RETURN
|
||||
*
|
||||
* End of CUNMTR
|
||||
*
|
||||
END
|
||||
Reference in New Issue
Block a user