Import GotoBLAS2 1.13 BSD version codes.
This commit is contained in:
Xianyi Zhang
160
reference/zlauumf.f
Normal file
160
reference/zlauumf.f
Normal file
@@ -0,0 +1,160 @@
|
||||
SUBROUTINE ZLAUUMF( UPLO, N, A, LDA, INFO )
|
||||
*
|
||||
* -- LAPACK auxiliary routine (version 3.0) --
|
||||
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
|
||||
* Courant Institute, Argonne National Lab, and Rice University
|
||||
* September 30, 1994
|
||||
*
|
||||
* .. Scalar Arguments ..
|
||||
CHARACTER UPLO
|
||||
INTEGER INFO, LDA, N
|
||||
* ..
|
||||
* .. Array Arguments ..
|
||||
COMPLEX*16 A( LDA, * )
|
||||
* ..
|
||||
*
|
||||
* Purpose
|
||||
* =======
|
||||
*
|
||||
* ZLAUUM computes the product U * U' or L' * L, where the triangular
|
||||
* factor U or L is stored in the upper or lower triangular part of
|
||||
* the array A.
|
||||
*
|
||||
* If UPLO = 'U' or 'u' then the upper triangle of the result is stored,
|
||||
* overwriting the factor U in A.
|
||||
* If UPLO = 'L' or 'l' then the lower triangle of the result is stored,
|
||||
* overwriting the factor L in A.
|
||||
*
|
||||
* This is the blocked form of the algorithm, calling Level 3 BLAS.
|
||||
*
|
||||
* Arguments
|
||||
* =========
|
||||
*
|
||||
* UPLO (input) CHARACTER*1
|
||||
* Specifies whether the triangular factor stored in the array A
|
||||
* is upper or lower triangular:
|
||||
* = 'U': Upper triangular
|
||||
* = 'L': Lower triangular
|
||||
*
|
||||
* N (input) INTEGER
|
||||
* The order of the triangular factor U or L. N >= 0.
|
||||
*
|
||||
* A (input/output) COMPLEX*16 array, dimension (LDA,N)
|
||||
* On entry, the triangular factor U or L.
|
||||
* On exit, if UPLO = 'U', the upper triangle of A is
|
||||
* overwritten with the upper triangle of the product U * U';
|
||||
* if UPLO = 'L', the lower triangle of A is overwritten with
|
||||
* the lower triangle of the product L' * L.
|
||||
*
|
||||
* LDA (input) INTEGER
|
||||
* The leading dimension of the array A. LDA >= max(1,N).
|
||||
*
|
||||
* INFO (output) INTEGER
|
||||
* = 0: successful exit
|
||||
* < 0: if INFO = -k, the k-th argument had an illegal value
|
||||
*
|
||||
* =====================================================================
|
||||
*
|
||||
* .. Parameters ..
|
||||
DOUBLE PRECISION ONE
|
||||
PARAMETER ( ONE = 1.0D+0 )
|
||||
COMPLEX*16 CONE
|
||||
PARAMETER ( CONE = ( 1.0D+0, 0.0D+0 ) )
|
||||
* ..
|
||||
* .. Local Scalars ..
|
||||
LOGICAL UPPER
|
||||
INTEGER I, IB, NB
|
||||
* ..
|
||||
* .. External Functions ..
|
||||
LOGICAL LSAME
|
||||
EXTERNAL LSAME
|
||||
* ..
|
||||
* .. External Subroutines ..
|
||||
EXTERNAL XERBLA, ZGEMM, ZHERK, ZLAUU2, ZTRMM
|
||||
* ..
|
||||
* .. Intrinsic Functions ..
|
||||
INTRINSIC MAX, MIN
|
||||
* ..
|
||||
* .. Executable Statements ..
|
||||
*
|
||||
* Test the input parameters.
|
||||
*
|
||||
INFO = 0
|
||||
UPPER = LSAME( UPLO, 'U' )
|
||||
IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
|
||||
INFO = -1
|
||||
ELSE IF( N.LT.0 ) THEN
|
||||
INFO = -2
|
||||
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
|
||||
INFO = -4
|
||||
END IF
|
||||
IF( INFO.NE.0 ) THEN
|
||||
CALL XERBLA( 'ZLAUUM', -INFO )
|
||||
RETURN
|
||||
END IF
|
||||
*
|
||||
* Quick return if possible
|
||||
*
|
||||
IF( N.EQ.0 )
|
||||
$ RETURN
|
||||
*
|
||||
* Determine the block size for this environment.
|
||||
*
|
||||
NB = 128
|
||||
*
|
||||
IF( NB.LE.1 .OR. NB.GE.N ) THEN
|
||||
*
|
||||
* Use unblocked code
|
||||
*
|
||||
CALL ZLAUU2( UPLO, N, A, LDA, INFO )
|
||||
ELSE
|
||||
*
|
||||
* Use blocked code
|
||||
*
|
||||
IF( UPPER ) THEN
|
||||
*
|
||||
* Compute the product U * U'.
|
||||
*
|
||||
DO 10 I = 1, N, NB
|
||||
IB = MIN( NB, N-I+1 )
|
||||
CALL ZTRMM( 'Right', 'Upper', 'Conjugate transpose',
|
||||
$ 'Non-unit', I-1, IB, CONE, A( I, I ), LDA,
|
||||
$ A( 1, I ), LDA )
|
||||
CALL ZLAUU2( 'Upper', IB, A( I, I ), LDA, INFO )
|
||||
IF( I+IB.LE.N ) THEN
|
||||
CALL ZGEMM( 'No transpose', 'Conjugate transpose',
|
||||
$ I-1, IB, N-I-IB+1, CONE, A( 1, I+IB ),
|
||||
$ LDA, A( I, I+IB ), LDA, CONE, A( 1, I ),
|
||||
$ LDA )
|
||||
CALL ZHERK( 'Upper', 'No transpose', IB, N-I-IB+1,
|
||||
$ ONE, A( I, I+IB ), LDA, ONE, A( I, I ),
|
||||
$ LDA )
|
||||
END IF
|
||||
10 CONTINUE
|
||||
ELSE
|
||||
*
|
||||
* Compute the product L' * L.
|
||||
*
|
||||
DO 20 I = 1, N, NB
|
||||
IB = MIN( NB, N-I+1 )
|
||||
CALL ZTRMM( 'Left', 'Lower', 'Conjugate transpose',
|
||||
$ 'Non-unit', IB, I-1, CONE, A( I, I ), LDA,
|
||||
$ A( I, 1 ), LDA )
|
||||
CALL ZLAUU2( 'Lower', IB, A( I, I ), LDA, INFO )
|
||||
IF( I+IB.LE.N ) THEN
|
||||
CALL ZGEMM( 'Conjugate transpose', 'No transpose', IB,
|
||||
$ I-1, N-I-IB+1, CONE, A( I+IB, I ), LDA,
|
||||
$ A( I+IB, 1 ), LDA, CONE, A( I, 1 ), LDA )
|
||||
CALL ZHERK( 'Lower', 'Conjugate transpose', IB,
|
||||
$ N-I-IB+1, ONE, A( I+IB, I ), LDA, ONE,
|
||||
$ A( I, I ), LDA )
|
||||
END IF
|
||||
20 CONTINUE
|
||||
END IF
|
||||
END IF
|
||||
*
|
||||
RETURN
|
||||
*
|
||||
* End of ZLAUUM
|
||||
*
|
||||
END
|
||||
Reference in New Issue
Block a user