Import GotoBLAS2 1.13 BSD version codes.
This commit is contained in:
Xianyi Zhang
187
reference/cpotrff.f
Normal file
187
reference/cpotrff.f
Normal file
@@ -0,0 +1,187 @@
|
||||
SUBROUTINE CPOTRFF( UPLO, N, A, LDA, INFO )
|
||||
*
|
||||
* -- LAPACK routine (version 3.0) --
|
||||
* Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
|
||||
* Courant Institute, Argonne National Lab, and Rice University
|
||||
* September 30, 1994
|
||||
*
|
||||
* .. Scalar Arguments ..
|
||||
CHARACTER UPLO
|
||||
INTEGER INFO, LDA, N
|
||||
* ..
|
||||
* .. Array Arguments ..
|
||||
COMPLEX A( LDA, * )
|
||||
* ..
|
||||
*
|
||||
* Purpose
|
||||
* =======
|
||||
*
|
||||
* CPOTRF computes the Cholesky factorization of a complex Hermitian
|
||||
* positive definite matrix A.
|
||||
*
|
||||
* The factorization has the form
|
||||
* A = U**H * U, if UPLO = 'U', or
|
||||
* A = L * L**H, if UPLO = 'L',
|
||||
* where U is an upper triangular matrix and L is lower triangular.
|
||||
*
|
||||
* This is the block version of the algorithm, calling Level 3 BLAS.
|
||||
*
|
||||
* Arguments
|
||||
* =========
|
||||
*
|
||||
* UPLO (input) CHARACTER*1
|
||||
* = 'U': Upper triangle of A is stored;
|
||||
* = 'L': Lower triangle of A is stored.
|
||||
*
|
||||
* N (input) INTEGER
|
||||
* The order of the matrix A. N >= 0.
|
||||
*
|
||||
* A (input/output) COMPLEX array, dimension (LDA,N)
|
||||
* On entry, the Hermitian matrix A. If UPLO = 'U', the leading
|
||||
* N-by-N upper triangular part of A contains the upper
|
||||
* triangular part of the matrix A, and the strictly lower
|
||||
* triangular part of A is not referenced. If UPLO = 'L', the
|
||||
* leading N-by-N lower triangular part of A contains the lower
|
||||
* triangular part of the matrix A, and the strictly upper
|
||||
* triangular part of A is not referenced.
|
||||
*
|
||||
* On exit, if INFO = 0, the factor U or L from the Cholesky
|
||||
* factorization A = U**H*U or A = L*L**H.
|
||||
*
|
||||
* LDA (input) INTEGER
|
||||
* The leading dimension of the array A. LDA >= max(1,N).
|
||||
*
|
||||
* INFO (output) INTEGER
|
||||
* = 0: successful exit
|
||||
* < 0: if INFO = -i, the i-th argument had an illegal value
|
||||
* > 0: if INFO = i, the leading minor of order i is not
|
||||
* positive definite, and the factorization could not be
|
||||
* completed.
|
||||
*
|
||||
* =====================================================================
|
||||
*
|
||||
* .. Parameters ..
|
||||
REAL ONE
|
||||
COMPLEX CONE
|
||||
PARAMETER ( ONE = 1.0E+0, CONE = ( 1.0E+0, 0.0E+0 ) )
|
||||
* ..
|
||||
* .. Local Scalars ..
|
||||
LOGICAL UPPER
|
||||
INTEGER J, JB, NB
|
||||
* ..
|
||||
* .. External Functions ..
|
||||
LOGICAL LSAME
|
||||
EXTERNAL LSAME
|
||||
* ..
|
||||
* .. External Subroutines ..
|
||||
EXTERNAL CGEMM, CHERK, CPOTF2, CTRSM, XERBLA
|
||||
* ..
|
||||
* .. Intrinsic Functions ..
|
||||
INTRINSIC MAX, MIN
|
||||
* ..
|
||||
* .. Executable Statements ..
|
||||
*
|
||||
* Test the input parameters.
|
||||
*
|
||||
INFO = 0
|
||||
UPPER = LSAME( UPLO, 'U' )
|
||||
IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
|
||||
INFO = -1
|
||||
ELSE IF( N.LT.0 ) THEN
|
||||
INFO = -2
|
||||
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
|
||||
INFO = -4
|
||||
END IF
|
||||
IF( INFO.NE.0 ) THEN
|
||||
CALL XERBLA( 'CPOTRF', -INFO )
|
||||
RETURN
|
||||
END IF
|
||||
*
|
||||
* Quick return if possible
|
||||
*
|
||||
IF( N.EQ.0 )
|
||||
$ RETURN
|
||||
*
|
||||
* Determine the block size for this environment.
|
||||
*
|
||||
NB = 56
|
||||
|
||||
IF( NB.LE.1 .OR. NB.GE.N ) THEN
|
||||
*
|
||||
* Use unblocked code.
|
||||
*
|
||||
CALL CPOTF2( UPLO, N, A, LDA, INFO )
|
||||
ELSE
|
||||
*
|
||||
* Use blocked code.
|
||||
*
|
||||
IF( UPPER ) THEN
|
||||
*
|
||||
* Compute the Cholesky factorization A = U'*U.
|
||||
*
|
||||
DO 10 J = 1, N, NB
|
||||
*
|
||||
* Update and factorize the current diagonal block and test
|
||||
* for non-positive-definiteness.
|
||||
*
|
||||
JB = MIN( NB, N-J+1 )
|
||||
CALL CHERK( 'Upper', 'Conjugate transpose', JB, J-1,
|
||||
$ -ONE, A( 1, J ), LDA, ONE, A( J, J ), LDA )
|
||||
CALL CPOTF2( 'Upper', JB, A( J, J ), LDA, INFO )
|
||||
IF( INFO.NE.0 )
|
||||
$ GO TO 30
|
||||
IF( J+JB.LE.N ) THEN
|
||||
*
|
||||
* Compute the current block row.
|
||||
*
|
||||
CALL CGEMM( 'Conjugate transpose', 'No transpose', JB,
|
||||
$ N-J-JB+1, J-1, -CONE, A( 1, J ), LDA,
|
||||
$ A( 1, J+JB ), LDA, CONE, A( J, J+JB ),
|
||||
$ LDA )
|
||||
CALL CTRSM( 'Left', 'Upper', 'Conjugate transpose',
|
||||
$ 'Non-unit', JB, N-J-JB+1, CONE, A( J, J ),
|
||||
$ LDA, A( J, J+JB ), LDA )
|
||||
END IF
|
||||
10 CONTINUE
|
||||
*
|
||||
ELSE
|
||||
*
|
||||
* Compute the Cholesky factorization A = L*L'.
|
||||
*
|
||||
DO 20 J = 1, N, NB
|
||||
*
|
||||
* Update and factorize the current diagonal block and test
|
||||
* for non-positive-definiteness.
|
||||
*
|
||||
JB = MIN( NB, N-J+1 )
|
||||
CALL CHERK( 'Lower', 'No transpose', JB, J-1, -ONE,
|
||||
$ A( J, 1 ), LDA, ONE, A( J, J ), LDA )
|
||||
CALL CPOTF2( 'Lower', JB, A( J, J ), LDA, INFO )
|
||||
IF( INFO.NE.0 )
|
||||
$ GO TO 30
|
||||
IF( J+JB.LE.N ) THEN
|
||||
*
|
||||
* Compute the current block column.
|
||||
*
|
||||
CALL CGEMM( 'No transpose', 'Conjugate transpose',
|
||||
$ N-J-JB+1, JB, J-1, -CONE, A( J+JB, 1 ),
|
||||
$ LDA, A( J, 1 ), LDA, CONE, A( J+JB, J ),
|
||||
$ LDA )
|
||||
CALL CTRSM( 'Right', 'Lower', 'Conjugate transpose',
|
||||
$ 'Non-unit', N-J-JB+1, JB, CONE, A( J, J ),
|
||||
$ LDA, A( J+JB, J ), LDA )
|
||||
END IF
|
||||
20 CONTINUE
|
||||
END IF
|
||||
END IF
|
||||
GO TO 40
|
||||
*
|
||||
30 CONTINUE
|
||||
INFO = INFO + J - 1
|
||||
*
|
||||
40 CONTINUE
|
||||
RETURN
|
||||
*
|
||||
* End of CPOTRF
|
||||
*
|
||||
END
|
||||
Reference in New Issue
Block a user